git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("2.3.50"),
   8       elixir: "~> 1.9",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: warnings_as_errors(Mix.env())],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/images/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load, eldap: :transient],
  40           steps: [:assemble, &put_otp_version/1, &copy_files/1, &copy_nginx_config/1],
  41           config_providers: [{Pleroma.Config.ReleaseRuntimeProvider, []}]
  42         ]
  43       ]
  44     ]
  45   end
  46
  47   def put_otp_version(%{path: target_path} = release) do
  48     File.write!(
  49       Path.join([target_path, "OTP_VERSION"]),
  50       Pleroma.OTPVersion.version()
  51     )
  52
  53     release
  54   end
  55
  56   def copy_files(%{path: target_path} = release) do
  57     File.cp_r!("./rel/files", target_path)
  58     release
  59   end
  60
  61   def copy_nginx_config(%{path: target_path} = release) do
  62     File.cp!(
  63       "./installation/pleroma.nginx",
  64       Path.join([target_path, "installation", "pleroma.nginx"])
  65     )
  66
  67     release
  68   end
  69
  70   # Configuration for the OTP application.
  71   #
  72   # Type `mix help compile.app` for more information.
  73   def application do
  74     [
  75       mod: {Pleroma.Application, []},
  76       extra_applications: [
  77         :logger,
  78         :runtime_tools,
  79         :comeonin,
  80         :quack,
  81         :fast_sanitize,
  82         :ssl
  83       ],
  84       included_applications: [:ex_syslogger]
  85     ]
  86   end
  87
  88   # Specifies which paths to compile per environment.
  89   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  90   defp elixirc_paths(:test), do: ["lib", "test/support"]
  91   defp elixirc_paths(_), do: ["lib"]
  92
  93   defp warnings_as_errors(:prod), do: false
  94   defp warnings_as_errors(_), do: true
  95
  96   # Specifies OAuth dependencies.
  97   defp oauth_deps do
  98     oauth_strategy_packages =
  99       System.get_env("OAUTH_CONSUMER_STRATEGIES")
 100       |> to_string()
 101       |> String.split()
 102       |> Enum.map(fn strategy_entry ->
 103         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
 104           dependency
 105         else
 106           [strategy] -> "ueberauth_#{strategy}"
 107         end
 108       end)
 109
 110     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
 111   end
 112
 113   # Specifies your project dependencies.
 114   #
 115   # Type `mix help deps` for examples and options.
 116   defp deps do
 117     [
 118       {:phoenix, "~> 1.5.5"},
 119       {:tzdata, "~> 1.0.3"},
 120       {:plug_cowboy, "~> 2.3"},
 121       {:phoenix_pubsub, "~> 2.0"},
 122       {:phoenix_ecto, "~> 4.0"},
 123       {:ecto_enum, "~> 1.4"},
 124       {:ecto_explain, "~> 0.1.2"},
 125       {:ecto_sql, "~> 3.4.4"},
 126       {:postgrex, ">= 0.15.5"},
 127       {:oban, "~> 2.3.4"},
 128       {:gettext, "~> 0.18"},
 129       {:bcrypt_elixir, "~> 2.2"},
 130       {:trailing_format_plug, "~> 0.0.7"},
 131       {:fast_sanitize, "~> 0.2.0"},
 132       {:html_entities, "~> 0.5", override: true},
 133       {:phoenix_html, "~> 2.14"},
 134       {:calendar, "~> 1.0"},
 135       {:cachex, "~> 3.2"},
 136       {:poison, "~> 3.0", override: true},
 137       {:tesla, "~> 1.4.0", override: true},
 138       {:castore, "~> 0.1"},
 139       {:cowlib, "~> 2.9", override: true},
 140       {:gun,
 141        github: "ninenines/gun", ref: "921c47146b2d9567eac7e9a4d2ccc60fffd4f327", override: true},
 142       {:jason, "~> 1.2"},
 143       {:mogrify, "~> 0.7.4"},
 144       {:ex_aws, "~> 2.1.6"},
 145       {:ex_aws_s3, "~> 2.0"},
 146       {:sweet_xml, "~> 0.6.6"},
 147       {:earmark, "1.4.15"},
 148       {:bbcode_pleroma, "~> 0.2.0"},
 149       {:crypt,
 150        git: "https://git.pleroma.social/pleroma/elixir-libraries/crypt.git",
 151        ref: "cf2aa3f11632e8b0634810a15b3e612c7526f6a3"},
 152       {:cors_plug, "~> 2.0"},
 153       {:web_push_encryption, "~> 0.3"},
 154       {:swoosh, "~> 1.0"},
 155       {:phoenix_swoosh, "~> 0.3"},
 156       {:gen_smtp, "~> 0.13"},
 157       {:ex_syslogger, "~> 1.4"},
 158       {:floki, "~> 0.27"},
 159       {:timex, "~> 3.6"},
 160       {:ueberauth, "~> 0.4"},
 161       {:linkify, "~> 0.5.0"},
 162       {:http_signatures, "~> 0.1.0"},
 163       {:telemetry, "~> 0.3"},
 164       {:poolboy, "~> 1.5"},
 165       {:prometheus, "~> 4.6"},
 166       {:prometheus_ex,
 167        git: "https://git.pleroma.social/pleroma/elixir-libraries/prometheus.ex.git",
 168        ref: "a4e9beb3c1c479d14b352fd9d6dd7b1f6d7deee5",
 169        override: true},
 170       {:prometheus_plugs, "~> 1.1"},
 171       {:prometheus_phoenix, "~> 1.3"},
 172       # Note: once `prometheus_phx` is integrated into `prometheus_phoenix`, remove the former:
 173       {:prometheus_phx,
 174        git: "https://git.pleroma.social/pleroma/elixir-libraries/prometheus-phx.git",
 175        branch: "no-logging"},
 176       {:prometheus_ecto, "~> 1.4"},
 177       {:recon, "~> 2.5"},
 178       {:quack, "~> 0.1.1"},
 179       {:joken, "~> 2.0"},
 180       {:benchee, "~> 1.0"},
 181       {:pot, "~> 0.11"},
 182       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 183       {:ex_const, "~> 0.2"},
 184       {:plug_static_index_html, "~> 1.0.0"},
 185       {:flake_id, "~> 0.1.0"},
 186       {:concurrent_limiter,
 187        git: "https://git.pleroma.social/pleroma/elixir-libraries/concurrent_limiter.git",
 188        ref: "d81be41024569330f296fc472e24198d7499ba78"},
 189       {:remote_ip,
 190        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 191        ref: "b647d0deecaa3acb140854fe4bda5b7e1dc6d1c8"},
 192       {:captcha,
 193        git: "https://git.pleroma.social/pleroma/elixir-libraries/elixir-captcha.git",
 194        ref: "e0f16822d578866e186a0974d65ad58cddc1e2ab"},
 195       {:restarter, path: "./restarter"},
 196       {:majic,
 197        git: "https://git.pleroma.social/pleroma/elixir-libraries/majic.git",
 198        ref: "289cda1b6d0d70ccb2ba508a2b0bd24638db2880"},
 199       {:eblurhash,
 200        git: "https://github.com/zotonic/eblurhash.git",
 201        ref: "04a0b76eadf4de1be17726f39b6313b88708fd12"},
 202       {:open_api_spex, "~> 3.10"},
 203
 204       ## dev & test
 205       {:ex_doc, "~> 0.22", only: :dev, runtime: false},
 206       {:ex_machina, "~> 2.4", only: :test},
 207       {:credo, "~> 1.4", only: [:dev, :test], runtime: false},
 208       {:mock, "~> 0.3.5", only: :test},
 209       # temporary downgrade for excoveralls, hackney until hackney max_connections bug will be fixed
 210       {:excoveralls, "0.12.3", only: :test},
 211       {:hackney,
 212        git: "https://git.pleroma.social/pleroma/elixir-libraries/hackney.git",
 213        ref: "7d7119f0651515d6d7669c78393fd90950a3ec6e",
 214        override: true},
 215       {:mox, "~> 1.0", only: :test},
 216       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test}
 217     ] ++ oauth_deps()
 218   end
 219
 220   # Aliases are shortcuts or tasks specific to the current project.
 221   # For example, to create, migrate and run the seeds file at once:
 222   #
 223   #     $ mix ecto.setup
 224   #
 225   # See the documentation for `Mix` for more info on aliases.
 226   defp aliases do
 227     [
 228       "ecto.migrate": ["pleroma.ecto.migrate"],
 229       "ecto.rollback": ["pleroma.ecto.rollback"],
 230       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 231       "ecto.reset": ["ecto.drop", "ecto.setup"],
 232       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 233       docs: ["pleroma.docs", "docs"],
 234       analyze: ["credo --strict --only=warnings,todo,fixme,consistency,readability"],
 235       copyright: &add_copyright/1,
 236       "copyright.bump": &bump_copyright/1
 237     ]
 238   end
 239
 240   # Builds a version string made of:
 241   # * the application version
 242   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 243   # * branch name
 244   # * build metadata:
 245   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 246   #   * the mix environment if different than prod
 247   defp version(version) do
 248     identifier_filter = ~r/[^0-9a-z\-]+/i
 249
 250     git_available? = match?({_output, 0}, System.cmd("sh", ["-c", "command -v git"]))
 251
 252     git_pre_release =
 253       if git_available? do
 254         {tag, tag_err} =
 255           System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true)
 256
 257         {describe, describe_err} = System.cmd("git", ["describe", "--tags", "--abbrev=8"])
 258         {commit_hash, commit_hash_err} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 259
 260         # Pre-release version, denoted from patch version with a hyphen
 261         cond do
 262           tag_err == 0 and describe_err == 0 ->
 263             describe
 264             |> String.trim()
 265             |> String.replace(String.trim(tag), "")
 266             |> String.trim_leading("-")
 267             |> String.trim()
 268
 269           commit_hash_err == 0 ->
 270             "0-g" <> String.trim(commit_hash)
 271
 272           true ->
 273             nil
 274         end
 275       end
 276
 277     # Branch name as pre-release version component, denoted with a dot
 278     branch_name =
 279       with true <- git_available?,
 280            {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 281            branch_name <- String.trim(branch_name),
 282            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 283            true <-
 284              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 285                String.starts_with?(name, branch_name)
 286              end) do
 287         branch_name =
 288           branch_name
 289           |> String.trim()
 290           |> String.replace(identifier_filter, "-")
 291
 292         branch_name
 293       else
 294         _ -> ""
 295       end
 296
 297     build_name =
 298       cond do
 299         name = Application.get_env(:pleroma, :build_name) -> name
 300         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 301         true -> nil
 302       end
 303
 304     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 305     env_override = System.get_env("PLEROMA_BUILD_ENV")
 306
 307     env_name =
 308       case env_override do
 309         nil -> env_name
 310         env_override when env_override in ["", "prod"] -> nil
 311         env_override -> env_override
 312       end
 313
 314     # Pre-release version, denoted by appending a hyphen
 315     # and a series of dot separated identifiers
 316     pre_release =
 317       [git_pre_release, branch_name]
 318       |> Enum.filter(fn string -> string && string != "" end)
 319       |> Enum.join(".")
 320       |> (fn
 321             "" -> nil
 322             string -> "-" <> String.replace(string, identifier_filter, "-")
 323           end).()
 324
 325     # Build metadata, denoted with a plus sign
 326     build_metadata =
 327       [build_name, env_name]
 328       |> Enum.filter(fn string -> string && string != "" end)
 329       |> Enum.join(".")
 330       |> (fn
 331             "" -> nil
 332             string -> "+" <> String.replace(string, identifier_filter, "-")
 333           end).()
 334
 335     [version, pre_release, build_metadata]
 336     |> Enum.filter(fn string -> string && string != "" end)
 337     |> Enum.join()
 338   end
 339
 340   defp add_copyright(_) do
 341     year = NaiveDateTime.utc_now().year
 342     template = ~s[\
 343 # Pleroma: A lightweight social networking server
 344 # Copyright © 2017-#{year} Pleroma Authors <https://pleroma.social/>
 345 # SPDX-License-Identifier: AGPL-3.0-only
 346
 347 ] |> String.replace("\n", "\\n")
 348
 349     find = "find lib test priv -type f \\( -name '*.ex' -or -name '*.exs' \\) -exec "
 350     grep = "grep -L '# Copyright © [0-9\-]* Pleroma' {} \\;"
 351     xargs = "xargs -n1 sed -i'' '1s;^;#{template};'"
 352
 353     :os.cmd(String.to_charlist("#{find}#{grep} | #{xargs}"))
 354   end
 355
 356   defp bump_copyright(_) do
 357     year = NaiveDateTime.utc_now().year
 358     find = "find lib test priv -type f \\( -name '*.ex' -or -name '*.exs' \\)"
 359
 360     xargs =
 361       "xargs sed -i'' 's;# Copyright © [0-9\-]* Pleroma.*$;# Copyright © 2017-#{year} Pleroma Authors <https://pleroma.social/>;'"
 362
 363     :os.cmd(String.to_charlist("#{find} | #{xargs}"))
 364   end
 365 end