git.squeep.com Git - akkoma/blob - test/pleroma/web/activity_pub/object_validators/like_validation_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.LikeValidationTest do
   6   use Pleroma.DataCase, async: true
   7
   8   alias Pleroma.Web.ActivityPub.ObjectValidator
   9   alias Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator
  10   alias Pleroma.Web.ActivityPub.Utils
  11   alias Pleroma.Web.CommonAPI
  12
  13   import Pleroma.Factory
  14
  15   describe "likes" do
  16     setup do
  17       user = insert(:user)
  18       {:ok, post_activity} = CommonAPI.post(user, %{status: "uguu"})
  19
  20       valid_like = %{
  21         "to" => [user.ap_id],
  22         "cc" => [],
  23         "type" => "Like",
  24         "id" => Utils.generate_activity_id(),
  25         "object" => post_activity.data["object"],
  26         "actor" => user.ap_id,
  27         "context" => "a context"
  28       }
  29
  30       %{valid_like: valid_like, user: user, post_activity: post_activity}
  31     end
  32
  33     test "returns ok when called in the ObjectValidator", %{valid_like: valid_like} do
  34       {:ok, object, _meta} = ObjectValidator.validate(valid_like, [])
  35
  36       assert "id" in Map.keys(object)
  37     end
  38
  39     test "is valid for a valid object", %{valid_like: valid_like} do
  40       assert LikeValidator.cast_and_validate(valid_like).valid?
  41     end
  42
  43     test "sets the 'to' field to the object actor if no recipients are given", %{
  44       valid_like: valid_like,
  45       user: user
  46     } do
  47       without_recipients =
  48         valid_like
  49         |> Map.delete("to")
  50
  51       {:ok, object, _meta} = ObjectValidator.validate(without_recipients, [])
  52
  53       assert object["to"] == [user.ap_id]
  54     end
  55
  56     test "sets the context field to the context of the object if no context is given", %{
  57       valid_like: valid_like,
  58       post_activity: post_activity
  59     } do
  60       without_context =
  61         valid_like
  62         |> Map.delete("context")
  63
  64       {:ok, object, _meta} = ObjectValidator.validate(without_context, [])
  65
  66       assert object["context"] == post_activity.data["context"]
  67     end
  68
  69     test "it errors when the actor is missing or not known", %{valid_like: valid_like} do
  70       without_actor = Map.delete(valid_like, "actor")
  71
  72       refute LikeValidator.cast_and_validate(without_actor).valid?
  73
  74       with_invalid_actor = Map.put(valid_like, "actor", "invalidactor")
  75
  76       refute LikeValidator.cast_and_validate(with_invalid_actor).valid?
  77     end
  78
  79     test "it errors when the object is missing or not known", %{valid_like: valid_like} do
  80       without_object = Map.delete(valid_like, "object")
  81
  82       refute LikeValidator.cast_and_validate(without_object).valid?
  83
  84       with_invalid_object = Map.put(valid_like, "object", "invalidobject")
  85
  86       refute LikeValidator.cast_and_validate(with_invalid_object).valid?
  87     end
  88
  89     test "it errors when the actor has already like the object", %{
  90       valid_like: valid_like,
  91       user: user,
  92       post_activity: post_activity
  93     } do
  94       _like = CommonAPI.favorite(user, post_activity.id)
  95
  96       refute LikeValidator.cast_and_validate(valid_like).valid?
  97     end
  98
  99     test "it works when actor or object are wrapped in maps", %{valid_like: valid_like} do
 100       wrapped_like =
 101         valid_like
 102         |> Map.put("actor", %{"id" => valid_like["actor"]})
 103         |> Map.put("object", %{"id" => valid_like["object"]})
 104
 105       validated = LikeValidator.cast_and_validate(wrapped_like)
 106
 107       assert validated.valid?
 108
 109       assert {:actor, valid_like["actor"]} in validated.changes
 110       assert {:object, valid_like["object"]} in validated.changes
 111     end
 112   end
 113 end