git.squeep.com Git - akkoma/blob - test/pleroma/web/pleroma_api/controllers/chat_controller_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4 defmodule Pleroma.Web.PleromaAPI.ChatControllerTest do
   5   use Pleroma.Web.ConnCase
   6
   7   alias Pleroma.Chat
   8   alias Pleroma.Chat.MessageReference
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.CommonAPI
  13
  14   import Pleroma.Factory
  15
  16   describe "POST /api/v1/pleroma/chats/:id/messages/:message_id/read" do
  17     setup do: oauth_access(["write:chats"])
  18
  19     test "it marks one message as read", %{conn: conn, user: user} do
  20       other_user = insert(:user)
  21
  22       {:ok, create} = CommonAPI.post_chat_message(other_user, user, "sup")
  23       {:ok, _create} = CommonAPI.post_chat_message(other_user, user, "sup part 2")
  24       {:ok, chat} = Chat.get_or_create(user.id, other_user.ap_id)
  25       object = Object.normalize(create, fetch: false)
  26       cm_ref = MessageReference.for_chat_and_object(chat, object)
  27
  28       assert cm_ref.unread == true
  29
  30       result =
  31         conn
  32         |> post("/api/v1/pleroma/chats/#{chat.id}/messages/#{cm_ref.id}/read")
  33         |> json_response_and_validate_schema(200)
  34
  35       assert result["unread"] == false
  36
  37       cm_ref = MessageReference.for_chat_and_object(chat, object)
  38
  39       assert cm_ref.unread == false
  40     end
  41   end
  42
  43   describe "POST /api/v1/pleroma/chats/:id/read" do
  44     setup do: oauth_access(["write:chats"])
  45
  46     test "given a `last_read_id`, it marks everything until then as read", %{
  47       conn: conn,
  48       user: user
  49     } do
  50       other_user = insert(:user)
  51
  52       {:ok, create} = CommonAPI.post_chat_message(other_user, user, "sup")
  53       {:ok, _create} = CommonAPI.post_chat_message(other_user, user, "sup part 2")
  54       {:ok, chat} = Chat.get_or_create(user.id, other_user.ap_id)
  55       object = Object.normalize(create, fetch: false)
  56       cm_ref = MessageReference.for_chat_and_object(chat, object)
  57
  58       assert cm_ref.unread == true
  59
  60       result =
  61         conn
  62         |> put_req_header("content-type", "application/json")
  63         |> post("/api/v1/pleroma/chats/#{chat.id}/read", %{"last_read_id" => cm_ref.id})
  64         |> json_response_and_validate_schema(200)
  65
  66       assert result["unread"] == 1
  67
  68       cm_ref = MessageReference.for_chat_and_object(chat, object)
  69
  70       assert cm_ref.unread == false
  71     end
  72   end
  73
  74   describe "POST /api/v1/pleroma/chats/:id/messages" do
  75     setup do: oauth_access(["write:chats"])
  76
  77     test "it posts a message to the chat", %{conn: conn, user: user} do
  78       other_user = insert(:user)
  79
  80       {:ok, chat} = Chat.get_or_create(user.id, other_user.ap_id)
  81
  82       result =
  83         conn
  84         |> put_req_header("content-type", "application/json")
  85         |> put_req_header("idempotency-key", "123")
  86         |> post("/api/v1/pleroma/chats/#{chat.id}/messages", %{"content" => "Hallo!!"})
  87         |> json_response_and_validate_schema(200)
  88
  89       assert result["content"] == "Hallo!!"
  90       assert result["chat_id"] == chat.id |> to_string()
  91       assert result["idempotency_key"] == "123"
  92     end
  93
  94     test "it fails if there is no content", %{conn: conn, user: user} do
  95       other_user = insert(:user)
  96
  97       {:ok, chat} = Chat.get_or_create(user.id, other_user.ap_id)
  98
  99       result =
 100         conn
 101         |> put_req_header("content-type", "application/json")
 102         |> post("/api/v1/pleroma/chats/#{chat.id}/messages")
 103         |> json_response_and_validate_schema(400)
 104
 105       assert %{"error" => "no_content"} == result
 106     end
 107
 108     test "it works with an attachment", %{conn: conn, user: user} do
 109       file = %Plug.Upload{
 110         content_type: "image/jpeg",
 111         path: Path.absname("test/fixtures/image.jpg"),
 112         filename: "an_image.jpg"
 113       }
 114
 115       {:ok, upload} = ActivityPub.upload(file, actor: user.ap_id)
 116
 117       other_user = insert(:user)
 118
 119       {:ok, chat} = Chat.get_or_create(user.id, other_user.ap_id)
 120
 121       result =
 122         conn
 123         |> put_req_header("content-type", "application/json")
 124         |> post("/api/v1/pleroma/chats/#{chat.id}/messages", %{
 125           "media_id" => to_string(upload.id)
 126         })
 127         |> json_response_and_validate_schema(200)
 128
 129       assert result["attachment"]
 130     end
 131
 132     test "gets MRF reason when rejected", %{conn: conn, user: user} do
 133       clear_config([:mrf_keyword, :reject], ["GNO"])
 134       clear_config([:mrf, :policies], [Pleroma.Web.ActivityPub.MRF.KeywordPolicy])
 135
 136       other_user = insert(:user)
 137
 138       {:ok, chat} = Chat.get_or_create(user.id, other_user.ap_id)
 139
 140       result =
 141         conn
 142         |> put_req_header("content-type", "application/json")
 143         |> post("/api/v1/pleroma/chats/#{chat.id}/messages", %{"content" => "GNO/Linux"})
 144         |> json_response_and_validate_schema(422)
 145
 146       assert %{"error" => "[KeywordPolicy] Matches with rejected keyword"} == result
 147     end
 148   end
 149
 150   describe "DELETE /api/v1/pleroma/chats/:id/messages/:message_id" do
 151     setup do: oauth_access(["write:chats"])
 152
 153     test "it deletes a message from the chat", %{conn: conn, user: user} do
 154       recipient = insert(:user)
 155
 156       {:ok, message} =
 157         CommonAPI.post_chat_message(user, recipient, "Hello darkness my old friend")
 158
 159       {:ok, other_message} = CommonAPI.post_chat_message(recipient, user, "nico nico ni")
 160
 161       object = Object.normalize(message, fetch: false)
 162
 163       chat = Chat.get(user.id, recipient.ap_id)
 164
 165       cm_ref = MessageReference.for_chat_and_object(chat, object)
 166
 167       # Deleting your own message removes the message and the reference
 168       result =
 169         conn
 170         |> put_req_header("content-type", "application/json")
 171         |> delete("/api/v1/pleroma/chats/#{chat.id}/messages/#{cm_ref.id}")
 172         |> json_response_and_validate_schema(200)
 173
 174       assert result["id"] == cm_ref.id
 175       refute MessageReference.get_by_id(cm_ref.id)
 176       assert %{data: %{"type" => "Tombstone"}} = Object.get_by_id(object.id)
 177
 178       # Deleting other people's messages just removes the reference
 179       object = Object.normalize(other_message, fetch: false)
 180       cm_ref = MessageReference.for_chat_and_object(chat, object)
 181
 182       result =
 183         conn
 184         |> put_req_header("content-type", "application/json")
 185         |> delete("/api/v1/pleroma/chats/#{chat.id}/messages/#{cm_ref.id}")
 186         |> json_response_and_validate_schema(200)
 187
 188       assert result["id"] == cm_ref.id
 189       refute MessageReference.get_by_id(cm_ref.id)
 190       assert Object.get_by_id(object.id)
 191     end
 192   end
 193
 194   describe "GET /api/v1/pleroma/chats/:id/messages" do
 195     setup do: oauth_access(["read:chats"])
 196
 197     test "it paginates", %{conn: conn, user: user} do
 198       recipient = insert(:user)
 199
 200       Enum.each(1..30, fn _ ->
 201         {:ok, _} = CommonAPI.post_chat_message(user, recipient, "hey")
 202       end)
 203
 204       chat = Chat.get(user.id, recipient.ap_id)
 205
 206       response = get(conn, "/api/v1/pleroma/chats/#{chat.id}/messages")
 207       result = json_response_and_validate_schema(response, 200)
 208
 209       [next, prev] = get_resp_header(response, "link") |> hd() |> String.split(", ")
 210       api_endpoint = "/api/v1/pleroma/chats/"
 211
 212       assert String.match?(
 213                next,
 214                ~r(#{api_endpoint}.*/messages\?id=.*&limit=\d+&max_id=.*; rel=\"next\"$)
 215              )
 216
 217       assert String.match?(
 218                prev,
 219                ~r(#{api_endpoint}.*/messages\?id=.*&limit=\d+&min_id=.*; rel=\"prev\"$)
 220              )
 221
 222       assert length(result) == 20
 223
 224       response =
 225         get(conn, "/api/v1/pleroma/chats/#{chat.id}/messages?max_id=#{List.last(result)["id"]}")
 226
 227       result = json_response_and_validate_schema(response, 200)
 228       [next, prev] = get_resp_header(response, "link") |> hd() |> String.split(", ")
 229
 230       assert String.match?(
 231                next,
 232                ~r(#{api_endpoint}.*/messages\?id=.*&limit=\d+&max_id=.*; rel=\"next\"$)
 233              )
 234
 235       assert String.match?(
 236                prev,
 237                ~r(#{api_endpoint}.*/messages\?id=.*&limit=\d+&max_id=.*&min_id=.*; rel=\"prev\"$)
 238              )
 239
 240       assert length(result) == 10
 241     end
 242
 243     test "it returns the messages for a given chat", %{conn: conn, user: user} do
 244       other_user = insert(:user)
 245       third_user = insert(:user)
 246
 247       {:ok, _} = CommonAPI.post_chat_message(user, other_user, "hey")
 248       {:ok, _} = CommonAPI.post_chat_message(user, third_user, "hey")
 249       {:ok, _} = CommonAPI.post_chat_message(user, other_user, "how are you?")
 250       {:ok, _} = CommonAPI.post_chat_message(other_user, user, "fine, how about you?")
 251
 252       chat = Chat.get(user.id, other_user.ap_id)
 253
 254       result =
 255         conn
 256         |> get("/api/v1/pleroma/chats/#{chat.id}/messages")
 257         |> json_response_and_validate_schema(200)
 258
 259       result
 260       |> Enum.each(fn message ->
 261         assert message["chat_id"] == chat.id |> to_string()
 262       end)
 263
 264       assert length(result) == 3
 265
 266       # Trying to get the chat of a different user
 267       other_user_chat = Chat.get(other_user.id, user.ap_id)
 268
 269       conn
 270       |> get("/api/v1/pleroma/chats/#{other_user_chat.id}/messages")
 271       |> json_response_and_validate_schema(404)
 272     end
 273   end
 274
 275   describe "POST /api/v1/pleroma/chats/by-account-id/:id" do
 276     setup do: oauth_access(["write:chats"])
 277
 278     test "it creates or returns a chat", %{conn: conn} do
 279       other_user = insert(:user)
 280
 281       result =
 282         conn
 283         |> post("/api/v1/pleroma/chats/by-account-id/#{other_user.id}")
 284         |> json_response_and_validate_schema(200)
 285
 286       assert result["id"]
 287     end
 288   end
 289
 290   describe "GET /api/v1/pleroma/chats/:id" do
 291     setup do: oauth_access(["read:chats"])
 292
 293     test "it returns a chat", %{conn: conn, user: user} do
 294       other_user = insert(:user)
 295
 296       {:ok, chat} = Chat.get_or_create(user.id, other_user.ap_id)
 297
 298       result =
 299         conn
 300         |> get("/api/v1/pleroma/chats/#{chat.id}")
 301         |> json_response_and_validate_schema(200)
 302
 303       assert result["id"] == to_string(chat.id)
 304     end
 305   end
 306
 307   describe "GET /api/v1/pleroma/chats" do
 308     setup do: oauth_access(["read:chats"])
 309
 310     test "it does not return chats with deleted users", %{conn: conn, user: user} do
 311       recipient = insert(:user)
 312       {:ok, _} = Chat.get_or_create(user.id, recipient.ap_id)
 313
 314       Pleroma.Repo.delete(recipient)
 315       User.invalidate_cache(recipient)
 316
 317       result =
 318         conn
 319         |> get("/api/v1/pleroma/chats")
 320         |> json_response_and_validate_schema(200)
 321
 322       assert length(result) == 0
 323     end
 324
 325     test "it does not return chats with users you blocked", %{conn: conn, user: user} do
 326       recipient = insert(:user)
 327
 328       {:ok, _} = Chat.get_or_create(user.id, recipient.ap_id)
 329
 330       result =
 331         conn
 332         |> get("/api/v1/pleroma/chats")
 333         |> json_response_and_validate_schema(200)
 334
 335       assert length(result) == 1
 336
 337       User.block(user, recipient)
 338
 339       result =
 340         conn
 341         |> get("/api/v1/pleroma/chats")
 342         |> json_response_and_validate_schema(200)
 343
 344       assert length(result) == 0
 345     end
 346
 347     test "it does not return chats with users you muted", %{conn: conn, user: user} do
 348       recipient = insert(:user)
 349
 350       {:ok, _} = Chat.get_or_create(user.id, recipient.ap_id)
 351
 352       result =
 353         conn
 354         |> get("/api/v1/pleroma/chats")
 355         |> json_response_and_validate_schema(200)
 356
 357       assert length(result) == 1
 358
 359       User.mute(user, recipient)
 360
 361       result =
 362         conn
 363         |> get("/api/v1/pleroma/chats")
 364         |> json_response_and_validate_schema(200)
 365
 366       assert length(result) == 0
 367
 368       result =
 369         conn
 370         |> get("/api/v1/pleroma/chats?with_muted=true")
 371         |> json_response_and_validate_schema(200)
 372
 373       assert length(result) == 1
 374     end
 375
 376     test "it returns all chats", %{conn: conn, user: user} do
 377       Enum.each(1..30, fn _ ->
 378         recipient = insert(:user)
 379         {:ok, _} = Chat.get_or_create(user.id, recipient.ap_id)
 380       end)
 381
 382       result =
 383         conn
 384         |> get("/api/v1/pleroma/chats")
 385         |> json_response_and_validate_schema(200)
 386
 387       assert length(result) == 30
 388     end
 389
 390     test "it return a list of chats the current user is participating in, in descending order of updates",
 391          %{conn: conn, user: user} do
 392       har = insert(:user)
 393       jafnhar = insert(:user)
 394       tridi = insert(:user)
 395
 396       {:ok, chat_1} = Chat.get_or_create(user.id, har.ap_id)
 397       {:ok, chat_1} = time_travel(chat_1, -3)
 398       {:ok, chat_2} = Chat.get_or_create(user.id, jafnhar.ap_id)
 399       {:ok, _chat_2} = time_travel(chat_2, -2)
 400       {:ok, chat_3} = Chat.get_or_create(user.id, tridi.ap_id)
 401       {:ok, chat_3} = time_travel(chat_3, -1)
 402
 403       # bump the second one
 404       {:ok, chat_2} = Chat.bump_or_create(user.id, jafnhar.ap_id)
 405
 406       result =
 407         conn
 408         |> get("/api/v1/pleroma/chats")
 409         |> json_response_and_validate_schema(200)
 410
 411       ids = Enum.map(result, & &1["id"])
 412
 413       assert ids == [
 414                chat_2.id |> to_string(),
 415                chat_3.id |> to_string(),
 416                chat_1.id |> to_string()
 417              ]
 418     end
 419
 420     test "it is not affected by :restrict_unauthenticated setting (issue #1973)", %{
 421       conn: conn,
 422       user: user
 423     } do
 424       clear_config([:restrict_unauthenticated, :profiles, :local], true)
 425       clear_config([:restrict_unauthenticated, :profiles, :remote], true)
 426
 427       user2 = insert(:user)
 428       user3 = insert(:user, local: false)
 429
 430       {:ok, _chat_12} = Chat.get_or_create(user.id, user2.ap_id)
 431       {:ok, _chat_13} = Chat.get_or_create(user.id, user3.ap_id)
 432
 433       result =
 434         conn
 435         |> get("/api/v1/pleroma/chats")
 436         |> json_response_and_validate_schema(200)
 437
 438       account_ids = Enum.map(result, &get_in(&1, ["account", "id"]))
 439       assert Enum.sort(account_ids) == Enum.sort([user2.id, user3.id])
 440     end
 441   end
 442 end