git.squeep.com Git - akkoma/blob - test/web/activity_pub/activity_pub_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPubTest do
   6   use Pleroma.DataCase
   7   alias Pleroma.Web.ActivityPub.ActivityPub
   8   alias Pleroma.Web.ActivityPub.Utils
   9   alias Pleroma.Web.CommonAPI
  10   alias Pleroma.{Activity, Object, User}
  11   alias Pleroma.Builders.ActivityBuilder
  12
  13   import Pleroma.Factory
  14   import Tesla.Mock
  15
  16   setup do
  17     mock(fn env -> apply(HttpRequestMock, :request, [env]) end)
  18     :ok
  19   end
  20
  21   describe "fetching restricted by visibility" do
  22     test "it restricts by the appropriate visibility" do
  23       user = insert(:user)
  24
  25       {:ok, public_activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "public"})
  26
  27       {:ok, direct_activity} = CommonAPI.post(user, %{"status" => ".", "visibility" => "direct"})
  28
  29       {:ok, unlisted_activity} =
  30         CommonAPI.post(user, %{"status" => ".", "visibility" => "unlisted"})
  31
  32       {:ok, private_activity} =
  33         CommonAPI.post(user, %{"status" => ".", "visibility" => "private"})
  34
  35       activities =
  36         ActivityPub.fetch_activities([], %{:visibility => "direct", "actor_id" => user.ap_id})
  37
  38       assert activities == [direct_activity]
  39
  40       activities =
  41         ActivityPub.fetch_activities([], %{:visibility => "unlisted", "actor_id" => user.ap_id})
  42
  43       assert activities == [unlisted_activity]
  44
  45       activities =
  46         ActivityPub.fetch_activities([], %{:visibility => "private", "actor_id" => user.ap_id})
  47
  48       assert activities == [private_activity]
  49
  50       activities =
  51         ActivityPub.fetch_activities([], %{:visibility => "public", "actor_id" => user.ap_id})
  52
  53       assert activities == [public_activity]
  54     end
  55   end
  56
  57   describe "building a user from his ap id" do
  58     test "it returns a user" do
  59       user_id = "http://mastodon.example.org/users/admin"
  60       {:ok, user} = ActivityPub.make_user_from_ap_id(user_id)
  61       assert user.ap_id == user_id
  62       assert user.nickname == "admin@mastodon.example.org"
  63       assert user.info.source_data
  64       assert user.info.ap_enabled
  65       assert user.follower_address == "http://mastodon.example.org/users/admin/followers"
  66     end
  67   end
  68
  69   describe "insertion" do
  70     test "drops activities beyond a certain limit" do
  71       limit = Pleroma.Config.get([:instance, :remote_limit])
  72
  73       random_text =
  74         :crypto.strong_rand_bytes(limit + 1)
  75         |> Base.encode64()
  76         |> binary_part(0, limit + 1)
  77
  78       data = %{
  79         "ok" => true,
  80         "object" => %{
  81           "content" => random_text
  82         }
  83       }
  84
  85       assert {:error, {:remote_limit_error, _}} = ActivityPub.insert(data)
  86     end
  87
  88     test "returns the activity if one with the same id is already in" do
  89       activity = insert(:note_activity)
  90       {:ok, new_activity} = ActivityPub.insert(activity.data)
  91
  92       assert activity == new_activity
  93     end
  94
  95     test "inserts a given map into the activity database, giving it an id if it has none." do
  96       data = %{
  97         "ok" => true
  98       }
  99
 100       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 101       assert activity.data["ok"] == data["ok"]
 102       assert is_binary(activity.data["id"])
 103
 104       given_id = "bla"
 105
 106       data = %{
 107         "ok" => true,
 108         "id" => given_id,
 109         "context" => "blabla"
 110       }
 111
 112       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 113       assert activity.data["ok"] == data["ok"]
 114       assert activity.data["id"] == given_id
 115       assert activity.data["context"] == "blabla"
 116       assert activity.data["context_id"]
 117     end
 118
 119     test "adds a context when none is there" do
 120       data = %{
 121         "id" => "some_id",
 122         "object" => %{
 123           "id" => "object_id"
 124         }
 125       }
 126
 127       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 128
 129       assert is_binary(activity.data["context"])
 130       assert is_binary(activity.data["object"]["context"])
 131       assert activity.data["context_id"]
 132       assert activity.data["object"]["context_id"]
 133     end
 134
 135     test "adds an id to a given object if it lacks one and is a note and inserts it to the object database" do
 136       data = %{
 137         "object" => %{
 138           "type" => "Note",
 139           "ok" => true
 140         }
 141       }
 142
 143       {:ok, %Activity{} = activity} = ActivityPub.insert(data)
 144       assert is_binary(activity.data["object"]["id"])
 145       assert %Object{} = Object.get_by_ap_id(activity.data["object"]["id"])
 146     end
 147   end
 148
 149   describe "create activities" do
 150     test "removes doubled 'to' recipients" do
 151       user = insert(:user)
 152
 153       {:ok, activity} =
 154         ActivityPub.create(%{
 155           to: ["user1", "user1", "user2"],
 156           actor: user,
 157           context: "",
 158           object: %{}
 159         })
 160
 161       assert activity.data["to"] == ["user1", "user2"]
 162       assert activity.actor == user.ap_id
 163       assert activity.recipients == ["user1", "user2"]
 164     end
 165   end
 166
 167   describe "fetch activities for recipients" do
 168     test "retrieve the activities for certain recipients" do
 169       {:ok, activity_one} = ActivityBuilder.insert(%{"to" => ["someone"]})
 170       {:ok, activity_two} = ActivityBuilder.insert(%{"to" => ["someone_else"]})
 171       {:ok, _activity_three} = ActivityBuilder.insert(%{"to" => ["noone"]})
 172
 173       activities = ActivityPub.fetch_activities(["someone", "someone_else"])
 174       assert length(activities) == 2
 175       assert activities == [activity_one, activity_two]
 176     end
 177   end
 178
 179   describe "fetch activities in context" do
 180     test "retrieves activities that have a given context" do
 181       {:ok, activity} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 182       {:ok, activity_two} = ActivityBuilder.insert(%{"type" => "Create", "context" => "2hu"})
 183       {:ok, _activity_three} = ActivityBuilder.insert(%{"type" => "Create", "context" => "3hu"})
 184       {:ok, _activity_four} = ActivityBuilder.insert(%{"type" => "Announce", "context" => "2hu"})
 185       activity_five = insert(:note_activity)
 186       user = insert(:user)
 187
 188       {:ok, user} = User.block(user, %{ap_id: activity_five.data["actor"]})
 189
 190       activities = ActivityPub.fetch_activities_for_context("2hu", %{"blocking_user" => user})
 191       assert activities == [activity_two, activity]
 192     end
 193   end
 194
 195   test "doesn't return blocked activities" do
 196     activity_one = insert(:note_activity)
 197     activity_two = insert(:note_activity)
 198     activity_three = insert(:note_activity)
 199     user = insert(:user)
 200     booster = insert(:user)
 201     {:ok, user} = User.block(user, %{ap_id: activity_one.data["actor"]})
 202
 203     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 204
 205     assert Enum.member?(activities, activity_two)
 206     assert Enum.member?(activities, activity_three)
 207     refute Enum.member?(activities, activity_one)
 208
 209     {:ok, user} = User.unblock(user, %{ap_id: activity_one.data["actor"]})
 210
 211     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 212
 213     assert Enum.member?(activities, activity_two)
 214     assert Enum.member?(activities, activity_three)
 215     assert Enum.member?(activities, activity_one)
 216
 217     {:ok, user} = User.block(user, %{ap_id: activity_three.data["actor"]})
 218     {:ok, _announce, %{data: %{"id" => id}}} = CommonAPI.repeat(activity_three.id, booster)
 219     %Activity{} = boost_activity = Activity.get_create_by_object_ap_id(id)
 220     activity_three = Repo.get(Activity, activity_three.id)
 221
 222     activities = ActivityPub.fetch_activities([], %{"blocking_user" => user})
 223
 224     assert Enum.member?(activities, activity_two)
 225     refute Enum.member?(activities, activity_three)
 226     refute Enum.member?(activities, boost_activity)
 227     assert Enum.member?(activities, activity_one)
 228
 229     activities = ActivityPub.fetch_activities([], %{"blocking_user" => nil})
 230
 231     assert Enum.member?(activities, activity_two)
 232     assert Enum.member?(activities, activity_three)
 233     assert Enum.member?(activities, boost_activity)
 234     assert Enum.member?(activities, activity_one)
 235   end
 236
 237   test "excludes reblogs on request" do
 238     user = insert(:user)
 239     {:ok, expected_activity} = ActivityBuilder.insert(%{"type" => "Create"}, %{:user => user})
 240     {:ok, _} = ActivityBuilder.insert(%{"type" => "Announce"}, %{:user => user})
 241
 242     [activity] = ActivityPub.fetch_user_activities(user, nil, %{"exclude_reblogs" => "true"})
 243
 244     assert activity == expected_activity
 245   end
 246
 247   describe "public fetch activities" do
 248     test "doesn't retrieve unlisted activities" do
 249       user = insert(:user)
 250
 251       {:ok, _unlisted_activity} =
 252         CommonAPI.post(user, %{"status" => "yeah", "visibility" => "unlisted"})
 253
 254       {:ok, listed_activity} = CommonAPI.post(user, %{"status" => "yeah"})
 255
 256       [activity] = ActivityPub.fetch_public_activities()
 257
 258       assert activity == listed_activity
 259     end
 260
 261     test "retrieves public activities" do
 262       _activities = ActivityPub.fetch_public_activities()
 263
 264       %{public: public} = ActivityBuilder.public_and_non_public()
 265
 266       activities = ActivityPub.fetch_public_activities()
 267       assert length(activities) == 1
 268       assert Enum.at(activities, 0) == public
 269     end
 270
 271     test "retrieves a maximum of 20 activities" do
 272       activities = ActivityBuilder.insert_list(30)
 273       last_expected = List.last(activities)
 274
 275       activities = ActivityPub.fetch_public_activities()
 276       last = List.last(activities)
 277
 278       assert length(activities) == 20
 279       assert last == last_expected
 280     end
 281
 282     test "retrieves ids starting from a since_id" do
 283       activities = ActivityBuilder.insert_list(30)
 284       later_activities = ActivityBuilder.insert_list(10)
 285       since_id = List.last(activities).id
 286       last_expected = List.last(later_activities)
 287
 288       activities = ActivityPub.fetch_public_activities(%{"since_id" => since_id})
 289       last = List.last(activities)
 290
 291       assert length(activities) == 10
 292       assert last == last_expected
 293     end
 294
 295     test "retrieves ids up to max_id" do
 296       _first_activities = ActivityBuilder.insert_list(10)
 297       activities = ActivityBuilder.insert_list(20)
 298       later_activities = ActivityBuilder.insert_list(10)
 299       max_id = List.first(later_activities).id
 300       last_expected = List.last(activities)
 301
 302       activities = ActivityPub.fetch_public_activities(%{"max_id" => max_id})
 303       last = List.last(activities)
 304
 305       assert length(activities) == 20
 306       assert last == last_expected
 307     end
 308   end
 309
 310   describe "like an object" do
 311     test "adds a like activity to the db" do
 312       note_activity = insert(:note_activity)
 313       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 314       user = insert(:user)
 315       user_two = insert(:user)
 316
 317       {:ok, like_activity, object} = ActivityPub.like(user, object)
 318
 319       assert like_activity.data["actor"] == user.ap_id
 320       assert like_activity.data["type"] == "Like"
 321       assert like_activity.data["object"] == object.data["id"]
 322       assert like_activity.data["to"] == [User.ap_followers(user), note_activity.data["actor"]]
 323       assert like_activity.data["context"] == object.data["context"]
 324       assert object.data["like_count"] == 1
 325       assert object.data["likes"] == [user.ap_id]
 326
 327       # Just return the original activity if the user already liked it.
 328       {:ok, same_like_activity, object} = ActivityPub.like(user, object)
 329
 330       assert like_activity == same_like_activity
 331       assert object.data["likes"] == [user.ap_id]
 332
 333       [note_activity] = Activity.get_all_create_by_object_ap_id(object.data["id"])
 334       assert note_activity.data["object"]["like_count"] == 1
 335
 336       {:ok, _like_activity, object} = ActivityPub.like(user_two, object)
 337       assert object.data["like_count"] == 2
 338     end
 339   end
 340
 341   describe "unliking" do
 342     test "unliking a previously liked object" do
 343       note_activity = insert(:note_activity)
 344       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 345       user = insert(:user)
 346
 347       # Unliking something that hasn't been liked does nothing
 348       {:ok, object} = ActivityPub.unlike(user, object)
 349       assert object.data["like_count"] == 0
 350
 351       {:ok, like_activity, object} = ActivityPub.like(user, object)
 352       assert object.data["like_count"] == 1
 353
 354       {:ok, _, _, object} = ActivityPub.unlike(user, object)
 355       assert object.data["like_count"] == 0
 356
 357       assert Repo.get(Activity, like_activity.id) == nil
 358     end
 359   end
 360
 361   describe "announcing an object" do
 362     test "adds an announce activity to the db" do
 363       note_activity = insert(:note_activity)
 364       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 365       user = insert(:user)
 366
 367       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 368       assert object.data["announcement_count"] == 1
 369       assert object.data["announcements"] == [user.ap_id]
 370
 371       assert announce_activity.data["to"] == [
 372                User.ap_followers(user),
 373                note_activity.data["actor"]
 374              ]
 375
 376       assert announce_activity.data["object"] == object.data["id"]
 377       assert announce_activity.data["actor"] == user.ap_id
 378       assert announce_activity.data["context"] == object.data["context"]
 379     end
 380   end
 381
 382   describe "unannouncing an object" do
 383     test "unannouncing a previously announced object" do
 384       note_activity = insert(:note_activity)
 385       object = Object.get_by_ap_id(note_activity.data["object"]["id"])
 386       user = insert(:user)
 387
 388       # Unannouncing an object that is not announced does nothing
 389       # {:ok, object} = ActivityPub.unannounce(user, object)
 390       # assert object.data["announcement_count"] == 0
 391
 392       {:ok, announce_activity, object} = ActivityPub.announce(user, object)
 393       assert object.data["announcement_count"] == 1
 394
 395       {:ok, unannounce_activity, object} = ActivityPub.unannounce(user, object)
 396       assert object.data["announcement_count"] == 0
 397
 398       assert unannounce_activity.data["to"] == [
 399                User.ap_followers(user),
 400                announce_activity.data["actor"]
 401              ]
 402
 403       assert unannounce_activity.data["type"] == "Undo"
 404       assert unannounce_activity.data["object"] == announce_activity.data
 405       assert unannounce_activity.data["actor"] == user.ap_id
 406       assert unannounce_activity.data["context"] == announce_activity.data["context"]
 407
 408       assert Repo.get(Activity, announce_activity.id) == nil
 409     end
 410   end
 411
 412   describe "uploading files" do
 413     test "copies the file to the configured folder" do
 414       file = %Plug.Upload{
 415         content_type: "image/jpg",
 416         path: Path.absname("test/fixtures/image.jpg"),
 417         filename: "an_image.jpg"
 418       }
 419
 420       {:ok, %Object{} = object} = ActivityPub.upload(file)
 421       assert object.data["name"] == "an_image.jpg"
 422     end
 423
 424     test "works with base64 encoded images" do
 425       file = %{
 426         "img" => data_uri()
 427       }
 428
 429       {:ok, %Object{}} = ActivityPub.upload(file)
 430     end
 431   end
 432
 433   describe "fetch the latest Follow" do
 434     test "fetches the latest Follow activity" do
 435       %Activity{data: %{"type" => "Follow"}} = activity = insert(:follow_activity)
 436       follower = Repo.get_by(User, ap_id: activity.data["actor"])
 437       followed = Repo.get_by(User, ap_id: activity.data["object"])
 438
 439       assert activity == Utils.fetch_latest_follow(follower, followed)
 440     end
 441   end
 442
 443   describe "fetching an object" do
 444     test "it fetches an object" do
 445       {:ok, object} =
 446         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 447
 448       assert activity = Activity.get_create_by_object_ap_id(object.data["id"])
 449       assert activity.data["id"]
 450
 451       {:ok, object_again} =
 452         ActivityPub.fetch_object_from_id("http://mastodon.example.org/@admin/99541947525187367")
 453
 454       assert [attachment] = object.data["attachment"]
 455       assert is_list(attachment["url"])
 456
 457       assert object == object_again
 458     end
 459
 460     test "it works with objects only available via Ostatus" do
 461       {:ok, object} = ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 462       assert activity = Activity.get_create_by_object_ap_id(object.data["id"])
 463       assert activity.data["id"]
 464
 465       {:ok, object_again} =
 466         ActivityPub.fetch_object_from_id("https://shitposter.club/notice/2827873")
 467
 468       assert object == object_again
 469     end
 470
 471     test "it correctly stitches up conversations between ostatus and ap" do
 472       last = "https://mstdn.io/users/mayuutann/statuses/99568293732299394"
 473       {:ok, object} = ActivityPub.fetch_object_from_id(last)
 474
 475       object = Object.get_by_ap_id(object.data["inReplyTo"])
 476       assert object
 477     end
 478   end
 479
 480   describe "following / unfollowing" do
 481     test "creates a follow activity" do
 482       follower = insert(:user)
 483       followed = insert(:user)
 484
 485       {:ok, activity} = ActivityPub.follow(follower, followed)
 486       assert activity.data["type"] == "Follow"
 487       assert activity.data["actor"] == follower.ap_id
 488       assert activity.data["object"] == followed.ap_id
 489     end
 490
 491     test "creates an undo activity for the last follow" do
 492       follower = insert(:user)
 493       followed = insert(:user)
 494
 495       {:ok, follow_activity} = ActivityPub.follow(follower, followed)
 496       {:ok, activity} = ActivityPub.unfollow(follower, followed)
 497
 498       assert activity.data["type"] == "Undo"
 499       assert activity.data["actor"] == follower.ap_id
 500
 501       assert is_map(activity.data["object"])
 502       assert activity.data["object"]["type"] == "Follow"
 503       assert activity.data["object"]["object"] == followed.ap_id
 504       assert activity.data["object"]["id"] == follow_activity.data["id"]
 505     end
 506   end
 507
 508   describe "blocking / unblocking" do
 509     test "creates a block activity" do
 510       blocker = insert(:user)
 511       blocked = insert(:user)
 512
 513       {:ok, activity} = ActivityPub.block(blocker, blocked)
 514
 515       assert activity.data["type"] == "Block"
 516       assert activity.data["actor"] == blocker.ap_id
 517       assert activity.data["object"] == blocked.ap_id
 518     end
 519
 520     test "creates an undo activity for the last block" do
 521       blocker = insert(:user)
 522       blocked = insert(:user)
 523
 524       {:ok, block_activity} = ActivityPub.block(blocker, blocked)
 525       {:ok, activity} = ActivityPub.unblock(blocker, blocked)
 526
 527       assert activity.data["type"] == "Undo"
 528       assert activity.data["actor"] == blocker.ap_id
 529
 530       assert is_map(activity.data["object"])
 531       assert activity.data["object"]["type"] == "Block"
 532       assert activity.data["object"]["object"] == blocked.ap_id
 533       assert activity.data["object"]["id"] == block_activity.data["id"]
 534     end
 535   end
 536
 537   describe "deletion" do
 538     test "it creates a delete activity and deletes the original object" do
 539       note = insert(:note_activity)
 540       object = Object.get_by_ap_id(note.data["object"]["id"])
 541       {:ok, delete} = ActivityPub.delete(object)
 542
 543       assert delete.data["type"] == "Delete"
 544       assert delete.data["actor"] == note.data["actor"]
 545       assert delete.data["object"] == note.data["object"]["id"]
 546
 547       assert Repo.get(Activity, delete.id) != nil
 548
 549       assert Repo.get(Object, object.id).data["type"] == "Tombstone"
 550     end
 551   end
 552
 553   describe "timeline post-processing" do
 554     test "it filters broken threads" do
 555       user1 = insert(:user)
 556       user2 = insert(:user)
 557       user3 = insert(:user)
 558
 559       {:ok, user1} = User.follow(user1, user3)
 560       assert User.following?(user1, user3)
 561
 562       {:ok, user2} = User.follow(user2, user3)
 563       assert User.following?(user2, user3)
 564
 565       {:ok, user3} = User.follow(user3, user2)
 566       assert User.following?(user3, user2)
 567
 568       {:ok, public_activity} = CommonAPI.post(user3, %{"status" => "hi 1"})
 569
 570       {:ok, private_activity_1} =
 571         CommonAPI.post(user3, %{"status" => "hi 2", "visibility" => "private"})
 572
 573       {:ok, private_activity_2} =
 574         CommonAPI.post(user2, %{
 575           "status" => "hi 3",
 576           "visibility" => "private",
 577           "in_reply_to_status_id" => private_activity_1.id
 578         })
 579
 580       {:ok, private_activity_3} =
 581         CommonAPI.post(user3, %{
 582           "status" => "hi 4",
 583           "visibility" => "private",
 584           "in_reply_to_status_id" => private_activity_2.id
 585         })
 586
 587       assert user1.following == [user3.ap_id <> "/followers", user1.ap_id]
 588
 589       activities = ActivityPub.fetch_activities([user1.ap_id | user1.following])
 590
 591       assert [public_activity, private_activity_1, private_activity_3] == activities
 592       assert length(activities) == 3
 593
 594       activities = ActivityPub.contain_timeline(activities, user1)
 595
 596       assert [public_activity, private_activity_1] == activities
 597       assert length(activities) == 2
 598     end
 599   end
 600
 601   test "it can fetch plume articles" do
 602     {:ok, object} =
 603       ActivityPub.fetch_object_from_id(
 604         "https://baptiste.gelez.xyz/~/PlumeDevelopment/this-month-in-plume-june-2018/"
 605       )
 606
 607     assert object
 608   end
 609
 610   describe "update" do
 611     test "it creates an update activity with the new user data" do
 612       user = insert(:user)
 613       {:ok, user} = Pleroma.Web.WebFinger.ensure_keys_present(user)
 614       user_data = Pleroma.Web.ActivityPub.UserView.render("user.json", %{user: user})
 615
 616       {:ok, update} =
 617         ActivityPub.update(%{
 618           actor: user_data["id"],
 619           to: [user.follower_address],
 620           cc: [],
 621           object: user_data
 622         })
 623
 624       assert update.data["actor"] == user.ap_id
 625       assert update.data["to"] == [user.follower_address]
 626       assert update.data["object"]["id"] == user_data["id"]
 627       assert update.data["object"]["type"] == user_data["type"]
 628     end
 629   end
 630
 631   test "it can fetch peertube videos" do
 632     {:ok, object} =
 633       ActivityPub.fetch_object_from_id(
 634         "https://peertube.moe/videos/watch/df5f464b-be8d-46fb-ad81-2d4c2d1630e3"
 635       )
 636
 637     assert object
 638   end
 639
 640   test "returned pinned statuses" do
 641     Pleroma.Config.put([:instance, :max_pinned_statuses], 3)
 642     user = insert(:user)
 643
 644     {:ok, activity_one} = CommonAPI.post(user, %{"status" => "HI!!!"})
 645     {:ok, activity_two} = CommonAPI.post(user, %{"status" => "HI!!!"})
 646     {:ok, activity_three} = CommonAPI.post(user, %{"status" => "HI!!!"})
 647
 648     CommonAPI.pin(activity_one.id, user)
 649     user = refresh_record(user)
 650
 651     CommonAPI.pin(activity_two.id, user)
 652     user = refresh_record(user)
 653
 654     CommonAPI.pin(activity_three.id, user)
 655     user = refresh_record(user)
 656
 657     activities = ActivityPub.fetch_user_activities(user, nil, %{"pinned" => "true"})
 658
 659     assert 3 = length(activities)
 660   end
 661
 662   def data_uri do
 663     File.read!("test/fixtures/avatar_data_uri")
 664   end
 665 end