git.squeep.com Git - akkoma/blob - test/web/pleroma_api/controllers/pleroma_api_controller_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.PleromaAPI.PleromaAPIControllerTest do
   6   use Pleroma.Web.ConnCase
   7
   8   alias Pleroma.Conversation.Participation
   9   alias Pleroma.Notification
  10   alias Pleroma.Object
  11   alias Pleroma.Repo
  12   alias Pleroma.User
  13   alias Pleroma.Web.CommonAPI
  14
  15   import Pleroma.Factory
  16
  17   test "POST /api/v1/pleroma/statuses/:id/react_with_emoji", %{conn: conn} do
  18     user = insert(:user)
  19     other_user = insert(:user)
  20
  21     {:ok, activity} = CommonAPI.post(user, %{"status" => "#cofe"})
  22
  23     result =
  24       conn
  25       |> assign(:user, other_user)
  26       |> post("/api/v1/pleroma/statuses/#{activity.id}/react_with_emoji", %{"emoji" => "☕"})
  27
  28     assert %{"id" => id} = json_response(result, 200)
  29     assert to_string(activity.id) == id
  30   end
  31
  32   test "POST /api/v1/pleroma/statuses/:id/unreact_with_emoji", %{conn: conn} do
  33     user = insert(:user)
  34     other_user = insert(:user)
  35
  36     {:ok, activity} = CommonAPI.post(user, %{"status" => "#cofe"})
  37     {:ok, activity, _object} = CommonAPI.react_with_emoji(activity.id, other_user, "☕")
  38
  39     result =
  40       conn
  41       |> assign(:user, other_user)
  42       |> post("/api/v1/pleroma/statuses/#{activity.id}/unreact_with_emoji", %{"emoji" => "☕"})
  43
  44     assert %{"id" => id} = json_response(result, 200)
  45     assert to_string(activity.id) == id
  46
  47     object = Object.normalize(activity)
  48
  49     assert object.data["reaction_count"] == 0
  50   end
  51
  52   test "GET /api/v1/pleroma/statuses/:id/emoji_reactions_by", %{conn: conn} do
  53     user = insert(:user)
  54     other_user = insert(:user)
  55
  56     {:ok, activity} = CommonAPI.post(user, %{"status" => "#cofe"})
  57
  58     result =
  59       conn
  60       |> get("/api/v1/pleroma/statuses/#{activity.id}/emoji_reactions_by")
  61       |> json_response(200)
  62
  63     assert result == %{}
  64
  65     {:ok, _, _} = CommonAPI.react_with_emoji(activity.id, other_user, "🎅")
  66
  67     result =
  68       conn
  69       |> get("/api/v1/pleroma/statuses/#{activity.id}/emoji_reactions_by")
  70       |> json_response(200)
  71
  72     [represented_user] = result["🎅"]
  73     assert represented_user["id"] == other_user.id
  74   end
  75
  76   test "/api/v1/pleroma/conversations/:id", %{conn: conn} do
  77     user = insert(:user)
  78     other_user = insert(:user)
  79
  80     {:ok, _activity} =
  81       CommonAPI.post(user, %{"status" => "Hi @#{other_user.nickname}!", "visibility" => "direct"})
  82
  83     [participation] = Participation.for_user(other_user)
  84
  85     result =
  86       conn
  87       |> assign(:user, other_user)
  88       |> get("/api/v1/pleroma/conversations/#{participation.id}")
  89       |> json_response(200)
  90
  91     assert result["id"] == participation.id |> to_string()
  92   end
  93
  94   test "/api/v1/pleroma/conversations/:id/statuses", %{conn: conn} do
  95     user = insert(:user)
  96     other_user = insert(:user)
  97     third_user = insert(:user)
  98
  99     {:ok, _activity} =
 100       CommonAPI.post(user, %{"status" => "Hi @#{third_user.nickname}!", "visibility" => "direct"})
 101
 102     {:ok, activity} =
 103       CommonAPI.post(user, %{"status" => "Hi @#{other_user.nickname}!", "visibility" => "direct"})
 104
 105     [participation] = Participation.for_user(other_user)
 106
 107     {:ok, activity_two} =
 108       CommonAPI.post(other_user, %{
 109         "status" => "Hi!",
 110         "in_reply_to_status_id" => activity.id,
 111         "in_reply_to_conversation_id" => participation.id
 112       })
 113
 114     result =
 115       conn
 116       |> assign(:user, other_user)
 117       |> get("/api/v1/pleroma/conversations/#{participation.id}/statuses")
 118       |> json_response(200)
 119
 120     assert length(result) == 2
 121
 122     id_one = activity.id
 123     id_two = activity_two.id
 124     assert [%{"id" => ^id_one}, %{"id" => ^id_two}] = result
 125   end
 126
 127   test "PATCH /api/v1/pleroma/conversations/:id", %{conn: conn} do
 128     user = insert(:user)
 129     other_user = insert(:user)
 130
 131     {:ok, _activity} = CommonAPI.post(user, %{"status" => "Hi", "visibility" => "direct"})
 132
 133     [participation] = Participation.for_user(user)
 134
 135     participation = Repo.preload(participation, :recipients)
 136
 137     user = User.get_cached_by_id(user.id)
 138     assert [user] == participation.recipients
 139     assert other_user not in participation.recipients
 140
 141     result =
 142       conn
 143       |> assign(:user, user)
 144       |> patch("/api/v1/pleroma/conversations/#{participation.id}", %{
 145         "recipients" => [user.id, other_user.id]
 146       })
 147       |> json_response(200)
 148
 149     assert result["id"] == participation.id |> to_string
 150
 151     [participation] = Participation.for_user(user)
 152     participation = Repo.preload(participation, :recipients)
 153
 154     assert user in participation.recipients
 155     assert other_user in participation.recipients
 156   end
 157
 158   describe "POST /api/v1/pleroma/notifications/read" do
 159     test "it marks a single notification as read", %{conn: conn} do
 160       user1 = insert(:user)
 161       user2 = insert(:user)
 162       {:ok, activity1} = CommonAPI.post(user2, %{"status" => "hi @#{user1.nickname}"})
 163       {:ok, activity2} = CommonAPI.post(user2, %{"status" => "hi @#{user1.nickname}"})
 164       {:ok, [notification1]} = Notification.create_notifications(activity1)
 165       {:ok, [notification2]} = Notification.create_notifications(activity2)
 166
 167       response =
 168         conn
 169         |> assign(:user, user1)
 170         |> post("/api/v1/pleroma/notifications/read", %{"id" => "#{notification1.id}"})
 171         |> json_response(:ok)
 172
 173       assert %{"pleroma" => %{"is_seen" => true}} = response
 174       assert Repo.get(Notification, notification1.id).seen
 175       refute Repo.get(Notification, notification2.id).seen
 176     end
 177
 178     test "it marks multiple notifications as read", %{conn: conn} do
 179       user1 = insert(:user)
 180       user2 = insert(:user)
 181       {:ok, _activity1} = CommonAPI.post(user2, %{"status" => "hi @#{user1.nickname}"})
 182       {:ok, _activity2} = CommonAPI.post(user2, %{"status" => "hi @#{user1.nickname}"})
 183       {:ok, _activity3} = CommonAPI.post(user2, %{"status" => "HIE @#{user1.nickname}"})
 184
 185       [notification3, notification2, notification1] = Notification.for_user(user1, %{limit: 3})
 186
 187       [response1, response2] =
 188         conn
 189         |> assign(:user, user1)
 190         |> post("/api/v1/pleroma/notifications/read", %{"max_id" => "#{notification2.id}"})
 191         |> json_response(:ok)
 192
 193       assert %{"pleroma" => %{"is_seen" => true}} = response1
 194       assert %{"pleroma" => %{"is_seen" => true}} = response2
 195       assert Repo.get(Notification, notification1.id).seen
 196       assert Repo.get(Notification, notification2.id).seen
 197       refute Repo.get(Notification, notification3.id).seen
 198     end
 199
 200     test "it returns error when notification not found", %{conn: conn} do
 201       user1 = insert(:user)
 202
 203       response =
 204         conn
 205         |> assign(:user, user1)
 206         |> post("/api/v1/pleroma/notifications/read", %{"id" => "22222222222222"})
 207         |> json_response(:bad_request)
 208
 209       assert response == %{"error" => "Cannot get notification"}
 210     end
 211   end
 212 end