git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("2.0.50"),
   8       elixir: "~> 1.8",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: warnings_as_errors(Mix.env())],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load],
  40           steps: [:assemble, &put_otp_version/1, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def put_otp_version(%{path: target_path} = release) do
  47     File.write!(
  48       Path.join([target_path, "OTP_VERSION"]),
  49       Pleroma.OTPVersion.version()
  50     )
  51
  52     release
  53   end
  54
  55   def copy_files(%{path: target_path} = release) do
  56     File.cp_r!("./rel/files", target_path)
  57     release
  58   end
  59
  60   def copy_nginx_config(%{path: target_path} = release) do
  61     File.cp!(
  62       "./installation/pleroma.nginx",
  63       Path.join([target_path, "installation", "pleroma.nginx"])
  64     )
  65
  66     release
  67   end
  68
  69   # Configuration for the OTP application.
  70   #
  71   # Type `mix help compile.app` for more information.
  72   def application do
  73     [
  74       mod: {Pleroma.Application, []},
  75       extra_applications: [:logger, :runtime_tools, :comeonin, :quack, :fast_sanitize, :ssl],
  76       included_applications: [:ex_syslogger]
  77     ]
  78   end
  79
  80   # Specifies which paths to compile per environment.
  81   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  82   defp elixirc_paths(:test), do: ["lib", "test/support"]
  83   defp elixirc_paths(_), do: ["lib"]
  84
  85   defp warnings_as_errors(:prod), do: false
  86   # Uncomment this if you need testing configurable_from_database logic
  87   # defp warnings_as_errors(:dev), do: false
  88   defp warnings_as_errors(_), do: true
  89
  90   # Specifies OAuth dependencies.
  91   defp oauth_deps do
  92     oauth_strategy_packages =
  93       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  94       |> to_string()
  95       |> String.split()
  96       |> Enum.map(fn strategy_entry ->
  97         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
  98           dependency
  99         else
 100           [strategy] -> "ueberauth_#{strategy}"
 101         end
 102       end)
 103
 104     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
 105   end
 106
 107   # Specifies your project dependencies.
 108   #
 109   # Type `mix help deps` for examples and options.
 110   defp deps do
 111     [
 112       {:phoenix, "~> 1.4.8"},
 113       {:tzdata, "~> 0.5.21"},
 114       {:plug_cowboy, "~> 2.0"},
 115       {:phoenix_pubsub, "~> 1.1"},
 116       {:phoenix_ecto, "~> 4.0"},
 117       {:ecto_enum, "~> 1.4"},
 118       {:ecto_sql, "~> 3.3.2"},
 119       {:postgrex, ">= 0.13.5"},
 120       {:oban, "~> 1.2"},
 121       {:gettext, "~> 0.15"},
 122       {:comeonin, "~> 4.1.1"},
 123       {:pbkdf2_elixir, "~> 0.12.3"},
 124       {:trailing_format_plug, "~> 0.0.7"},
 125       {:fast_sanitize, "~> 0.1"},
 126       {:html_entities, "~> 0.5", override: true},
 127       {:phoenix_html, "~> 2.10"},
 128       {:calendar, "~> 0.17.4"},
 129       {:cachex, "~> 3.2"},
 130       {:poison, "~> 3.0", override: true},
 131       # {:tesla, "~> 1.3", override: true},
 132       {:tesla,
 133        git: "https://git.pleroma.social/pleroma/elixir-libraries/tesla.git",
 134        ref: "61b7503cef33f00834f78ddfafe0d5d9dec2270b",
 135        override: true},
 136       {:castore, "~> 0.1"},
 137       {:cowlib, "~> 2.8", override: true},
 138       {:gun,
 139        github: "ninenines/gun", ref: "e1a69b36b180a574c0ac314ced9613fdd52312cc", override: true},
 140       {:jason, "~> 1.0"},
 141       {:mogrify, "~> 0.6.1"},
 142       {:ex_aws, "~> 2.1"},
 143       {:ex_aws_s3, "~> 2.0"},
 144       {:sweet_xml, "~> 0.6.6"},
 145       {:earmark, "~> 1.3"},
 146       {:bbcode_pleroma, "~> 0.2.0"},
 147       {:ex_machina, "~> 2.3", only: :test},
 148       {:credo, "~> 1.1.0", only: [:dev, :test], runtime: false},
 149       {:mock, "~> 0.3.3", only: :test},
 150       {:crypt,
 151        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
 152       {:cors_plug, "~> 1.5"},
 153       {:ex_doc, "~> 0.21", only: :dev, runtime: false},
 154       {:web_push_encryption, "~> 0.2.1"},
 155       {:swoosh, "~> 0.23.2"},
 156       {:phoenix_swoosh, "~> 0.2"},
 157       {:gen_smtp, "~> 0.13"},
 158       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 159       {:ex_syslogger, "~> 1.4"},
 160       {:floki, "~> 0.25"},
 161       {:timex, "~> 3.5"},
 162       {:ueberauth, "~> 0.4"},
 163       {:auto_linker,
 164        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 165        ref: "95e8188490e97505c56636c1379ffdf036c1fdde"},
 166       {:http_signatures,
 167        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 168        ref: "293d77bb6f4a67ac8bde1428735c3b42f22cbb30"},
 169       {:telemetry, "~> 0.3"},
 170       {:poolboy, "~> 1.5"},
 171       {:prometheus_ex, "~> 3.0"},
 172       {:prometheus_plugs, "~> 1.1"},
 173       {:prometheus_phoenix, "~> 1.3"},
 174       {:prometheus_ecto, "~> 1.4"},
 175       {:recon, "~> 2.5"},
 176       {:quack, "~> 0.1.1"},
 177       {:joken, "~> 2.0"},
 178       {:benchee, "~> 1.0"},
 179       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 180       {:ex_const, "~> 0.2"},
 181       {:plug_static_index_html, "~> 1.0.0"},
 182       {:excoveralls, "~> 0.12.1", only: :test},
 183       {:flake_id, "~> 0.1.0"},
 184       {:remote_ip,
 185        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 186        ref: "b647d0deecaa3acb140854fe4bda5b7e1dc6d1c8"},
 187       {:captcha,
 188        git: "https://git.pleroma.social/pleroma/elixir-libraries/elixir-captcha.git",
 189        ref: "e0f16822d578866e186a0974d65ad58cddc1e2ab"},
 190       {:mox, "~> 0.5", only: :test},
 191       {:restarter, path: "./restarter"},
 192       {:open_api_spex,
 193        git: "https://git.pleroma.social/pleroma/elixir-libraries/open_api_spex.git",
 194        ref: "b862ebd78de0df95875cf46feb6e9607130dc2a8"}
 195     ] ++ oauth_deps()
 196   end
 197
 198   # Aliases are shortcuts or tasks specific to the current project.
 199   # For example, to create, migrate and run the seeds file at once:
 200   #
 201   #     $ mix ecto.setup
 202   #
 203   # See the documentation for `Mix` for more info on aliases.
 204   defp aliases do
 205     [
 206       "ecto.migrate": ["pleroma.ecto.migrate"],
 207       "ecto.rollback": ["pleroma.ecto.rollback"],
 208       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 209       "ecto.reset": ["ecto.drop", "ecto.setup"],
 210       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 211       docs: ["pleroma.docs", "docs"]
 212     ]
 213   end
 214
 215   # Builds a version string made of:
 216   # * the application version
 217   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 218   # * branch name
 219   # * build metadata:
 220   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 221   #   * the mix environment if different than prod
 222   defp version(version) do
 223     identifier_filter = ~r/[^0-9a-z\-]+/i
 224
 225     # Pre-release version, denoted from patch version with a hyphen
 226     {tag, tag_err} =
 227       System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true)
 228
 229     {describe, describe_err} = System.cmd("git", ["describe", "--tags", "--abbrev=8"])
 230     {commit_hash, commit_hash_err} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 231
 232     git_pre_release =
 233       cond do
 234         tag_err == 0 and describe_err == 0 ->
 235           describe
 236           |> String.trim()
 237           |> String.replace(String.trim(tag), "")
 238           |> String.trim_leading("-")
 239           |> String.trim()
 240
 241         commit_hash_err == 0 ->
 242           "0-g" <> String.trim(commit_hash)
 243
 244         true ->
 245           ""
 246       end
 247
 248     # Branch name as pre-release version component, denoted with a dot
 249     branch_name =
 250       with {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 251            branch_name <- String.trim(branch_name),
 252            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 253            true <-
 254              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 255                String.starts_with?(name, branch_name)
 256              end) do
 257         branch_name =
 258           branch_name
 259           |> String.trim()
 260           |> String.replace(identifier_filter, "-")
 261
 262         branch_name
 263       else
 264         _ -> "stable"
 265       end
 266
 267     build_name =
 268       cond do
 269         name = Application.get_env(:pleroma, :build_name) -> name
 270         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 271         true -> nil
 272       end
 273
 274     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 275     env_override = System.get_env("PLEROMA_BUILD_ENV")
 276
 277     env_name =
 278       case env_override do
 279         nil -> env_name
 280         env_override when env_override in ["", "prod"] -> nil
 281         env_override -> env_override
 282       end
 283
 284     # Pre-release version, denoted by appending a hyphen
 285     # and a series of dot separated identifiers
 286     pre_release =
 287       [git_pre_release, branch_name]
 288       |> Enum.filter(fn string -> string && string != "" end)
 289       |> Enum.join(".")
 290       |> (fn
 291             "" -> nil
 292             string -> "-" <> String.replace(string, identifier_filter, "-")
 293           end).()
 294
 295     # Build metadata, denoted with a plus sign
 296     build_metadata =
 297       [build_name, env_name]
 298       |> Enum.filter(fn string -> string && string != "" end)
 299       |> Enum.join(".")
 300       |> (fn
 301             "" -> nil
 302             string -> "+" <> String.replace(string, identifier_filter, "-")
 303           end).()
 304
 305     [version, pre_release, build_metadata]
 306     |> Enum.filter(fn string -> string && string != "" end)
 307     |> Enum.join()
 308   end
 309 end