git.squeep.com Git - akkoma/blob - test/web/activity_pub/activity_pub_controller_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ActivityPubControllerTest do
   6   use Pleroma.Web.ConnCase
   7   import Pleroma.Factory
   8   alias Pleroma.Web.ActivityPub.{UserView, ObjectView}
   9   alias Pleroma.{Repo, User}
  10   alias Pleroma.Activity
  11
  12   setup_all do
  13     Tesla.Mock.mock_global(fn env -> apply(HttpRequestMock, :request, [env]) end)
  14     :ok
  15   end
  16
  17   describe "/relay" do
  18     test "with the relay active, it returns the relay user", %{conn: conn} do
  19       res =
  20         conn
  21         |> get(activity_pub_path(conn, :relay))
  22         |> json_response(200)
  23
  24       assert res["id"] =~ "/relay"
  25     end
  26
  27     test "with the relay disabled, it returns 404", %{conn: conn} do
  28       Pleroma.Config.put([:instance, :allow_relay], false)
  29
  30       conn
  31       |> get(activity_pub_path(conn, :relay))
  32       |> json_response(404)
  33       |> assert
  34
  35       Pleroma.Config.put([:instance, :allow_relay], true)
  36     end
  37   end
  38
  39   describe "/users/:nickname" do
  40     test "it returns a json representation of the user", %{conn: conn} do
  41       user = insert(:user)
  42
  43       conn =
  44         conn
  45         |> put_req_header("accept", "application/activity+json")
  46         |> get("/users/#{user.nickname}")
  47
  48       user = Repo.get(User, user.id)
  49
  50       assert json_response(conn, 200) == UserView.render("user.json", %{user: user})
  51     end
  52   end
  53
  54   describe "/object/:uuid" do
  55     test "it returns a json representation of the object", %{conn: conn} do
  56       note = insert(:note)
  57       uuid = String.split(note.data["id"], "/") |> List.last()
  58
  59       conn =
  60         conn
  61         |> put_req_header("accept", "application/activity+json")
  62         |> get("/objects/#{uuid}")
  63
  64       assert json_response(conn, 200) == ObjectView.render("object.json", %{object: note})
  65     end
  66
  67     test "it returns 404 for non-public messages", %{conn: conn} do
  68       note = insert(:direct_note)
  69       uuid = String.split(note.data["id"], "/") |> List.last()
  70
  71       conn =
  72         conn
  73         |> put_req_header("accept", "application/activity+json")
  74         |> get("/objects/#{uuid}")
  75
  76       assert json_response(conn, 404)
  77     end
  78   end
  79
  80   describe "/inbox" do
  81     test "it inserts an incoming activity into the database", %{conn: conn} do
  82       data = File.read!("test/fixtures/mastodon-post-activity.json") |> Poison.decode!()
  83
  84       conn =
  85         conn
  86         |> assign(:valid_signature, true)
  87         |> put_req_header("content-type", "application/activity+json")
  88         |> post("/inbox", data)
  89
  90       assert "ok" == json_response(conn, 200)
  91       :timer.sleep(500)
  92       assert Activity.get_by_ap_id(data["id"])
  93     end
  94   end
  95
  96   describe "/users/:nickname/inbox" do
  97     test "it inserts an incoming activity into the database", %{conn: conn} do
  98       user = insert(:user)
  99
 100       data =
 101         File.read!("test/fixtures/mastodon-post-activity.json")
 102         |> Poison.decode!()
 103         |> Map.put("bcc", [user.ap_id])
 104
 105       conn =
 106         conn
 107         |> assign(:valid_signature, true)
 108         |> put_req_header("content-type", "application/activity+json")
 109         |> post("/users/#{user.nickname}/inbox", data)
 110
 111       assert "ok" == json_response(conn, 200)
 112       :timer.sleep(500)
 113       assert Activity.get_by_ap_id(data["id"])
 114     end
 115
 116     test "it rejects reads from other users", %{conn: conn} do
 117       user = insert(:user)
 118       otheruser = insert(:user)
 119
 120       conn =
 121         conn
 122         |> assign(:user, otheruser)
 123         |> put_req_header("accept", "application/activity+json")
 124         |> get("/users/#{user.nickname}/inbox")
 125
 126       assert json_response(conn, 403)
 127     end
 128
 129     test "it returns a note activity in a collection", %{conn: conn} do
 130       note_activity = insert(:direct_note_activity)
 131       user = User.get_cached_by_ap_id(hd(note_activity.data["to"]))
 132
 133       conn =
 134         conn
 135         |> assign(:user, user)
 136         |> put_req_header("accept", "application/activity+json")
 137         |> get("/users/#{user.nickname}/inbox")
 138
 139       assert response(conn, 200) =~ note_activity.data["object"]["content"]
 140     end
 141   end
 142
 143   describe "/users/:nickname/outbox" do
 144     test "it returns a note activity in a collection", %{conn: conn} do
 145       note_activity = insert(:note_activity)
 146       user = User.get_cached_by_ap_id(note_activity.data["actor"])
 147
 148       conn =
 149         conn
 150         |> put_req_header("accept", "application/activity+json")
 151         |> get("/users/#{user.nickname}/outbox")
 152
 153       assert response(conn, 200) =~ note_activity.data["object"]["content"]
 154     end
 155
 156     test "it returns an announce activity in a collection", %{conn: conn} do
 157       announce_activity = insert(:announce_activity)
 158       user = User.get_cached_by_ap_id(announce_activity.data["actor"])
 159
 160       conn =
 161         conn
 162         |> put_req_header("accept", "application/activity+json")
 163         |> get("/users/#{user.nickname}/outbox")
 164
 165       assert response(conn, 200) =~ announce_activity.data["object"]
 166     end
 167
 168     test "it rejects posts from other users", %{conn: conn} do
 169       data = File.read!("test/fixtures/activitypub-client-post-activity.json") |> Poison.decode!()
 170       user = insert(:user)
 171       otheruser = insert(:user)
 172
 173       conn =
 174         conn
 175         |> assign(:user, otheruser)
 176         |> put_req_header("content-type", "application/activity+json")
 177         |> post("/users/#{user.nickname}/outbox", data)
 178
 179       assert json_response(conn, 403)
 180     end
 181
 182     test "it inserts an incoming activity into the database", %{conn: conn} do
 183       data = File.read!("test/fixtures/activitypub-client-post-activity.json") |> Poison.decode!()
 184       user = insert(:user)
 185
 186       conn =
 187         conn
 188         |> assign(:user, user)
 189         |> put_req_header("content-type", "application/activity+json")
 190         |> post("/users/#{user.nickname}/outbox", data)
 191
 192       result = json_response(conn, 201)
 193       assert Activity.get_by_ap_id(result["id"])
 194     end
 195
 196     test "it rejects an incoming activity with bogus type", %{conn: conn} do
 197       data = File.read!("test/fixtures/activitypub-client-post-activity.json") |> Poison.decode!()
 198       user = insert(:user)
 199
 200       data =
 201         data
 202         |> Map.put("type", "BadType")
 203
 204       conn =
 205         conn
 206         |> assign(:user, user)
 207         |> put_req_header("content-type", "application/activity+json")
 208         |> post("/users/#{user.nickname}/outbox", data)
 209
 210       assert json_response(conn, 400)
 211     end
 212   end
 213
 214   describe "/users/:nickname/followers" do
 215     test "it returns the followers in a collection", %{conn: conn} do
 216       user = insert(:user)
 217       user_two = insert(:user)
 218       User.follow(user, user_two)
 219
 220       result =
 221         conn
 222         |> get("/users/#{user_two.nickname}/followers")
 223         |> json_response(200)
 224
 225       assert result["first"]["orderedItems"] == [user.ap_id]
 226     end
 227
 228     test "it returns returns empty if the user has 'hide_network' set", %{conn: conn} do
 229       user = insert(:user)
 230       user_two = insert(:user, %{info: %{hide_network: true}})
 231       User.follow(user, user_two)
 232
 233       result =
 234         conn
 235         |> get("/users/#{user_two.nickname}/followers")
 236         |> json_response(200)
 237
 238       assert result["first"]["orderedItems"] == []
 239       assert result["totalItems"] == 1
 240     end
 241
 242     test "it works for more than 10 users", %{conn: conn} do
 243       user = insert(:user)
 244
 245       Enum.each(1..15, fn _ ->
 246         other_user = insert(:user)
 247         User.follow(other_user, user)
 248       end)
 249
 250       result =
 251         conn
 252         |> get("/users/#{user.nickname}/followers")
 253         |> json_response(200)
 254
 255       assert length(result["first"]["orderedItems"]) == 10
 256       assert result["first"]["totalItems"] == 15
 257       assert result["totalItems"] == 15
 258
 259       result =
 260         conn
 261         |> get("/users/#{user.nickname}/followers?page=2")
 262         |> json_response(200)
 263
 264       assert length(result["orderedItems"]) == 5
 265       assert result["totalItems"] == 15
 266     end
 267   end
 268
 269   describe "/users/:nickname/following" do
 270     test "it returns the following in a collection", %{conn: conn} do
 271       user = insert(:user)
 272       user_two = insert(:user)
 273       User.follow(user, user_two)
 274
 275       result =
 276         conn
 277         |> get("/users/#{user.nickname}/following")
 278         |> json_response(200)
 279
 280       assert result["first"]["orderedItems"] == [user_two.ap_id]
 281     end
 282
 283     test "it returns returns empty if the user has 'hide_network' set", %{conn: conn} do
 284       user = insert(:user, %{info: %{hide_network: true}})
 285       user_two = insert(:user)
 286       User.follow(user, user_two)
 287
 288       result =
 289         conn
 290         |> get("/users/#{user.nickname}/following")
 291         |> json_response(200)
 292
 293       assert result["first"]["orderedItems"] == []
 294       assert result["totalItems"] == 1
 295     end
 296
 297     test "it works for more than 10 users", %{conn: conn} do
 298       user = insert(:user)
 299
 300       Enum.each(1..15, fn _ ->
 301         user = Repo.get(User, user.id)
 302         other_user = insert(:user)
 303         User.follow(user, other_user)
 304       end)
 305
 306       result =
 307         conn
 308         |> get("/users/#{user.nickname}/following")
 309         |> json_response(200)
 310
 311       assert length(result["first"]["orderedItems"]) == 10
 312       assert result["first"]["totalItems"] == 15
 313       assert result["totalItems"] == 15
 314
 315       result =
 316         conn
 317         |> get("/users/#{user.nickname}/following?page=2")
 318         |> json_response(200)
 319
 320       assert length(result["orderedItems"]) == 5
 321       assert result["totalItems"] == 15
 322     end
 323   end
 324 end