git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("2.0.50"),
   8       elixir: "~> 1.9",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: warnings_as_errors(Mix.env())],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load, eldap: :transient],
  40           steps: [:assemble, &put_otp_version/1, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def put_otp_version(%{path: target_path} = release) do
  47     File.write!(
  48       Path.join([target_path, "OTP_VERSION"]),
  49       Pleroma.OTPVersion.version()
  50     )
  51
  52     release
  53   end
  54
  55   def copy_files(%{path: target_path} = release) do
  56     File.cp_r!("./rel/files", target_path)
  57     release
  58   end
  59
  60   def copy_nginx_config(%{path: target_path} = release) do
  61     File.cp!(
  62       "./installation/pleroma.nginx",
  63       Path.join([target_path, "installation", "pleroma.nginx"])
  64     )
  65
  66     release
  67   end
  68
  69   # Configuration for the OTP application.
  70   #
  71   # Type `mix help compile.app` for more information.
  72   def application do
  73     [
  74       mod: {Pleroma.Application, []},
  75       extra_applications: [
  76         :logger,
  77         :runtime_tools,
  78         :comeonin,
  79         :quack,
  80         :fast_sanitize,
  81         :ssl
  82       ],
  83       included_applications: [:ex_syslogger]
  84     ]
  85   end
  86
  87   # Specifies which paths to compile per environment.
  88   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  89   defp elixirc_paths(:test), do: ["lib", "test/support"]
  90   defp elixirc_paths(_), do: ["lib"]
  91
  92   defp warnings_as_errors(:prod), do: false
  93   # Uncomment this if you need testing configurable_from_database logic
  94   # defp warnings_as_errors(:dev), do: false
  95   defp warnings_as_errors(_), do: true
  96
  97   # Specifies OAuth dependencies.
  98   defp oauth_deps do
  99     oauth_strategy_packages =
 100       System.get_env("OAUTH_CONSUMER_STRATEGIES")
 101       |> to_string()
 102       |> String.split()
 103       |> Enum.map(fn strategy_entry ->
 104         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
 105           dependency
 106         else
 107           [strategy] -> "ueberauth_#{strategy}"
 108         end
 109       end)
 110
 111     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
 112   end
 113
 114   # Specifies your project dependencies.
 115   #
 116   # Type `mix help deps` for examples and options.
 117   defp deps do
 118     [
 119       {:phoenix, "~> 1.4.8"},
 120       {:tzdata, "~> 1.0.3"},
 121       {:plug_cowboy, "~> 2.0"},
 122       {:phoenix_pubsub, "~> 1.1"},
 123       {:phoenix_ecto, "~> 4.0"},
 124       {:ecto_enum, "~> 1.4"},
 125       {:ecto_sql, "~> 3.3.2"},
 126       {:postgrex, ">= 0.13.5"},
 127       {:oban, "~> 1.2"},
 128       {:gettext, "~> 0.15"},
 129       {:pbkdf2_elixir, "~> 1.0"},
 130       {:bcrypt_elixir, "~> 2.0"},
 131       {:trailing_format_plug, "~> 0.0.7"},
 132       {:fast_sanitize, "~> 0.1"},
 133       {:html_entities, "~> 0.5", override: true},
 134       {:phoenix_html, "~> 2.10"},
 135       {:calendar, "~> 0.17.4"},
 136       {:cachex, "~> 3.2"},
 137       {:poison, "~> 3.0", override: true},
 138       # {:tesla, "~> 1.3", override: true},
 139       {:tesla,
 140        git: "https://git.pleroma.social/pleroma/elixir-libraries/tesla.git",
 141        ref: "61b7503cef33f00834f78ddfafe0d5d9dec2270b",
 142        override: true},
 143       {:castore, "~> 0.1"},
 144       {:cowlib, "~> 2.8", override: true},
 145       {:gun,
 146        github: "ninenines/gun", ref: "e1a69b36b180a574c0ac314ced9613fdd52312cc", override: true},
 147       {:jason, "~> 1.0"},
 148       {:mogrify, "~> 0.6.1"},
 149       {:ex_aws, "~> 2.1"},
 150       {:ex_aws_s3, "~> 2.0"},
 151       {:sweet_xml, "~> 0.6.6"},
 152       {:earmark, "~> 1.3"},
 153       {:bbcode_pleroma, "~> 0.2.0"},
 154       {:ex_machina, "~> 2.3", only: :test},
 155       {:credo, "~> 1.1.0", only: [:dev, :test], runtime: false},
 156       {:mock, "~> 0.3.3", only: :test},
 157       {:crypt,
 158        git: "https://github.com/msantos/crypt", ref: "f63a705f92c26955977ee62a313012e309a4d77a"},
 159       {:cors_plug, "~> 1.5"},
 160       {:ex_doc, "~> 0.21", only: :dev, runtime: false},
 161       {:web_push_encryption, "~> 0.2.1"},
 162       {:swoosh, "~> 0.23.2"},
 163       {:phoenix_swoosh, "~> 0.2"},
 164       {:gen_smtp, "~> 0.13"},
 165       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 166       {:ex_syslogger, "~> 1.4"},
 167       {:floki, "~> 0.25"},
 168       {:timex, "~> 3.5"},
 169       {:ueberauth, "~> 0.4"},
 170       {:linkify, "~> 0.1.0"},
 171       {:http_signatures,
 172        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 173        ref: "293d77bb6f4a67ac8bde1428735c3b42f22cbb30"},
 174       {:telemetry, "~> 0.3"},
 175       {:poolboy, "~> 1.5"},
 176       {:prometheus_ex, "~> 3.0"},
 177       {:prometheus_plugs, "~> 1.1"},
 178       {:prometheus_phoenix, "~> 1.3"},
 179       {:prometheus_ecto, "~> 1.4"},
 180       {:recon, "~> 2.5"},
 181       {:quack, "~> 0.1.1"},
 182       {:joken, "~> 2.0"},
 183       {:benchee, "~> 1.0"},
 184       {:pot, "~> 0.10.2"},
 185       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 186       {:ex_const, "~> 0.2"},
 187       {:plug_static_index_html, "~> 1.0.0"},
 188       {:excoveralls, "~> 0.12.1", only: :test},
 189       {:flake_id, "~> 0.1.0"},
 190       {:remote_ip,
 191        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 192        ref: "b647d0deecaa3acb140854fe4bda5b7e1dc6d1c8"},
 193       {:captcha,
 194        git: "https://git.pleroma.social/pleroma/elixir-libraries/elixir-captcha.git",
 195        ref: "e0f16822d578866e186a0974d65ad58cddc1e2ab"},
 196       {:mox, "~> 0.5", only: :test},
 197       {:restarter, path: "./restarter"},
 198       {:open_api_spex,
 199        git: "https://git.pleroma.social/pleroma/elixir-libraries/open_api_spex.git",
 200        ref: "f296ac0924ba3cf79c7a588c4c252889df4c2edd"}
 201     ] ++ oauth_deps()
 202   end
 203
 204   # Aliases are shortcuts or tasks specific to the current project.
 205   # For example, to create, migrate and run the seeds file at once:
 206   #
 207   #     $ mix ecto.setup
 208   #
 209   # See the documentation for `Mix` for more info on aliases.
 210   defp aliases do
 211     [
 212       "ecto.migrate": ["pleroma.ecto.migrate"],
 213       "ecto.rollback": ["pleroma.ecto.rollback"],
 214       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 215       "ecto.reset": ["ecto.drop", "ecto.setup"],
 216       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 217       docs: ["pleroma.docs", "docs"]
 218     ]
 219   end
 220
 221   # Builds a version string made of:
 222   # * the application version
 223   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 224   # * branch name
 225   # * build metadata:
 226   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 227   #   * the mix environment if different than prod
 228   defp version(version) do
 229     identifier_filter = ~r/[^0-9a-z\-]+/i
 230
 231     {_cmdgit, cmdgit_err} = System.cmd("sh", ["-c", "command -v git"])
 232
 233     git_pre_release =
 234       if cmdgit_err == 0 do
 235         {tag, tag_err} =
 236           System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true)
 237
 238         {describe, describe_err} = System.cmd("git", ["describe", "--tags", "--abbrev=8"])
 239         {commit_hash, commit_hash_err} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 240
 241         # Pre-release version, denoted from patch version with a hyphen
 242         cond do
 243           tag_err == 0 and describe_err == 0 ->
 244             describe
 245             |> String.trim()
 246             |> String.replace(String.trim(tag), "")
 247             |> String.trim_leading("-")
 248             |> String.trim()
 249
 250           commit_hash_err == 0 ->
 251             "0-g" <> String.trim(commit_hash)
 252
 253           true ->
 254             nil
 255         end
 256       end
 257
 258     # Branch name as pre-release version component, denoted with a dot
 259     branch_name =
 260       with 0 <- cmdgit_err,
 261            {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 262            branch_name <- String.trim(branch_name),
 263            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 264            true <-
 265              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 266                String.starts_with?(name, branch_name)
 267              end) do
 268         branch_name =
 269           branch_name
 270           |> String.trim()
 271           |> String.replace(identifier_filter, "-")
 272
 273         branch_name
 274       else
 275         _ -> ""
 276       end
 277
 278     build_name =
 279       cond do
 280         name = Application.get_env(:pleroma, :build_name) -> name
 281         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 282         true -> nil
 283       end
 284
 285     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 286     env_override = System.get_env("PLEROMA_BUILD_ENV")
 287
 288     env_name =
 289       case env_override do
 290         nil -> env_name
 291         env_override when env_override in ["", "prod"] -> nil
 292         env_override -> env_override
 293       end
 294
 295     # Pre-release version, denoted by appending a hyphen
 296     # and a series of dot separated identifiers
 297     pre_release =
 298       [git_pre_release, branch_name]
 299       |> Enum.filter(fn string -> string && string != "" end)
 300       |> Enum.join(".")
 301       |> (fn
 302             "" -> nil
 303             string -> "-" <> String.replace(string, identifier_filter, "-")
 304           end).()
 305
 306     # Build metadata, denoted with a plus sign
 307     build_metadata =
 308       [build_name, env_name]
 309       |> Enum.filter(fn string -> string && string != "" end)
 310       |> Enum.join(".")
 311       |> (fn
 312             "" -> nil
 313             string -> "+" <> String.replace(string, identifier_filter, "-")
 314           end).()
 315
 316     [version, pre_release, build_metadata]
 317     |> Enum.filter(fn string -> string && string != "" end)
 318     |> Enum.join()
 319   end
 320 end