git.squeep.com Git - akkoma/blob - test/web/activity_pub/views/user_view_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.UserViewTest do
   6   use Pleroma.DataCase
   7   import Pleroma.Factory
   8
   9   alias Pleroma.User
  10   alias Pleroma.Web.ActivityPub.UserView
  11   alias Pleroma.Web.CommonAPI
  12
  13   test "Renders a user, including the public key" do
  14     user = insert(:user)
  15     {:ok, user} = User.ensure_keys_present(user)
  16
  17     result = UserView.render("user.json", %{user: user})
  18
  19     assert result["id"] == user.ap_id
  20     assert result["preferredUsername"] == user.nickname
  21
  22     assert String.contains?(result["publicKey"]["publicKeyPem"], "BEGIN PUBLIC KEY")
  23   end
  24
  25   test "Renders profile fields" do
  26     fields = [
  27       %{"name" => "foo", "value" => "bar"}
  28     ]
  29
  30     {:ok, user} =
  31       insert(:user)
  32       |> User.upgrade_changeset(%{info: %{fields: fields}})
  33       |> User.update_and_set_cache()
  34
  35     assert %{
  36              "attachment" => [%{"name" => "foo", "type" => "PropertyValue", "value" => "bar"}]
  37            } = UserView.render("user.json", %{user: user})
  38   end
  39
  40   test "Renders with emoji tags" do
  41     user = insert(:user, %{info: %{emoji: [%{"bib" => "/test"}]}})
  42
  43     assert %{
  44              "tag" => [
  45                %{
  46                  "icon" => %{"type" => "Image", "url" => "/test"},
  47                  "id" => "/test",
  48                  "name" => ":bib:",
  49                  "type" => "Emoji",
  50                  "updated" => "1970-01-01T00:00:00Z"
  51                }
  52              ]
  53            } = UserView.render("user.json", %{user: user})
  54   end
  55
  56   test "Does not add an avatar image if the user hasn't set one" do
  57     user = insert(:user)
  58     {:ok, user} = User.ensure_keys_present(user)
  59
  60     result = UserView.render("user.json", %{user: user})
  61     refute result["icon"]
  62     refute result["image"]
  63
  64     user =
  65       insert(:user,
  66         avatar: %{"url" => [%{"href" => "https://someurl"}]},
  67         info: %{
  68           banner: %{"url" => [%{"href" => "https://somebanner"}]}
  69         }
  70       )
  71
  72     {:ok, user} = User.ensure_keys_present(user)
  73
  74     result = UserView.render("user.json", %{user: user})
  75     assert result["icon"]["url"] == "https://someurl"
  76     assert result["image"]["url"] == "https://somebanner"
  77   end
  78
  79   test "renders an invisible user with the invisible property set to true" do
  80     user = insert(:user, %{info: %{invisible: true}})
  81
  82     assert %{"invisible" => true} = UserView.render("service.json", %{user: user})
  83   end
  84
  85   describe "endpoints" do
  86     test "local users have a usable endpoints structure" do
  87       user = insert(:user)
  88       {:ok, user} = User.ensure_keys_present(user)
  89
  90       result = UserView.render("user.json", %{user: user})
  91
  92       assert result["id"] == user.ap_id
  93
  94       %{
  95         "sharedInbox" => _,
  96         "oauthAuthorizationEndpoint" => _,
  97         "oauthRegistrationEndpoint" => _,
  98         "oauthTokenEndpoint" => _
  99       } = result["endpoints"]
 100     end
 101
 102     test "remote users have an empty endpoints structure" do
 103       user = insert(:user, local: false)
 104       {:ok, user} = User.ensure_keys_present(user)
 105
 106       result = UserView.render("user.json", %{user: user})
 107
 108       assert result["id"] == user.ap_id
 109       assert result["endpoints"] == %{}
 110     end
 111
 112     test "instance users do not expose oAuth endpoints" do
 113       user = insert(:user, nickname: nil, local: true)
 114       {:ok, user} = User.ensure_keys_present(user)
 115
 116       result = UserView.render("user.json", %{user: user})
 117
 118       refute result["endpoints"]["oauthAuthorizationEndpoint"]
 119       refute result["endpoints"]["oauthRegistrationEndpoint"]
 120       refute result["endpoints"]["oauthTokenEndpoint"]
 121     end
 122   end
 123
 124   describe "followers" do
 125     test "sets totalItems to zero when followers are hidden" do
 126       user = insert(:user)
 127       other_user = insert(:user)
 128       {:ok, _other_user, user, _activity} = CommonAPI.follow(other_user, user)
 129       assert %{"totalItems" => 1} = UserView.render("followers.json", %{user: user})
 130       info = Map.merge(user.info, %{hide_followers_count: true, hide_followers: true})
 131       user = Map.put(user, :info, info)
 132       assert %{"totalItems" => 0} = UserView.render("followers.json", %{user: user})
 133     end
 134
 135     test "sets correct totalItems when followers are hidden but the follower counter is not" do
 136       user = insert(:user)
 137       other_user = insert(:user)
 138       {:ok, _other_user, user, _activity} = CommonAPI.follow(other_user, user)
 139       assert %{"totalItems" => 1} = UserView.render("followers.json", %{user: user})
 140       info = Map.merge(user.info, %{hide_followers_count: false, hide_followers: true})
 141       user = Map.put(user, :info, info)
 142       assert %{"totalItems" => 1} = UserView.render("followers.json", %{user: user})
 143     end
 144   end
 145
 146   describe "following" do
 147     test "sets totalItems to zero when follows are hidden" do
 148       user = insert(:user)
 149       other_user = insert(:user)
 150       {:ok, user, _other_user, _activity} = CommonAPI.follow(user, other_user)
 151       assert %{"totalItems" => 1} = UserView.render("following.json", %{user: user})
 152       info = Map.merge(user.info, %{hide_follows_count: true, hide_follows: true})
 153       user = Map.put(user, :info, info)
 154       assert %{"totalItems" => 0} = UserView.render("following.json", %{user: user})
 155     end
 156
 157     test "sets correct totalItems when follows are hidden but the follow counter is not" do
 158       user = insert(:user)
 159       other_user = insert(:user)
 160       {:ok, user, _other_user, _activity} = CommonAPI.follow(user, other_user)
 161       assert %{"totalItems" => 1} = UserView.render("following.json", %{user: user})
 162       info = Map.merge(user.info, %{hide_follows_count: false, hide_follows: true})
 163       user = Map.put(user, :info, info)
 164       assert %{"totalItems" => 1} = UserView.render("following.json", %{user: user})
 165     end
 166   end
 167
 168   test "activity collection page aginates correctly" do
 169     user = insert(:user)
 170
 171     posts =
 172       for i <- 0..25 do
 173         {:ok, activity} = CommonAPI.post(user, %{"status" => "post #{i}"})
 174         activity
 175       end
 176
 177     # outbox sorts chronologically, newest first, with ten per page
 178     posts = Enum.reverse(posts)
 179
 180     %{"next" => next_url} =
 181       UserView.render("activity_collection_page.json", %{
 182         iri: "#{user.ap_id}/outbox",
 183         activities: Enum.take(posts, 10)
 184       })
 185
 186     next_id = Enum.at(posts, 9).id
 187     assert next_url =~ next_id
 188
 189     %{"next" => next_url} =
 190       UserView.render("activity_collection_page.json", %{
 191         iri: "#{user.ap_id}/outbox",
 192         activities: Enum.take(Enum.drop(posts, 10), 10)
 193       })
 194
 195     next_id = Enum.at(posts, 19).id
 196     assert next_url =~ next_id
 197   end
 198 end