git.squeep.com Git - akkoma/blob - test/support/helpers.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Tests.Helpers do
   6   @moduledoc """
   7   Helpers for use in tests.
   8   """
   9   alias Pleroma.Config
  10
  11   defmacro clear_config(config_path) do
  12     quote do
  13       clear_config(unquote(config_path)) do
  14       end
  15     end
  16   end
  17
  18   defmacro clear_config(config_path, do: yield) do
  19     quote do
  20       initial_setting = Config.fetch(unquote(config_path))
  21       unquote(yield)
  22
  23       on_exit(fn ->
  24         case initial_setting do
  25           :error ->
  26             Config.delete(unquote(config_path))
  27
  28           {:ok, value} ->
  29             Config.put(unquote(config_path), value)
  30         end
  31       end)
  32
  33       :ok
  34     end
  35   end
  36
  37   defmacro clear_config(config_path, temp_setting) do
  38     quote do
  39       clear_config(unquote(config_path)) do
  40         Config.put(unquote(config_path), unquote(temp_setting))
  41       end
  42     end
  43   end
  44
  45   def require_migration(migration_name) do
  46     [{module, _}] = Code.require_file("#{migration_name}.exs", "priv/repo/migrations")
  47     {:ok, %{migration: module}}
  48   end
  49
  50   defmacro __using__(_opts) do
  51     quote do
  52       import Pleroma.Tests.Helpers,
  53         only: [
  54           clear_config: 1,
  55           clear_config: 2
  56         ]
  57
  58       def to_datetime(%NaiveDateTime{} = naive_datetime) do
  59         naive_datetime
  60         |> DateTime.from_naive!("Etc/UTC")
  61         |> DateTime.truncate(:second)
  62       end
  63
  64       def to_datetime(datetime) when is_binary(datetime) do
  65         datetime
  66         |> NaiveDateTime.from_iso8601!()
  67         |> to_datetime()
  68       end
  69
  70       def collect_ids(collection) do
  71         collection
  72         |> Enum.map(& &1.id)
  73         |> Enum.sort()
  74       end
  75
  76       def refresh_record(%{id: id, __struct__: model} = _),
  77         do: refresh_record(model, %{id: id})
  78
  79       def refresh_record(model, %{id: id} = _) do
  80         Pleroma.Repo.get_by(model, id: id)
  81       end
  82
  83       # Used for comparing json rendering during tests.
  84       def render_json(view, template, assigns) do
  85         assigns = Map.new(assigns)
  86
  87         view.render(template, assigns)
  88         |> Jason.encode!()
  89         |> Jason.decode!()
  90       end
  91
  92       def stringify_keys(nil), do: nil
  93
  94       def stringify_keys(key) when key in [true, false], do: key
  95       def stringify_keys(key) when is_atom(key), do: Atom.to_string(key)
  96
  97       def stringify_keys(map) when is_map(map) do
  98         map
  99         |> Enum.map(fn {k, v} -> {stringify_keys(k), stringify_keys(v)} end)
 100         |> Enum.into(%{})
 101       end
 102
 103       def stringify_keys([head | rest] = list) when is_list(list) do
 104         [stringify_keys(head) | stringify_keys(rest)]
 105       end
 106
 107       def stringify_keys(key), do: key
 108
 109       defmacro guards_config(config_path) do
 110         quote do
 111           initial_setting = Config.get(config_path)
 112
 113           Config.put(config_path, true)
 114           on_exit(fn -> Config.put(config_path, initial_setting) end)
 115         end
 116       end
 117     end
 118   end
 119 end