git.squeep.com Git - allocwithin/blob - m4/ax_pthread.m4

   1 # ===========================================================================
   2 #        http://www.gnu.org/software/autoconf-archive/ax_pthread.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
   8 #
   9 # DESCRIPTION
  10 #
  11 #   This macro figures out how to build C programs using POSIX threads. It
  12 #   sets the PTHREAD_LIBS output variable to the threads library and linker
  13 #   flags, and the PTHREAD_CFLAGS output variable to any special C compiler
  14 #   flags that are needed. (The user can also force certain compiler
  15 #   flags/libs to be tested by setting these environment variables.)
  16 #
  17 #   Also sets PTHREAD_CC to any special C compiler that is needed for
  18 #   multi-threaded programs (defaults to the value of CC otherwise). (This
  19 #   is necessary on AIX to use the special cc_r compiler alias.)
  20 #
  21 #   NOTE: You are assumed to not only compile your program with these flags,
  22 #   but also link it with them as well. e.g. you should link with
  23 #   $PTHREAD_CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS $LIBS
  24 #
  25 #   If you are only building threads programs, you may wish to use these
  26 #   variables in your default LIBS, CFLAGS, and CC:
  27 #
  28 #     LIBS="$PTHREAD_LIBS $LIBS"
  29 #     CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  30 #     CC="$PTHREAD_CC"
  31 #
  32 #   In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute constant
  33 #   has a nonstandard name, defines PTHREAD_CREATE_JOINABLE to that name
  34 #   (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
  35 #
  36 #   ACTION-IF-FOUND is a list of shell commands to run if a threads library
  37 #   is found, and ACTION-IF-NOT-FOUND is a list of commands to run it if it
  38 #   is not found. If ACTION-IF-FOUND is not specified, the default action
  39 #   will define HAVE_PTHREAD.
  40 #
  41 #   Please let the authors know if this macro fails on any platform, or if
  42 #   you have any other suggestions or comments. This macro was based on work
  43 #   by SGJ on autoconf scripts for FFTW (http://www.fftw.org/) (with help
  44 #   from M. Frigo), as well as ac_pthread and hb_pthread macros posted by
  45 #   Alejandro Forero Cuervo to the autoconf macro repository. We are also
  46 #   grateful for the helpful feedback of numerous users.
  47 #
  48 # LICENSE
  49 #
  50 #   Copyright (c) 2008 Steven G. Johnson <stevenj@alum.mit.edu>
  51 #
  52 #   This program is free software: you can redistribute it and/or modify it
  53 #   under the terms of the GNU General Public License as published by the
  54 #   Free Software Foundation, either version 3 of the License, or (at your
  55 #   option) any later version.
  56 #
  57 #   This program is distributed in the hope that it will be useful, but
  58 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  59 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  60 #   Public License for more details.
  61 #
  62 #   You should have received a copy of the GNU General Public License along
  63 #   with this program. If not, see <http://www.gnu.org/licenses/>.
  64 #
  65 #   As a special exception, the respective Autoconf Macro's copyright owner
  66 #   gives unlimited permission to copy, distribute and modify the configure
  67 #   scripts that are the output of Autoconf when processing the Macro. You
  68 #   need not follow the terms of the GNU General Public License when using
  69 #   or distributing such scripts, even though portions of the text of the
  70 #   Macro appear in them. The GNU General Public License (GPL) does govern
  71 #   all other use of the material that constitutes the Autoconf Macro.
  72 #
  73 #   This special exception to the GPL applies to versions of the Autoconf
  74 #   Macro released by the Autoconf Archive. When you make and distribute a
  75 #   modified version of the Autoconf Macro, you may extend this special
  76 #   exception to the GPL to apply to your modified version as well.
  77
  78 #serial 11
  79
  80 AU_ALIAS([ACX_PTHREAD], [AX_PTHREAD])
  81 AC_DEFUN([AX_PTHREAD], [
  82 AC_REQUIRE([AC_CANONICAL_HOST])
  83 AC_LANG_SAVE
  84 AC_LANG_C
  85 ax_pthread_ok=no
  86
  87 # We used to check for pthread.h first, but this fails if pthread.h
  88 # requires special compiler flags (e.g. on True64 or Sequent).
  89 # It gets checked for in the link test anyway.
  90
  91 # First of all, check if the user has set any of the PTHREAD_LIBS,
  92 # etcetera environment variables, and if threads linking works using
  93 # them:
  94 if test x"$PTHREAD_LIBS$PTHREAD_CFLAGS" != x; then
  95         save_CFLAGS="$CFLAGS"
  96         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  97         save_LIBS="$LIBS"
  98         LIBS="$PTHREAD_LIBS $LIBS"
  99         AC_MSG_CHECKING([for pthread_join in LIBS=$PTHREAD_LIBS with CFLAGS=$PTHREAD_CFLAGS])
 100         AC_TRY_LINK_FUNC(pthread_join, ax_pthread_ok=yes)
 101         AC_MSG_RESULT($ax_pthread_ok)
 102         if test x"$ax_pthread_ok" = xno; then
 103                 PTHREAD_LIBS=""
 104                 PTHREAD_CFLAGS=""
 105         fi
 106         LIBS="$save_LIBS"
 107         CFLAGS="$save_CFLAGS"
 108 fi
 109
 110 # We must check for the threads library under a number of different
 111 # names; the ordering is very important because some systems
 112 # (e.g. DEC) have both -lpthread and -lpthreads, where one of the
 113 # libraries is broken (non-POSIX).
 114
 115 # Create a list of thread flags to try.  Items starting with a "-" are
 116 # C compiler flags, and other items are library names, except for "none"
 117 # which indicates that we try without any flags at all, and "pthread-config"
 118 # which is a program returning the flags for the Pth emulation library.
 119
 120 ax_pthread_flags="pthreads none -Kthread -kthread lthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
 121
 122 # The ordering *is* (sometimes) important.  Some notes on the
 123 # individual items follow:
 124
 125 # pthreads: AIX (must check this before -lpthread)
 126 # none: in case threads are in libc; should be tried before -Kthread and
 127 #       other compiler flags to prevent continual compiler warnings
 128 # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
 129 # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
 130 # lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
 131 # -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads)
 132 # -pthreads: Solaris/gcc
 133 # -mthreads: Mingw32/gcc, Lynx/gcc
 134 # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
 135 #      doesn't hurt to check since this sometimes defines pthreads too;
 136 #      also defines -D_REENTRANT)
 137 #      ... -mt is also the pthreads flag for HP/aCC
 138 # pthread: Linux, etcetera
 139 # --thread-safe: KAI C++
 140 # pthread-config: use pthread-config program (for GNU Pth library)
 141
 142 case "${host_cpu}-${host_os}" in
 143         *solaris*)
 144
 145         # On Solaris (at least, for some versions), libc contains stubbed
 146         # (non-functional) versions of the pthreads routines, so link-based
 147         # tests will erroneously succeed.  (We need to link with -pthreads/-mt/
 148         # -lpthread.)  (The stubs are missing pthread_cleanup_push, or rather
 149         # a function called by this macro, so we could check for that, but
 150         # who knows whether they'll stub that too in a future libc.)  So,
 151         # we'll just look for -pthreads and -lpthread first:
 152
 153         ax_pthread_flags="-pthreads pthread -mt -pthread $ax_pthread_flags"
 154         ;;
 155
 156         *-darwin*)
 157         ax_pthread_flags="-pthread $ax_pthread_flags"
 158         ;;
 159 esac
 160
 161 if test x"$ax_pthread_ok" = xno; then
 162 for flag in $ax_pthread_flags; do
 163
 164         case $flag in
 165                 none)
 166                 AC_MSG_CHECKING([whether pthreads work without any flags])
 167                 ;;
 168
 169                 -*)
 170                 AC_MSG_CHECKING([whether pthreads work with $flag])
 171                 PTHREAD_CFLAGS="$flag"
 172                 ;;
 173
 174                 pthread-config)
 175                 AC_CHECK_PROG(ax_pthread_config, pthread-config, yes, no)
 176                 if test x"$ax_pthread_config" = xno; then continue; fi
 177                 PTHREAD_CFLAGS="`pthread-config --cflags`"
 178                 PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
 179                 ;;
 180
 181                 *)
 182                 AC_MSG_CHECKING([for the pthreads library -l$flag])
 183                 PTHREAD_LIBS="-l$flag"
 184                 ;;
 185         esac
 186
 187         save_LIBS="$LIBS"
 188         save_CFLAGS="$CFLAGS"
 189         LIBS="$PTHREAD_LIBS $LIBS"
 190         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 191
 192         # Check for various functions.  We must include pthread.h,
 193         # since some functions may be macros.  (On the Sequent, we
 194         # need a special flag -Kthread to make this header compile.)
 195         # We check for pthread_join because it is in -lpthread on IRIX
 196         # while pthread_create is in libc.  We check for pthread_attr_init
 197         # due to DEC craziness with -lpthreads.  We check for
 198         # pthread_cleanup_push because it is one of the few pthread
 199         # functions on Solaris that doesn't have a non-functional libc stub.
 200         # We try pthread_create on general principles.
 201         AC_TRY_LINK([#include <pthread.h>
 202                      static void routine(void* a) {a=0;}
 203                      static void* start_routine(void* a) {return a;}],
 204                     [pthread_t th; pthread_attr_t attr;
 205                      pthread_create(&th,0,start_routine,0);
 206                      pthread_join(th, 0);
 207                      pthread_attr_init(&attr);
 208                      pthread_cleanup_push(routine, 0);
 209                      pthread_cleanup_pop(0); ],
 210                     [ax_pthread_ok=yes])
 211
 212         LIBS="$save_LIBS"
 213         CFLAGS="$save_CFLAGS"
 214
 215         AC_MSG_RESULT($ax_pthread_ok)
 216         if test "x$ax_pthread_ok" = xyes; then
 217                 break;
 218         fi
 219
 220         PTHREAD_LIBS=""
 221         PTHREAD_CFLAGS=""
 222 done
 223 fi
 224
 225 # Various other checks:
 226 if test "x$ax_pthread_ok" = xyes; then
 227         save_LIBS="$LIBS"
 228         LIBS="$PTHREAD_LIBS $LIBS"
 229         save_CFLAGS="$CFLAGS"
 230         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 231
 232         # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
 233         AC_MSG_CHECKING([for joinable pthread attribute])
 234         attr_name=unknown
 235         for attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
 236             AC_TRY_LINK([#include <pthread.h>], [int attr=$attr; return attr;],
 237                         [attr_name=$attr; break])
 238         done
 239         AC_MSG_RESULT($attr_name)
 240         if test "$attr_name" != PTHREAD_CREATE_JOINABLE; then
 241             AC_DEFINE_UNQUOTED(PTHREAD_CREATE_JOINABLE, $attr_name,
 242                                [Define to necessary symbol if this constant
 243                                 uses a non-standard name on your system.])
 244         fi
 245
 246         AC_MSG_CHECKING([if more special flags are required for pthreads])
 247         flag=no
 248         case "${host_cpu}-${host_os}" in
 249             *-aix* | *-freebsd* | *-darwin*) flag="-D_THREAD_SAFE";;
 250             *solaris* | *-osf* | *-hpux*) flag="-D_REENTRANT";;
 251         esac
 252         AC_MSG_RESULT(${flag})
 253         if test "x$flag" != xno; then
 254             PTHREAD_CFLAGS="$flag $PTHREAD_CFLAGS"
 255         fi
 256
 257         LIBS="$save_LIBS"
 258         CFLAGS="$save_CFLAGS"
 259
 260         # More AIX lossage: must compile with xlc_r or cc_r
 261         if test x"$GCC" != xyes; then
 262           AC_CHECK_PROGS(PTHREAD_CC, xlc_r cc_r, ${CC})
 263         else
 264           PTHREAD_CC=$CC
 265         fi
 266 else
 267         PTHREAD_CC="$CC"
 268 fi
 269
 270 AC_SUBST(PTHREAD_LIBS)
 271 AC_SUBST(PTHREAD_CFLAGS)
 272 AC_SUBST(PTHREAD_CC)
 273
 274 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
 275 if test x"$ax_pthread_ok" = xyes; then
 276         ifelse([$1],,AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.]),[$1])
 277         :
 278 else
 279         ax_pthread_ok=no
 280         $2
 281 fi
 282 AC_LANG_RESTORE
 283 ])dnl AX_PTHREAD