git.squeep.com Git - akkoma/blob - test/pleroma/user_search_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.UserSearchTest do
   6   alias Pleroma.Repo
   7   alias Pleroma.User
   8   use Pleroma.DataCase
   9
  10   import Pleroma.Factory
  11
  12   setup_all do
  13     Tesla.Mock.mock_global(fn env -> apply(HttpRequestMock, :request, [env]) end)
  14     :ok
  15   end
  16
  17   describe "User.search" do
  18     setup do: clear_config([:instance, :limit_to_local_content])
  19
  20     test "returns a resolved user as the first result" do
  21       Pleroma.Config.put([:instance, :limit_to_local_content], false)
  22       user = insert(:user, %{nickname: "no_relation", ap_id: "https://lain.com/users/lain"})
  23       _user = insert(:user, %{nickname: "com_user"})
  24
  25       [first_user, _second_user] = User.search("https://lain.com/users/lain", resolve: true)
  26
  27       assert first_user.id == user.id
  28     end
  29
  30     test "returns a user with matching ap_id as the first result" do
  31       user = insert(:user, %{nickname: "no_relation", ap_id: "https://lain.com/users/lain"})
  32       _user = insert(:user, %{nickname: "com_user"})
  33
  34       [first_user, _second_user] = User.search("https://lain.com/users/lain")
  35
  36       assert first_user.id == user.id
  37     end
  38
  39     test "doesn't die if two users have the same uri" do
  40       insert(:user, %{uri: "https://gensokyo.2hu/@raymoo"})
  41       insert(:user, %{uri: "https://gensokyo.2hu/@raymoo"})
  42       assert [_first_user, _second_user] = User.search("https://gensokyo.2hu/@raymoo")
  43     end
  44
  45     test "returns a user with matching uri as the first result" do
  46       user =
  47         insert(:user, %{
  48           nickname: "no_relation",
  49           ap_id: "https://lain.com/users/lain",
  50           uri: "https://lain.com/@lain"
  51         })
  52
  53       _user = insert(:user, %{nickname: "com_user"})
  54
  55       [first_user, _second_user] = User.search("https://lain.com/@lain")
  56
  57       assert first_user.id == user.id
  58     end
  59
  60     test "excludes invisible users from results" do
  61       user = insert(:user, %{nickname: "john t1000"})
  62       insert(:user, %{invisible: true, nickname: "john t800"})
  63
  64       [found_user] = User.search("john")
  65       assert found_user.id == user.id
  66     end
  67
  68     test "does NOT exclude non-discoverable users from results (as long as it's the default)" do
  69       # NOTE: as long as users are non-discoverable by default,
  70       # we can't filter out most users: #2301
  71       insert(:user, %{nickname: "john 3000", discoverable: false})
  72       insert(:user, %{nickname: "john 3001"})
  73
  74       users = User.search("john")
  75       assert Enum.count(users) == 2
  76     end
  77
  78     test "excludes service actors from results" do
  79       insert(:user, actor_type: "Application", nickname: "user1")
  80       service = insert(:user, actor_type: "Service", nickname: "user2")
  81       person = insert(:user, actor_type: "Person", nickname: "user3")
  82
  83       assert [found_user1, found_user2] = User.search("user")
  84       assert [found_user1.id, found_user2.id] -- [service.id, person.id] == []
  85     end
  86
  87     test "accepts limit parameter" do
  88       Enum.each(0..4, &insert(:user, %{nickname: "john#{&1}"}))
  89       assert length(User.search("john", limit: 3)) == 3
  90       assert length(User.search("john")) == 5
  91     end
  92
  93     test "accepts offset parameter" do
  94       Enum.each(0..4, &insert(:user, %{nickname: "john#{&1}"}))
  95       assert length(User.search("john", limit: 3)) == 3
  96       assert length(User.search("john", limit: 3, offset: 3)) == 2
  97     end
  98
  99     defp clear_virtual_fields(user) do
 100       Map.merge(user, %{search_rank: nil, search_type: nil})
 101     end
 102
 103     test "finds a user by full nickname or its leading fragment" do
 104       user = insert(:user, %{nickname: "john"})
 105
 106       Enum.each(["john", "jo", "j"], fn query ->
 107         assert user ==
 108                  User.search(query)
 109                  |> List.first()
 110                  |> clear_virtual_fields()
 111       end)
 112     end
 113
 114     test "finds a user by full name or leading fragment(s) of its words" do
 115       user = insert(:user, %{name: "John Doe"})
 116
 117       Enum.each(["John Doe", "JOHN", "doe", "j d", "j", "d"], fn query ->
 118         assert user ==
 119                  User.search(query)
 120                  |> List.first()
 121                  |> clear_virtual_fields()
 122       end)
 123     end
 124
 125     test "matches by leading fragment of user domain" do
 126       user = insert(:user, %{nickname: "arandom@dude.com"})
 127       insert(:user, %{nickname: "iamthedude"})
 128
 129       assert [user.id] == User.search("dud") |> Enum.map(& &1.id)
 130     end
 131
 132     test "ranks full nickname match higher than full name match" do
 133       nicknamed_user = insert(:user, %{nickname: "hj@shigusegubu.club"})
 134       named_user = insert(:user, %{nickname: "xyz@sample.com", name: "HJ"})
 135
 136       results = User.search("hj")
 137
 138       assert [nicknamed_user.id, named_user.id] == Enum.map(results, & &1.id)
 139       assert Enum.at(results, 0).search_rank > Enum.at(results, 1).search_rank
 140     end
 141
 142     test "finds users, considering density of matched tokens" do
 143       u1 = insert(:user, %{name: "Bar Bar plus Word Word"})
 144       u2 = insert(:user, %{name: "Word Word Bar Bar Bar"})
 145
 146       assert [u2.id, u1.id] == Enum.map(User.search("bar word"), & &1.id)
 147     end
 148
 149     test "finds users, boosting ranks of friends and followers" do
 150       u1 = insert(:user)
 151       u2 = insert(:user, %{name: "Doe"})
 152       follower = insert(:user, %{name: "Doe"})
 153       friend = insert(:user, %{name: "Doe"})
 154
 155       {:ok, follower} = User.follow(follower, u1)
 156       {:ok, u1} = User.follow(u1, friend)
 157
 158       assert [friend.id, follower.id, u2.id] --
 159                Enum.map(User.search("doe", resolve: false, for_user: u1), & &1.id) == []
 160     end
 161
 162     test "finds followings of user by partial name" do
 163       lizz = insert(:user, %{name: "Lizz"})
 164       jimi = insert(:user, %{name: "Jimi"})
 165       following_lizz = insert(:user, %{name: "Jimi Hendrix"})
 166       following_jimi = insert(:user, %{name: "Lizz Wright"})
 167       follower_lizz = insert(:user, %{name: "Jimi"})
 168
 169       {:ok, lizz} = User.follow(lizz, following_lizz)
 170       {:ok, _jimi} = User.follow(jimi, following_jimi)
 171       {:ok, _follower_lizz} = User.follow(follower_lizz, lizz)
 172
 173       assert Enum.map(User.search("jimi", following: true, for_user: lizz), & &1.id) == [
 174                following_lizz.id
 175              ]
 176
 177       assert User.search("lizz", following: true, for_user: lizz) == []
 178     end
 179
 180     test "find local and remote users for authenticated users" do
 181       u1 = insert(:user, %{name: "lain"})
 182       u2 = insert(:user, %{name: "ebn", nickname: "lain@mastodon.social", local: false})
 183       u3 = insert(:user, %{nickname: "lain@pleroma.soykaf.com", local: false})
 184
 185       results =
 186         "lain"
 187         |> User.search(for_user: u1)
 188         |> Enum.map(& &1.id)
 189         |> Enum.sort()
 190
 191       assert [u1.id, u2.id, u3.id] == results
 192     end
 193
 194     test "find only local users for unauthenticated users" do
 195       %{id: id} = insert(:user, %{name: "lain"})
 196       insert(:user, %{name: "ebn", nickname: "lain@mastodon.social", local: false})
 197       insert(:user, %{nickname: "lain@pleroma.soykaf.com", local: false})
 198
 199       assert [%{id: ^id}] = User.search("lain")
 200     end
 201
 202     test "find only local users for authenticated users when `limit_to_local_content` is `:all`" do
 203       Pleroma.Config.put([:instance, :limit_to_local_content], :all)
 204
 205       %{id: id} = insert(:user, %{name: "lain"})
 206       insert(:user, %{name: "ebn", nickname: "lain@mastodon.social", local: false})
 207       insert(:user, %{nickname: "lain@pleroma.soykaf.com", local: false})
 208
 209       assert [%{id: ^id}] = User.search("lain")
 210     end
 211
 212     test "find all users for unauthenticated users when `limit_to_local_content` is `false`" do
 213       Pleroma.Config.put([:instance, :limit_to_local_content], false)
 214
 215       u1 = insert(:user, %{name: "lain"})
 216       u2 = insert(:user, %{name: "ebn", nickname: "lain@mastodon.social", local: false})
 217       u3 = insert(:user, %{nickname: "lain@pleroma.soykaf.com", local: false})
 218
 219       results =
 220         "lain"
 221         |> User.search()
 222         |> Enum.map(& &1.id)
 223         |> Enum.sort()
 224
 225       assert [u1.id, u2.id, u3.id] == results
 226     end
 227
 228     test "does not yield false-positive matches" do
 229       insert(:user, %{name: "John Doe"})
 230
 231       Enum.each(["mary", "a", ""], fn query ->
 232         assert [] == User.search(query)
 233       end)
 234     end
 235
 236     test "works with URIs" do
 237       user = insert(:user)
 238
 239       results =
 240         User.search("http://mastodon.example.org/users/admin", resolve: true, for_user: user)
 241
 242       result = results |> List.first()
 243
 244       user = User.get_cached_by_ap_id("http://mastodon.example.org/users/admin")
 245
 246       assert length(results) == 1
 247
 248       expected =
 249         result
 250         |> Map.put(:search_rank, nil)
 251         |> Map.put(:search_type, nil)
 252         |> Map.put(:last_digest_emailed_at, nil)
 253         |> Map.put(:multi_factor_authentication_settings, nil)
 254         |> Map.put(:notification_settings, nil)
 255
 256       assert user == expected
 257     end
 258
 259     test "excludes a blocked users from search result" do
 260       user = insert(:user, %{nickname: "Bill"})
 261
 262       [blocked_user | users] = Enum.map(0..3, &insert(:user, %{nickname: "john#{&1}"}))
 263
 264       blocked_user2 =
 265         insert(
 266           :user,
 267           %{nickname: "john awful", ap_id: "https://awful-and-rude-instance.com/user/bully"}
 268         )
 269
 270       User.block_domain(user, "awful-and-rude-instance.com")
 271       User.block(user, blocked_user)
 272
 273       account_ids = User.search("john", for_user: refresh_record(user)) |> collect_ids
 274
 275       assert account_ids == collect_ids(users)
 276       refute Enum.member?(account_ids, blocked_user.id)
 277       refute Enum.member?(account_ids, blocked_user2.id)
 278       assert length(account_ids) == 3
 279     end
 280
 281     test "local user has the same search_rank as for users with the same nickname, but another domain" do
 282       user = insert(:user)
 283       insert(:user, nickname: "lain@mastodon.social")
 284       insert(:user, nickname: "lain")
 285       insert(:user, nickname: "lain@pleroma.social")
 286
 287       assert User.search("lain@localhost", resolve: true, for_user: user)
 288              |> Enum.each(fn u -> u.search_rank == 0.5 end)
 289     end
 290
 291     test "localhost is the part of the domain" do
 292       user = insert(:user)
 293       insert(:user, nickname: "another@somedomain")
 294       insert(:user, nickname: "lain")
 295       insert(:user, nickname: "lain@examplelocalhost")
 296
 297       result = User.search("lain@examplelocalhost", resolve: true, for_user: user)
 298       assert Enum.each(result, fn u -> u.search_rank == 0.5 end)
 299       assert length(result) == 2
 300     end
 301
 302     test "local user search with users" do
 303       user = insert(:user)
 304       local_user = insert(:user, nickname: "lain")
 305       insert(:user, nickname: "another@localhost.com")
 306       insert(:user, nickname: "localhost@localhost.com")
 307
 308       [result] = User.search("lain@localhost", resolve: true, for_user: user)
 309       assert Map.put(result, :search_rank, nil) |> Map.put(:search_type, nil) == local_user
 310     end
 311
 312     test "works with idna domains" do
 313       user = insert(:user, nickname: "lain@" <> to_string(:idna.encode("zetsubou.みんな")))
 314
 315       results = User.search("lain@zetsubou.みんな", resolve: false, for_user: user)
 316
 317       result = List.first(results)
 318
 319       assert user == result |> Map.put(:search_rank, nil) |> Map.put(:search_type, nil)
 320     end
 321
 322     test "works with idna domains converted input" do
 323       user = insert(:user, nickname: "lain@" <> to_string(:idna.encode("zetsubou.みんな")))
 324
 325       results =
 326         User.search("lain@zetsubou." <> to_string(:idna.encode("zetsubou.みんな")),
 327           resolve: false,
 328           for_user: user
 329         )
 330
 331       result = List.first(results)
 332
 333       assert user == result |> Map.put(:search_rank, nil) |> Map.put(:search_type, nil)
 334     end
 335
 336     test "works with idna domains and bad chars in domain" do
 337       user = insert(:user, nickname: "lain@" <> to_string(:idna.encode("zetsubou.みんな")))
 338
 339       results =
 340         User.search("lain@zetsubou!@#$%^&*()+,-/:;<=>?[]'_{}|~`.みんな",
 341           resolve: false,
 342           for_user: user
 343         )
 344
 345       result = List.first(results)
 346
 347       assert user == result |> Map.put(:search_rank, nil) |> Map.put(:search_type, nil)
 348     end
 349
 350     test "works with idna domains and query as link" do
 351       user = insert(:user, nickname: "lain@" <> to_string(:idna.encode("zetsubou.みんな")))
 352
 353       results =
 354         User.search("https://zetsubou.みんな/users/lain",
 355           resolve: false,
 356           for_user: user
 357         )
 358
 359       result = List.first(results)
 360
 361       assert user == result |> Map.put(:search_rank, nil) |> Map.put(:search_type, nil)
 362     end
 363   end
 364 end