git.squeep.com Git - akkoma/blob - test/integration/mastodon_websocket_test.exs

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2018 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Integration.MastodonWebsocketTest do
   6   use Pleroma.DataCase
   7
   8   import ExUnit.CaptureLog
   9   import Pleroma.Factory
  10
  11   alias Pleroma.Integration.WebsocketClient
  12   alias Pleroma.Web.CommonAPI
  13   alias Pleroma.Web.OAuth
  14   alias Pleroma.Web.Streamer
  15
  16   @path Pleroma.Web.Endpoint.url()
  17         |> URI.parse()
  18         |> Map.put(:scheme, "ws")
  19         |> Map.put(:path, "/api/v1/streaming")
  20         |> URI.to_string()
  21
  22   setup do
  23     GenServer.start(Streamer, %{}, name: Streamer)
  24
  25     on_exit(fn ->
  26       if pid = Process.whereis(Streamer) do
  27         Process.exit(pid, :kill)
  28       end
  29     end)
  30   end
  31
  32   def start_socket(qs \\ nil, headers \\ []) do
  33     path =
  34       case qs do
  35         nil -> @path
  36         qs -> @path <> qs
  37       end
  38
  39     WebsocketClient.start_link(self(), path, headers)
  40   end
  41
  42   test "refuses invalid requests" do
  43     capture_log(fn ->
  44       assert {:error, {400, _}} = start_socket()
  45       assert {:error, {404, _}} = start_socket("?stream=ncjdk")
  46     end)
  47   end
  48
  49   test "requires authentication and a valid token for protected streams" do
  50     capture_log(fn ->
  51       assert {:error, {403, _}} = start_socket("?stream=user&access_token=aaaaaaaaaaaa")
  52       assert {:error, {403, _}} = start_socket("?stream=user")
  53     end)
  54   end
  55
  56   test "allows public streams without authentication" do
  57     assert {:ok, _} = start_socket("?stream=public")
  58     assert {:ok, _} = start_socket("?stream=public:local")
  59     assert {:ok, _} = start_socket("?stream=hashtag&tag=lain")
  60   end
  61
  62   test "receives well formatted events" do
  63     user = insert(:user)
  64     {:ok, _} = start_socket("?stream=public")
  65     {:ok, activity} = CommonAPI.post(user, %{"status" => "nice echo chamber"})
  66
  67     assert_receive {:text, raw_json}, 1_000
  68     assert {:ok, json} = Jason.decode(raw_json)
  69
  70     assert "update" == json["event"]
  71     assert json["payload"]
  72     assert {:ok, json} = Jason.decode(json["payload"])
  73
  74     view_json =
  75       Pleroma.Web.MastodonAPI.StatusView.render("status.json", activity: activity, for: nil)
  76       |> Jason.encode!()
  77       |> Jason.decode!()
  78
  79     assert json == view_json
  80   end
  81
  82   describe "with a valid user token" do
  83     setup do
  84       {:ok, app} =
  85         Pleroma.Repo.insert(
  86           OAuth.App.register_changeset(%OAuth.App{}, %{
  87             client_name: "client",
  88             scopes: ["scope"],
  89             redirect_uris: "url"
  90           })
  91         )
  92
  93       user = insert(:user)
  94
  95       {:ok, auth} = OAuth.Authorization.create_authorization(app, user)
  96
  97       {:ok, token} = OAuth.Token.exchange_token(app, auth)
  98
  99       %{user: user, token: token}
 100     end
 101
 102     test "accepts valid tokens", state do
 103       assert {:ok, _} = start_socket("?stream=user&access_token=#{state.token.token}")
 104     end
 105
 106     test "accepts the 'user' stream", %{token: token} = _state do
 107       assert {:ok, _} = start_socket("?stream=user&access_token=#{token.token}")
 108
 109       assert capture_log(fn ->
 110                assert {:error, {403, "Forbidden"}} = start_socket("?stream=user")
 111              end) =~ ":badarg"
 112     end
 113
 114     test "accepts the 'user:notification' stream", %{token: token} = _state do
 115       assert {:ok, _} = start_socket("?stream=user:notification&access_token=#{token.token}")
 116
 117       assert capture_log(fn ->
 118                assert {:error, {403, "Forbidden"}} = start_socket("?stream=user:notification")
 119              end) =~ ":badarg"
 120     end
 121
 122     test "accepts valid token on Sec-WebSocket-Protocol header", %{token: token} do
 123       assert {:ok, _} = start_socket("?stream=user", [{"Sec-WebSocket-Protocol", token.token}])
 124
 125       assert capture_log(fn ->
 126                assert {:error, {403, "Forbidden"}} =
 127                         start_socket("?stream=user", [{"Sec-WebSocket-Protocol", "I am a friend"}])
 128              end) =~ ":badarg"
 129     end
 130   end
 131 end