git.squeep.com Git - akkoma/blob - test/web/federator_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.FederatorTest do
   6   alias Pleroma.Instances
   7   alias Pleroma.Tests.ObanHelpers
   8   alias Pleroma.Web.CommonAPI
   9   alias Pleroma.Web.Federator
  10   alias Pleroma.Workers.PublisherWorker
  11
  12   use Pleroma.DataCase
  13   use Oban.Testing, repo: Pleroma.Repo
  14
  15   import Pleroma.Factory
  16   import Mock
  17
  18   setup_all do
  19     Tesla.Mock.mock_global(fn env -> apply(HttpRequestMock, :request, [env]) end)
  20
  21     :ok
  22   end
  23
  24   clear_config_all([:instance, :federating]) do
  25     Pleroma.Config.put([:instance, :federating], true)
  26   end
  27
  28   clear_config([:instance, :allow_relay])
  29   clear_config([:instance, :rewrite_policy])
  30   clear_config([:mrf_keyword])
  31
  32   describe "Publish an activity" do
  33     setup do
  34       user = insert(:user)
  35       {:ok, activity} = CommonAPI.post(user, %{"status" => "HI"})
  36
  37       relay_mock = {
  38         Pleroma.Web.ActivityPub.Relay,
  39         [],
  40         [publish: fn _activity -> send(self(), :relay_publish) end]
  41       }
  42
  43       %{activity: activity, relay_mock: relay_mock}
  44     end
  45
  46     test "with relays active, it publishes to the relay", %{
  47       activity: activity,
  48       relay_mock: relay_mock
  49     } do
  50       with_mocks([relay_mock]) do
  51         Federator.publish(activity)
  52         ObanHelpers.perform(all_enqueued(worker: PublisherWorker))
  53       end
  54
  55       assert_received :relay_publish
  56     end
  57
  58     test "with relays deactivated, it does not publish to the relay", %{
  59       activity: activity,
  60       relay_mock: relay_mock
  61     } do
  62       Pleroma.Config.put([:instance, :allow_relay], false)
  63
  64       with_mocks([relay_mock]) do
  65         Federator.publish(activity)
  66         ObanHelpers.perform(all_enqueued(worker: PublisherWorker))
  67       end
  68
  69       refute_received :relay_publish
  70     end
  71   end
  72
  73   describe "Targets reachability filtering in `publish`" do
  74     test "it federates only to reachable instances via AP" do
  75       user = insert(:user)
  76
  77       {inbox1, inbox2} =
  78         {"https://domain.com/users/nick1/inbox", "https://domain2.com/users/nick2/inbox"}
  79
  80       insert(:user, %{
  81         local: false,
  82         nickname: "nick1@domain.com",
  83         ap_id: "https://domain.com/users/nick1",
  84         info: %{ap_enabled: true, source_data: %{"inbox" => inbox1}}
  85       })
  86
  87       insert(:user, %{
  88         local: false,
  89         nickname: "nick2@domain2.com",
  90         ap_id: "https://domain2.com/users/nick2",
  91         info: %{ap_enabled: true, source_data: %{"inbox" => inbox2}}
  92       })
  93
  94       dt = NaiveDateTime.utc_now()
  95       Instances.set_unreachable(inbox1, dt)
  96
  97       Instances.set_consistently_unreachable(URI.parse(inbox2).host)
  98
  99       {:ok, _activity} =
 100         CommonAPI.post(user, %{"status" => "HI @nick1@domain.com, @nick2@domain2.com!"})
 101
 102       expected_dt = NaiveDateTime.to_iso8601(dt)
 103
 104       ObanHelpers.perform(all_enqueued(worker: PublisherWorker))
 105
 106       assert ObanHelpers.member?(
 107                %{
 108                  "op" => "publish_one",
 109                  "params" => %{"inbox" => inbox1, "unreachable_since" => expected_dt}
 110                },
 111                all_enqueued(worker: PublisherWorker)
 112              )
 113     end
 114   end
 115
 116   describe "Receive an activity" do
 117     test "successfully processes incoming AP docs with correct origin" do
 118       params = %{
 119         "@context" => "https://www.w3.org/ns/activitystreams",
 120         "actor" => "http://mastodon.example.org/users/admin",
 121         "type" => "Create",
 122         "id" => "http://mastodon.example.org/users/admin/activities/1",
 123         "object" => %{
 124           "type" => "Note",
 125           "content" => "hi world!",
 126           "id" => "http://mastodon.example.org/users/admin/objects/1",
 127           "attributedTo" => "http://mastodon.example.org/users/admin"
 128         },
 129         "to" => ["https://www.w3.org/ns/activitystreams#Public"]
 130       }
 131
 132       assert {:ok, job} = Federator.incoming_ap_doc(params)
 133       assert {:ok, _activity} = ObanHelpers.perform(job)
 134     end
 135
 136     test "rejects incoming AP docs with incorrect origin" do
 137       params = %{
 138         "@context" => "https://www.w3.org/ns/activitystreams",
 139         "actor" => "https://niu.moe/users/rye",
 140         "type" => "Create",
 141         "id" => "http://mastodon.example.org/users/admin/activities/1",
 142         "object" => %{
 143           "type" => "Note",
 144           "content" => "hi world!",
 145           "id" => "http://mastodon.example.org/users/admin/objects/1",
 146           "attributedTo" => "http://mastodon.example.org/users/admin"
 147         },
 148         "to" => ["https://www.w3.org/ns/activitystreams#Public"]
 149       }
 150
 151       assert {:ok, job} = Federator.incoming_ap_doc(params)
 152       assert :error = ObanHelpers.perform(job)
 153     end
 154
 155     test "it does not crash if MRF rejects the post" do
 156       Pleroma.Config.put([:mrf_keyword, :reject], ["lain"])
 157
 158       Pleroma.Config.put(
 159         [:instance, :rewrite_policy],
 160         Pleroma.Web.ActivityPub.MRF.KeywordPolicy
 161       )
 162
 163       params =
 164         File.read!("test/fixtures/mastodon-post-activity.json")
 165         |> Poison.decode!()
 166
 167       assert {:ok, job} = Federator.incoming_ap_doc(params)
 168       assert :error = ObanHelpers.perform(job)
 169     end
 170   end
 171 end