git.squeep.com Git - akkoma/blob - test/web/activity_pub/activity_pub_controller_test.exs

   1 defmodule Pleroma.Web.ActivityPub.ActivityPubControllerTest do
   2   use Pleroma.Web.ConnCase
   3   import Pleroma.Factory
   4   alias Pleroma.Web.ActivityPub.{UserView, ObjectView}
   5   alias Pleroma.{Repo, User}
   6   alias Pleroma.Activity
   7
   8   describe "/users/:nickname" do
   9     test "it returns a json representation of the user", %{conn: conn} do
  10       user = insert(:user)
  11
  12       conn =
  13         conn
  14         |> put_req_header("accept", "application/activity+json")
  15         |> get("/users/#{user.nickname}")
  16
  17       user = Repo.get(User, user.id)
  18
  19       assert json_response(conn, 200) == UserView.render("user.json", %{user: user})
  20     end
  21   end
  22
  23   describe "/object/:uuid" do
  24     test "it returns a json representation of the object", %{conn: conn} do
  25       note = insert(:note)
  26       uuid = String.split(note.data["id"], "/") |> List.last()
  27
  28       conn =
  29         conn
  30         |> put_req_header("accept", "application/activity+json")
  31         |> get("/objects/#{uuid}")
  32
  33       assert json_response(conn, 200) == ObjectView.render("object.json", %{object: note})
  34     end
  35   end
  36
  37   describe "/users/:nickname/inbox" do
  38     test "it inserts an incoming activity into the database", %{conn: conn} do
  39       data = File.read!("test/fixtures/mastodon-post-activity.json") |> Poison.decode!()
  40
  41       conn =
  42         conn
  43         |> assign(:valid_signature, true)
  44         |> put_req_header("content-type", "application/activity+json")
  45         |> post("/inbox", data)
  46
  47       assert "ok" == json_response(conn, 200)
  48       :timer.sleep(500)
  49       assert Activity.get_by_ap_id(data["id"])
  50     end
  51   end
  52
  53   describe "/users/:nickname/outbox" do
  54     test "it returns a note action in a collection", %{conn: conn} do
  55       note_activity = insert(:note_activity)
  56       user = User.get_cached_by_ap_id(note_activity.data["actor"])
  57
  58       conn =
  59         conn
  60         |> put_req_header("accept", "application/activity+json")
  61         |> get("/users/#{user.nickname}/outbox")
  62
  63       assert response(conn, 200) =~ note_activity.data["object"]["content"]
  64     end
  65   end
  66
  67   describe "/users/:nickname/followers" do
  68     test "it returns the followers in a collection", %{conn: conn} do
  69       user = insert(:user)
  70       user_two = insert(:user)
  71       User.follow(user, user_two)
  72
  73       result =
  74         conn
  75         |> get("/users/#{user_two.nickname}/followers")
  76         |> json_response(200)
  77
  78       assert result["first"]["orderedItems"] == [user.ap_id]
  79     end
  80
  81     test "it works for more than 10 users", %{conn: conn} do
  82       user = insert(:user)
  83
  84       Enum.each(1..15, fn _ ->
  85         other_user = insert(:user)
  86         User.follow(other_user, user)
  87       end)
  88
  89       result =
  90         conn
  91         |> get("/users/#{user.nickname}/followers")
  92         |> json_response(200)
  93
  94       assert length(result["first"]["orderedItems"]) == 10
  95       assert result["first"]["totalItems"] == 15
  96       assert result["totalItems"] == 15
  97
  98       result =
  99         conn
 100         |> get("/users/#{user.nickname}/followers?page=2")
 101         |> json_response(200)
 102
 103       assert length(result["orderedItems"]) == 5
 104       assert result["totalItems"] == 15
 105     end
 106   end
 107
 108   describe "/users/:nickname/following" do
 109     test "it returns the following in a collection", %{conn: conn} do
 110       user = insert(:user)
 111       user_two = insert(:user)
 112       User.follow(user, user_two)
 113
 114       result =
 115         conn
 116         |> get("/users/#{user.nickname}/following")
 117         |> json_response(200)
 118
 119       assert result["first"]["orderedItems"] == [user_two.ap_id]
 120     end
 121
 122     test "it works for more than 10 users", %{conn: conn} do
 123       user = insert(:user)
 124
 125       Enum.each(1..15, fn _ ->
 126         user = Repo.get(User, user.id)
 127         other_user = insert(:user)
 128         User.follow(user, other_user)
 129       end)
 130
 131       result =
 132         conn
 133         |> get("/users/#{user.nickname}/following")
 134         |> json_response(200)
 135
 136       assert length(result["first"]["orderedItems"]) == 10
 137       assert result["first"]["totalItems"] == 15
 138       assert result["totalItems"] == 15
 139
 140       result =
 141         conn
 142         |> get("/users/#{user.nickname}/following?page=2")
 143         |> json_response(200)
 144
 145       assert length(result["orderedItems"]) == 5
 146       assert result["totalItems"] == 15
 147     end
 148   end
 149 end