git.squeep.com Git - akkoma/blob - test/web/activity_pub/activity_pub_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPubTest do
   6   use Pleroma.DataCase
   7   alias Pleroma.Web.ActivityPub.ActivityPub
   8   alias Pleroma.Web.ActivityPub.Utils
   9   alias Pleroma.Web.CommonAPI
  10   alias Pleroma.{Activity, Object, User, Instances}
  11   alias Pleroma.Builders.ActivityBuilder
  12
  13   import Pleroma.Factory
  14   import Tesla.Mock
  15   import Mock
  16
  17   setup do
  18     mock(fn env -> apply(HttpRequestMock, :request, [env]) end)
  19     :ok
  20   end
  21
  22   describe "fetching restricted by visibility" do
  23     test "it restricts by the appropriate visibility" do
  24       user = insert(:user)
  25
  26       {:ok, public_activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "public"})
  27
  28       {:ok, direct_activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "direct"})
  29
  30       {:ok, unlisted_activity} =
  31         CommonAPI.post(user, %{"status" => ".", "visibility" => "unlisted"})
  32
  33       {:ok, private_activity} =
  34         CommonAPI.post(user, %{"status" => ".", "visibility" => "private"})
  35
  36       activities =
  37         ActivityPub.fetch_activities([], %{:visibility => "direct", "actor_id" => user.ap_id})
  38
  39       assert activities == [direct_activity]
  40
  41       activities =
  42         ActivityPub.fetch_activities([], %{:visibility => "unlisted", "actor_id" => user.ap_id})
  43
  44       assert activities == [unlisted_activity]
  45
  46       activities =
  47         ActivityPub.fetch_activities([], %{:visibility => "private", "actor_id" => user.ap_id})
  48
  49       assert activities == [private_activity]
  50
  51       activities =
  52         ActivityPub.fetch_activities([], %{:visibility => "public", "actor_id" => user.ap_id})
  53
  54       assert activities == [public_activity]
  55     end
  56   end
  57
  58   describe "building a user from his ap id" do
  59     test "it returns a user" do
  60       user_id = "http://mastodon.example.org/users/admin"
  61       {:ok, user} = ActivityPub.make_user_from_ap_id(user_id)
  62       assert user.ap_id == user_id
  63       assert user.nickname == "admin@mastodon.example.org"
  64       assert user.info.source_data
  65       assert user.info.ap_enabled
  66       assert user.follower_address == "http://mastodon.example.org/users/admin/followers"
  67     end
  68   end
  69
  70   describe "insertion" do
  71     test "drops activities beyond a certain limit" do
  72       limit = Pleroma.Config.get([:instance, :remote_limit])
  73
  74       random_text =
  75         :crypto.strong_rand_bytes(limit + 1)
  76         |> Base.encode64()
  77         |> binary_part(0, limit + 1)
  78
  79       data = %{
  80         "ok" => true,
  81         "object" => %{
  82           "content" => random_text
  83         }
  84       }
  85
  86       assert {:error, {:remote_limit_error, _}} = ActivityPub.insert(data)
  87     end
  88
  89     test "returns the activity if one with the same id is already in" do
  90       activity = insert(:note_activity)
  91       {:ok, new_activity} = ActivityPub.insert(activity.data)
  92
  93       assert activity == new_activity
  94     end
  95
  96     test "inserts a given map into the activity database, giving it an id if it has none." do
  97       data = %{
  98         "ok" => true
  99       }
 100
 101       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 102       assert activity.data["ok"] == data["ok"]
 103       assert is_binary(activity.data["id"])
 104
 105       given_id = "bla"
 106
 107       data = %{
 108         "ok" => true,
 109         "id" => given_id,
 110         "context" => "blabla"
 111       }
 112
 113       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 114       assert activity.data["ok"] == data["ok"]
 115       assert activity.data["id"] == given_id
 116       assert activity.data["context"] == "blabla"
 117       assert activity.data["context_id"]
 118     end
 119
 120     test "adds a context when none is there" do
 121       data = %{
 122         "id" => "some_id",
 123         "object" => %{
 124           "id" => "object_id"
 125         }
 126       }
 127
 128       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 129
 130       assert is_binary(activity.data["context"])
 131       assert is_binary(activity.data["object"]["context"])
 132       assert activity.data["context_id"]
 133       assert activity.data["object"]["context_id"]
 134     end
 135
 136     test "adds an id to a given object if it lacks one and is a note and inserts it to the object database" do
 137       data = %{
 138         "object" => %{
 139           "type" => "Note",
 140           "ok" => true
 141         }
 142       }
 143
 144       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 145       assert is_binary(activity.data["object"]["id"])
 146       assert %Object{} = Object.get_by_ap_id(activity.data["object"]["id"])
 147     end
 148   end
 149
 150   describe "create activities" do
 151     test "removes doubled 'to' recipients" do
 152       user = insert(:user)
 153
 154       {:ok, activity} =
 155         ActivityPub.create(%{
 156           to: ["user1", "user1", "user2"],
 157           actor: user,
 158           context: "",
 159           object: %{}
 160         })
 161
 162       assert activity.data["to"] == ["user1", "user2"]
 163       assert activity.actor == user.ap_id
 164       assert activity.recipients == ["user1", "user2"]
 165     end
 166   end
 167
 168   describe "fetch activities for recipients" do
 169     test "retrieve the activities for certain recipients" do
 170       {:ok, activity_one} = ActivityBuilder.insert(%{"to" => ["someone"]})
 171       {:ok, activity_two} = ActivityBuilder.insert(%{"to" => ["someone_else"]})
 172       {:ok, _activity_three} = ActivityBuilder.insert(%{"to" => ["noone"]})
 173
 174       activities = ActivityPub.fetch_activities(["someone", "someone_else"])
 175       assert length(activities) == 2
 176       assert activities == [activity_one, activity_two]
 177     end
 178   end
 179
 180   describe "fetch activities in context" do
 181     test "retrieves activities that have a given context" do
 182       {:ok, activity} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 183       {:ok, activity_two} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 184       {:ok, _activity_three} = ActivityBuilder.insert(%{"type" => "Create", "context" => "3hu"})
 185       {:ok, _activity_four} = ActivityBuilder.insert(%{"type" => "Announce", "context" => "2hu"})
 186       activity_five = insert(:note_activity)
 187       user = insert(:user)
 188
 189       {:ok, user} = User.block(user, %{ap_id: activity_five.data["actor"]})
 190
 191       activities = ActivityPub.fetch_activities_for_context("2hu", %{"blocking_user" => user})
 192       assert activities == [activity_two, activity]
 193     end
 194   end
 195
 196   test "doesn't return blocked activities" do
 197     activity_one = insert(:note_activity)
 198     activity_two = insert(:note_activity)
 199     activity_three = insert(:note_activity)
 200     user = insert(:user)
 201     booster = insert(:user)
 202     {:ok, user} = User.block(user, %{ap_id: activity_one.data["actor"]})
 203
 204     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 205
 206     assert Enum.member?(activities, activity_two)
 207     assert Enum.member?(activities, activity_three)
 208     refute Enum.member?(activities, activity_one)
 209
 210     {:ok, user} = User.unblock(user, %{ap_id: activity_one.data["actor"]})
 211
 212     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 213
 214     assert Enum.member?(activities, activity_two)
 215     assert Enum.member?(activities, activity_three)
 216     assert Enum.member?(activities, activity_one)
 217
 218     {:ok, user} = User.block(user, %{ap_id: activity_three.data["actor"]})
 219     {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(activity_three.id, booster)
 220     %Activity{} = boost_activity = Activity.get_create_by_object_ap_id(id)
 221     activity_three = Repo.get(Activity, activity_three.id)
 222
 223     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 224
 225     assert Enum.member?(activities, activity_two)
 226     refute Enum.member?(activities, activity_three)
 227     refute Enum.member?(activities, boost_activity)
 228     assert Enum.member?(activities, activity_one)
 229
 230     activities = ActivityPub.fetch_activities([], %{"blocking_user" => nil})
 231
 232     assert Enum.member?(activities, activity_two)
 233     assert Enum.member?(activities, activity_three)
 234     assert Enum.member?(activities, boost_activity)
 235     assert Enum.member?(activities, activity_one)
 236   end
 237
 238   test "excludes reblogs on request" do
 239     user = insert(:user)
 240     {:ok, expected_activity} = ActivityBuilder.insert(%{"type" => "Create"}, %{:user => user})
 241     {:ok, _} = ActivityBuilder.insert(%{"type" => "Announce"}, %{:user => user})
 242
 243     [activity] = ActivityPub.fetch_user_activities(user, nil, %{"exclude_reblogs" => "true"})
 244
 245     assert activity == expected_activity
 246   end
 247
 248   describe "public fetch activities" do
 249     test "doesn't retrieve unlisted activities" do
 250       user = insert(:user)
 251
 252       {:ok, _unlisted_activity} =
 253         CommonAPI.post(user, %{"status" => "yeah", "visibility" => "unlisted"})
 254
 255       {:ok, listed_activity} = CommonAPI.post(user, %{"status" => "yeah"})
 256
 257       [activity] = ActivityPub.fetch_public_activities()
 258
 259       assert activity == listed_activity
 260     end
 261
 262     test "retrieves public activities" do
 263       _activities = ActivityPub.fetch_public_activities()
 264
 265       %{public: public} = ActivityBuilder.public_and_non_public()
 266
 267       activities = ActivityPub.fetch_public_activities()
 268       assert length(activities) == 1
 269       assert Enum.at(activities, 0) == public
 270     end
 271
 272     test "retrieves a maximum of 20 activities" do
 273       activities = ActivityBuilder.insert_list(30)
 274       last_expected = List.last(activities)
 275
 276       activities = ActivityPub.fetch_public_activities()
 277       last = List.last(activities)
 278
 279       assert length(activities) == 20
 280       assert last == last_expected
 281     end
 282
 283     test "retrieves ids starting from a since_id" do
 284       activities = ActivityBuilder.insert_list(30)
 285       later_activities = ActivityBuilder.insert_list(10)
 286       since_id = List.last(activities).id
 287       last_expected = List.last(later_activities)
 288
 289       activities = ActivityPub.fetch_public_activities(%{"since_id" => since_id})
 290       last = List.last(activities)
 291
 292       assert length(activities) == 10
 293       assert last == last_expected
 294     end
 295
 296     test "retrieves ids up to max_id" do
 297       _first_activities = ActivityBuilder.insert_list(10)
 298       activities = ActivityBuilder.insert_list(20)
 299       later_activities = ActivityBuilder.insert_list(10)
 300       max_id = List.first(later_activities).id
 301       last_expected = List.last(activities)
 302
 303       activities = ActivityPub.fetch_public_activities(%{"max_id" => max_id})
 304       last = List.last(activities)
 305
 306       assert length(activities) == 20
 307       assert last == last_expected
 308     end
 309   end
 310
 311   describe "like an object" do
 312     test "adds a like activity to the db" do
 313       note_activity = insert(:note_activity)
 314       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 315       user = insert(:user)
 316       user_two = insert(:user)
 317
 318       {:ok, like_activity, object} = ActivityPub.like(user, object)
 319
 320       assert like_activity.data["actor"] == user.ap_id
 321       assert like_activity.data["type"] == "Like"
 322       assert like_activity.data["object"] == object.data["id"]
 323       assert like_activity.data["to"] == [User.ap_followers(user), note_activity.data["actor"]]
 324       assert like_activity.data["context"] == object.data["context"]
 325       assert object.data["like_count"] == 1
 326       assert object.data["likes"] == [user.ap_id]
 327
 328       # Just return the original activity if the user already liked it.
 329       {:ok, same_like_activity, object} = ActivityPub.like(user, object)
 330
 331       assert like_activity == same_like_activity
 332       assert object.data["likes"] == [user.ap_id]
 333
 334       [note_activity] = Activity.get_all_create_by_object_ap_id(object.data["id"])
 335       assert note_activity.data["object"]["like_count"] == 1
 336
 337       {:ok, _like_activity, object} = ActivityPub.like(user_two, object)
 338       assert object.data["like_count"] == 2
 339     end
 340   end
 341
 342   describe "unliking" do
 343     test "unliking a previously liked object" do
 344       note_activity = insert(:note_activity)
 345       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 346       user = insert(:user)
 347
 348       # Unliking something that hasn't been liked does nothing
 349       {:ok, object} = ActivityPub.unlike(user, object)
 350       assert object.data["like_count"] == 0
 351
 352       {:ok, like_activity, object} = ActivityPub.like(user, object)
 353       assert object.data["like_count"] == 1
 354
 355       {:ok, _, _, object} = ActivityPub.unlike(user, object)
 356       assert object.data["like_count"] == 0
 357
 358       assert Repo.get(Activity, like_activity.id) == nil
 359     end
 360   end
 361
 362   describe "announcing an object" do
 363     test "adds an announce activity to the db" do
 364       note_activity = insert(:note_activity)
 365       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 366       user = insert(:user)
 367
 368       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 369       assert object.data["announcement_count"] == 1
 370       assert object.data["announcements"] == [user.ap_id]
 371
 372       assert announce_activity.data["to"] == [
 373                User.ap_followers(user),
 374                note_activity.data["actor"]
 375              ]
 376
 377       assert announce_activity.data["object"] == object.data["id"]
 378       assert announce_activity.data["actor"] == user.ap_id
 379       assert announce_activity.data["context"] == object.data["context"]
 380     end
 381   end
 382
 383   describe "unannouncing an object" do
 384     test "unannouncing a previously announced object" do
 385       note_activity = insert(:note_activity)
 386       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 387       user = insert(:user)
 388
 389       # Unannouncing an object that is not announced does nothing
 390       # {:ok, object} = ActivityPub.unannounce(user, object)
 391       # assert object.data["announcement_count"] == 0
 392
 393       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 394       assert object.data["announcement_count"] == 1
 395
 396       {:ok, unannounce_activity, object} = ActivityPub.unannounce(user, object)
 397       assert object.data["announcement_count"] == 0
 398
 399       assert unannounce_activity.data["to"] == [
 400                User.ap_followers(user),
 401                announce_activity.data["actor"]
 402              ]
 403
 404       assert unannounce_activity.data["type"] == "Undo"
 405       assert unannounce_activity.data["object"] == announce_activity.data
 406       assert unannounce_activity.data["actor"] == user.ap_id
 407       assert unannounce_activity.data["context"] == announce_activity.data["context"]
 408
 409       assert Repo.get(Activity, announce_activity.id) == nil
 410     end
 411   end
 412
 413   describe "uploading files" do
 414     test "copies the file to the configured folder" do
 415       file = %Plug.Upload{
 416         content_type: "image/jpg",
 417         path: Path.absname("test/fixtures/image.jpg"),
 418         filename: "an_image.jpg"
 419       }
 420
 421       {:ok, %Object{} = object} = ActivityPub.upload(file)
 422       assert object.data["name"] == "an_image.jpg"
 423     end
 424
 425     test "works with base64 encoded images" do
 426       file = %{
 427         "img" => data_uri()
 428       }
 429
 430       {:ok, %Object{}} = ActivityPub.upload(file)
 431     end
 432   end
 433
 434   describe "fetch the latest Follow" do
 435     test "fetches the latest Follow activity" do
 436       %Activity{data: %{"type" => "Follow"}} = activity = insert(:follow_activity)
 437       follower = Repo.get_by(User, ap_id: activity.data["actor"])
 438       followed = Repo.get_by(User, ap_id: activity.data["object"])
 439
 440       assert activity == Utils.fetch_latest_follow(follower, followed)
 441     end
 442   end
 443
 444   describe "fetching an object" do
 445     test "it fetches an object" do
 446       {:ok, object} =
 447         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 448
 449       assert activity = Activity.get_create_by_object_ap_id(object.data["id"])
 450       assert activity.data["id"]
 451
 452       {:ok, object_again} =
 453         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 454
 455       assert [attachment] = object.data["attachment"]
 456       assert is_list(attachment["url"])
 457
 458       assert object == object_again
 459     end
 460
 461     test "it works with objects only available via Ostatus" do
 462       {:ok, object} = ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 463       assert activity = Activity.get_create_by_object_ap_id(object.data["id"])
 464       assert activity.data["id"]
 465
 466       {:ok, object_again} =
 467         ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 468
 469       assert object == object_again
 470     end
 471
 472     test "it correctly stitches up conversations between ostatus and ap" do
 473       last = "https://mstdn.io/users/mayuutann/statuses/99568293732299394"
 474       {:ok, object} = ActivityPub.fetch_object_from_id(last)
 475
 476       object = Object.get_by_ap_id(object.data["inReplyTo"])
 477       assert object
 478     end
 479   end
 480
 481   describe "following / unfollowing" do
 482     test "creates a follow activity" do
 483       follower = insert(:user)
 484       followed = insert(:user)
 485
 486       {:ok, activity} = ActivityPub.follow(follower, followed)
 487       assert activity.data["type"] == "Follow"
 488       assert activity.data["actor"] == follower.ap_id
 489       assert activity.data["object"] == followed.ap_id
 490     end
 491
 492     test "creates an undo activity for the last follow" do
 493       follower = insert(:user)
 494       followed = insert(:user)
 495
 496       {:ok, follow_activity} = ActivityPub.follow(follower, followed)
 497       {:ok, activity} = ActivityPub.unfollow(follower, followed)
 498
 499       assert activity.data["type"] == "Undo"
 500       assert activity.data["actor"] == follower.ap_id
 501
 502       assert is_map(activity.data["object"])
 503       assert activity.data["object"]["type"] == "Follow"
 504       assert activity.data["object"]["object"] == followed.ap_id
 505       assert activity.data["object"]["id"] == follow_activity.data["id"]
 506     end
 507   end
 508
 509   describe "blocking / unblocking" do
 510     test "creates a block activity" do
 511       blocker = insert(:user)
 512       blocked = insert(:user)
 513
 514       {:ok, activity} = ActivityPub.block(blocker, blocked)
 515
 516       assert activity.data["type"] == "Block"
 517       assert activity.data["actor"] == blocker.ap_id
 518       assert activity.data["object"] == blocked.ap_id
 519     end
 520
 521     test "creates an undo activity for the last block" do
 522       blocker = insert(:user)
 523       blocked = insert(:user)
 524
 525       {:ok, block_activity} = ActivityPub.block(blocker, blocked)
 526       {:ok, activity} = ActivityPub.unblock(blocker, blocked)
 527
 528       assert activity.data["type"] == "Undo"
 529       assert activity.data["actor"] == blocker.ap_id
 530
 531       assert is_map(activity.data["object"])
 532       assert activity.data["object"]["type"] == "Block"
 533       assert activity.data["object"]["object"] == blocked.ap_id
 534       assert activity.data["object"]["id"] == block_activity.data["id"]
 535     end
 536   end
 537
 538   describe "deletion" do
 539     test "it creates a delete activity and deletes the original object" do
 540       note = insert(:note_activity)
 541       object = Object.get_by_ap_id(note.data["object"]["id"])
 542       {:ok, delete} = ActivityPub.delete(object)
 543
 544       assert delete.data["type"] == "Delete"
 545       assert delete.data["actor"] == note.data["actor"]
 546       assert delete.data["object"] == note.data["object"]["id"]
 547
 548       assert Repo.get(Activity, delete.id) != nil
 549
 550       assert Repo.get(Object, object.id).data["type"] == "Tombstone"
 551     end
 552   end
 553
 554   describe "timeline post-processing" do
 555     test "it filters broken threads" do
 556       user1 = insert(:user)
 557       user2 = insert(:user)
 558       user3 = insert(:user)
 559
 560       {:ok, user1} = User.follow(user1, user3)
 561       assert User.following?(user1, user3)
 562
 563       {:ok, user2} = User.follow(user2, user3)
 564       assert User.following?(user2, user3)
 565
 566       {:ok, user3} = User.follow(user3, user2)
 567       assert User.following?(user3, user2)
 568
 569       {:ok, public_activity} = CommonAPI.post(user3, %{"status" => "hi 1"})
 570
 571       {:ok, private_activity_1} =
 572         CommonAPI.post(user3, %{"status" => "hi 2", "visibility" => "private"})
 573
 574       {:ok, private_activity_2} =
 575         CommonAPI.post(user2, %{
 576           "status" => "hi 3",
 577           "visibility" => "private",
 578           "in_reply_to_status_id" => private_activity_1.id
 579         })
 580
 581       {:ok, private_activity_3} =
 582         CommonAPI.post(user3, %{
 583           "status" => "hi 4",
 584           "visibility" => "private",
 585           "in_reply_to_status_id" => private_activity_2.id
 586         })
 587
 588       assert user1.following == [user3.ap_id <> "/followers", user1.ap_id]
 589
 590       activities = ActivityPub.fetch_activities([user1.ap_id | user1.following])
 591
 592       assert [public_activity, private_activity_1, private_activity_3] == activities
 593       assert length(activities) == 3
 594
 595       activities = ActivityPub.contain_timeline(activities, user1)
 596
 597       assert [public_activity, private_activity_1] == activities
 598       assert length(activities) == 2
 599     end
 600   end
 601
 602   test "it can fetch plume articles" do
 603     {:ok, object} =
 604       ActivityPub.fetch_object_from_id(
 605         "https://baptiste.gelez.xyz/~/PlumeDevelopment/this-month-in-plume-june-2018/"
 606       )
 607
 608     assert object
 609   end
 610
 611   describe "update" do
 612     test "it creates an update activity with the new user data" do
 613       user = insert(:user)
 614       {:ok, user} = Pleroma.Web.WebFinger.ensure_keys_present(user)
 615       user_data = Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 616
 617       {:ok, update} =
 618         ActivityPub.update(%{
 619           actor: user_data["id"],
 620           to: [user.follower_address],
 621           cc: [],
 622           object: user_data
 623         })
 624
 625       assert update.data["actor"] == user.ap_id
 626       assert update.data["to"] == [user.follower_address]
 627       assert update.data["object"]["id"] == user_data["id"]
 628       assert update.data["object"]["type"] == user_data["type"]
 629     end
 630   end
 631
 632   test "it can fetch peertube videos" do
 633     {:ok, object} =
 634       ActivityPub.fetch_object_from_id(
 635         "https://peertube.moe/videos/watch/df5f464b-be8d-46fb-ad81-2d4c2d1630e3"
 636       )
 637
 638     assert object
 639   end
 640
 641   test "returned pinned statuses" do
 642     Pleroma.Config.put([:instance, :max_pinned_statuses], 3)
 643     user = insert(:user)
 644
 645     {:ok, activity_one} = CommonAPI.post(user, %{"status" => "HI!!!"})
 646     {:ok, activity_two} = CommonAPI.post(user, %{"status" => "HI!!!"})
 647     {:ok, activity_three} = CommonAPI.post(user, %{"status" => "HI!!!"})
 648
 649     CommonAPI.pin(activity_one.id, user)
 650     user = refresh_record(user)
 651
 652     CommonAPI.pin(activity_two.id, user)
 653     user = refresh_record(user)
 654
 655     CommonAPI.pin(activity_three.id, user)
 656     user = refresh_record(user)
 657
 658     activities = ActivityPub.fetch_user_activities(user, nil, %{"pinned" => "true"})
 659
 660     assert 3 = length(activities)
 661   end
 662
 663   describe "publish_one/1" do
 664     test_with_mock "it calls `Instances.set_unreachable` on target inbox on non-2xx HTTP response code",
 665                    Instances,
 666                    [:passthrough],
 667                    [] do
 668       actor = insert(:user)
 669       inbox = "http://404.site/users/nick1/inbox"
 670
 671       assert {:error, _} =
 672                ActivityPub.publish_one(%{inbox: inbox, json: "{}", actor: actor, id: 1})
 673
 674       assert called(Instances.set_unreachable(inbox))
 675     end
 676
 677     test_with_mock "it calls `Instances.set_unreachable` on target inbox on request error of any kind",
 678                    Instances,
 679                    [:passthrough],
 680                    [] do
 681       actor = insert(:user)
 682       inbox = "http://connrefused.site/users/nick1/inbox"
 683
 684       assert {:error, _} =
 685                ActivityPub.publish_one(%{inbox: inbox, json: "{}", actor: actor, id: 1})
 686
 687       assert called(Instances.set_unreachable(inbox))
 688     end
 689
 690     test_with_mock "it does NOT call `Instances.set_unreachable` if target is reachable",
 691                    Instances,
 692                    [:passthrough],
 693                    [] do
 694       actor = insert(:user)
 695       inbox = "http://200.site/users/nick1/inbox"
 696
 697       assert {:ok, _} = ActivityPub.publish_one(%{inbox: inbox, json: "{}", actor: actor, id: 1})
 698
 699       refute called(Instances.set_unreachable(inbox))
 700     end
 701   end
 702
 703   def data_uri do
 704     File.read!("test/fixtures/avatar_data_uri")
 705   end
 706 end