git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("3.6.0"),
   8       elixir: "~> 1.12",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: warnings_as_errors()],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Akkoma",
  20       homepage_url: "https://akkoma.dev/",
  21       source_url: "https://akkoma.dev/AkkomaGang/akkoma",
  22       docs: [
  23         source_url_pattern: "https://akkoma.dev/AkkomaGang/akkoma/blob/develop/%{path}#L%{line}",
  24         logo: "priv/static/images/logo.png",
  25         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  26         groups_for_extras: [
  27           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  28           Configuration: Path.wildcard("docs/config/*.md"),
  29           Administration: Path.wildcard("docs/admin/*.md"),
  30           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  31         ],
  32         main: "readme",
  33         output: "priv/static/doc"
  34       ],
  35       releases: [
  36         pleroma: [
  37           include_executables_for: [:unix],
  38           applications: [ex_syslogger: :load, syslog: :load, eldap: :transient],
  39           steps: [:assemble, &put_otp_version/1, &copy_files/1, &copy_nginx_config/1],
  40           config_providers: [{Pleroma.Config.ReleaseRuntimeProvider, []}]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def put_otp_version(%{path: target_path} = release) do
  47     File.write!(
  48       Path.join([target_path, "OTP_VERSION"]),
  49       Pleroma.OTPVersion.version()
  50     )
  51
  52     release
  53   end
  54
  55   def copy_files(%{path: target_path} = release) do
  56     File.cp_r!("./rel/files", target_path)
  57     release
  58   end
  59
  60   def copy_nginx_config(%{path: target_path} = release) do
  61     File.cp!(
  62       "./installation/nginx/akkoma.nginx",
  63       Path.join([target_path, "installation", "akkoma.nginx"])
  64     )
  65
  66     release
  67   end
  68
  69   # Configuration for the OTP application.
  70   #
  71   # Type `mix help compile.app` for more information.
  72   def application do
  73     [
  74       mod: {Pleroma.Application, []},
  75       extra_applications: [
  76         :logger,
  77         :runtime_tools,
  78         :comeonin,
  79         :fast_sanitize,
  80         :os_mon,
  81         :ssl
  82       ],
  83       included_applications: [:ex_syslogger]
  84     ]
  85   end
  86
  87   # Specifies which paths to compile per environment.
  88   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks", "priv/scrubbers"]
  89   defp elixirc_paths(:test), do: ["lib", "test/support"]
  90   defp elixirc_paths(_), do: ["lib"]
  91
  92   defp warnings_as_errors, do: System.get_env("CI") == "true"
  93
  94   # Specifies OAuth dependencies.
  95   defp oauth_deps do
  96     oauth_strategy_packages =
  97       "OAUTH_CONSUMER_STRATEGIES"
  98       |> System.get_env()
  99       |> to_string()
 100       |> String.split()
 101       |> Enum.map(fn strategy_entry ->
 102         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
 103           dependency
 104         else
 105           [strategy] -> "ueberauth_#{strategy}"
 106         end
 107       end)
 108
 109     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
 110   end
 111
 112   # Specifies your project dependencies.
 113   #
 114   # Type `mix help deps` for examples and options.
 115   defp deps do
 116     [
 117       {:phoenix, "~> 1.6.15"},
 118       {:tzdata, "~> 1.1.1"},
 119       {:plug_cowboy, "~> 2.6"},
 120       {:phoenix_pubsub, "~> 2.1"},
 121       {:phoenix_ecto, "~> 4.4"},
 122       {:inet_cidr, "~> 1.0.0"},
 123       {:ecto_enum, "~> 1.4"},
 124       {:ecto_sql, "~> 3.9.0"},
 125       {:postgrex, ">= 0.16.3"},
 126       {:oban, "~> 2.12.1"},
 127       {:gettext, "~> 0.20.0"},
 128       {:bcrypt_elixir, "~> 2.2"},
 129       {:fast_sanitize, "~> 0.2.3"},
 130       {:html_entities, "~> 0.5"},
 131       {:phoenix_html, "~> 3.2"},
 132       {:calendar, "~> 1.0"},
 133       {:cachex, "~> 3.4"},
 134       {:tesla, "~> 1.4.4"},
 135       {:castore, "~> 0.1"},
 136       {:cowlib, "~> 2.9"},
 137       {:finch, "~> 0.14.0"},
 138       {:jason, "~> 1.2"},
 139       {:trailing_format_plug, "~> 0.0.7"},
 140       {:mogrify, "~> 0.9.1"},
 141       {:ex_aws, "~> 2.1.6"},
 142       {:ex_aws_s3, "~> 2.0"},
 143       {:sweet_xml, "~> 0.7.2"},
 144       {:earmark, "~> 1.4.15"},
 145       {:bbcode_pleroma, "~> 0.2.0"},
 146       {:argon2_elixir, "~> 3.0.0"},
 147       {:cors_plug, "~> 2.0"},
 148       {:web_push_encryption, "~> 0.3.1"},
 149       {:swoosh, "~> 1.0"},
 150       # for gmail adapter in swoosh
 151       {:mail, ">= 0.0.0"},
 152       {:phoenix_swoosh, "~> 0.3"},
 153       {:gen_smtp, "~> 0.13"},
 154       {:ex_syslogger, "~> 1.4"},
 155       {:floki, "~> 0.27"},
 156       {:timex, "~> 3.6"},
 157       {:ueberauth, "~> 0.4"},
 158       {:linkify,
 159        git: "https://akkoma.dev/AkkomaGang/linkify.git", branch: "bugfix/line-ending-buffer"},
 160       {:http_signatures, "~> 0.1.1"},
 161       {:telemetry, "~> 0.3"},
 162       {:telemetry_poller, "~> 0.4"},
 163       {:telemetry_metrics, "~> 0.4"},
 164       {:telemetry_metrics_prometheus_core, "~> 1.1.0"},
 165       {:poolboy, "~> 1.5"},
 166       {:recon, "~> 2.5"},
 167       {:joken, "~> 2.0"},
 168       {:benchee, "~> 1.0"},
 169       {:pot, "~> 1.0"},
 170       {:ex_const, "~> 0.2"},
 171       {:plug_static_index_html, "~> 1.0.0"},
 172       {:flake_id, "~> 0.1.0"},
 173       {:concurrent_limiter, "~> 0.1.1"},
 174       {:remote_ip, "~> 1.1.0"},
 175       {:captcha,
 176        git: "https://git.pleroma.social/pleroma/elixir-libraries/elixir-captcha.git",
 177        ref: "e0f16822d578866e186a0974d65ad58cddc1e2ab"},
 178       {:restarter, path: "./restarter"},
 179       {:majic, "~> 1.0"},
 180       {:eblurhash, "~> 1.2.2"},
 181       {:open_api_spex, "~> 3.16.0"},
 182       {:search_parser,
 183        git: "https://github.com/FloatingGhost/pleroma-contrib-search-parser.git",
 184        ref: "08971a81e68686f9ac465cfb6661d51c5e4e1e7f"},
 185       {:nimble_parsec, "~> 1.0", override: true},
 186       {:phoenix_live_dashboard, "~> 0.7.2"},
 187       {:ecto_psql_extras, "~> 0.6"},
 188       {:elasticsearch,
 189        git: "https://akkoma.dev/AkkomaGang/elasticsearch-elixir.git", ref: "main"},
 190       {:mfm_parser,
 191        git: "https://akkoma.dev/AkkomaGang/mfm-parser.git",
 192        ref: "912fba81152d4d572e457fd5427f9875b2bc3dbe"},
 193       {:poison, ">= 0.0.0"},
 194
 195       ## dev & test
 196       {:ex_doc, "~> 0.22", only: :dev, runtime: false},
 197       {:ex_machina, "~> 2.4", only: :test},
 198       {:credo,
 199        git: "https://github.com/rrrene/credo.git",
 200        ref: "1c1b99ea41a457761383d81aaf6a606913996fe7",
 201        only: [:dev, :test],
 202        runtime: false},
 203       {:mock, "~> 0.3.7", only: :test},
 204       {:excoveralls, "0.15.1", only: :test},
 205       {:mox, "~> 1.0", only: :test},
 206       {:websockex, "~> 0.4.3", only: :test},
 207       {:dialyxir, "~> 1.0", only: [:dev], runtime: false}
 208     ] ++ oauth_deps()
 209   end
 210
 211   # Aliases are shortcuts or tasks specific to the current project.
 212   # For example, to create, migrate and run the seeds file at once:
 213   #
 214   #     $ mix ecto.setup
 215   #
 216   # See the documentation for `Mix` for more info on aliases.
 217   defp aliases do
 218     [
 219       "ecto.migrate": ["pleroma.ecto.migrate"],
 220       "ecto.rollback": ["pleroma.ecto.rollback"],
 221       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 222       "ecto.reset": ["ecto.drop", "ecto.setup"],
 223       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 224       docs: ["pleroma.docs", "docs"],
 225       analyze: ["credo --strict --only=warnings,todo,fixme,consistency,readability"],
 226       copyright: &add_copyright/1,
 227       "copyright.bump": &bump_copyright/1
 228     ]
 229   end
 230
 231   # Builds a version string made of:
 232   # * the application version
 233   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 234   # * branch name
 235   # * build metadata:
 236   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 237   #   * the mix environment if different than prod
 238   defp version(version) do
 239     identifier_filter = ~r/[^0-9a-z\-]+/i
 240
 241     git_available? = match?({_output, 0}, System.cmd("sh", ["-c", "command -v git"]))
 242     dotgit_present? = File.exists?(".git")
 243
 244     git_pre_release =
 245       if git_available? and dotgit_present? do
 246         {tag, tag_err} =
 247           System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true)
 248
 249         {describe, describe_err} = System.cmd("git", ["describe", "--tags", "--abbrev=8"])
 250         {commit_hash, commit_hash_err} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 251
 252         # Pre-release version, denoted from patch version with a hyphen
 253         cond do
 254           tag_err == 0 and describe_err == 0 ->
 255             describe
 256             |> String.trim()
 257             |> String.replace(String.trim(tag), "")
 258             |> String.trim_leading("-")
 259             |> String.trim()
 260
 261           commit_hash_err == 0 ->
 262             "0-g" <> String.trim(commit_hash)
 263
 264           true ->
 265             nil
 266         end
 267       end
 268
 269     # Branch name as pre-release version component, denoted with a dot
 270     branch_name =
 271       with true <- git_available?,
 272            true <- dotgit_present?,
 273            {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 274            branch_name <- String.trim(branch_name),
 275            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 276            true <-
 277              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 278                String.starts_with?(name, branch_name)
 279              end) do
 280         branch_name =
 281           branch_name
 282           |> String.trim()
 283           |> String.replace(identifier_filter, "-")
 284
 285         branch_name
 286       else
 287         _ -> ""
 288       end
 289
 290     build_name =
 291       cond do
 292         name = Application.get_env(:pleroma, :build_name) -> name
 293         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 294         true -> nil
 295       end
 296
 297     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 298     env_override = System.get_env("PLEROMA_BUILD_ENV")
 299
 300     env_name =
 301       case env_override do
 302         nil -> env_name
 303         env_override when env_override in ["", "prod"] -> nil
 304         env_override -> env_override
 305       end
 306
 307     # Pre-release version, denoted by appending a hyphen
 308     # and a series of dot separated identifiers
 309     pre_release =
 310       [git_pre_release, branch_name]
 311       |> Enum.filter(fn string -> string && string != "" end)
 312       |> Enum.join(".")
 313       |> (fn
 314             "" -> nil
 315             string -> "-" <> String.replace(string, identifier_filter, "-")
 316           end).()
 317
 318     # Build metadata, denoted with a plus sign
 319     build_metadata =
 320       [build_name, env_name]
 321       |> Enum.filter(fn string -> string && string != "" end)
 322       |> Enum.join(".")
 323       |> (fn
 324             "" -> nil
 325             string -> "+" <> String.replace(string, identifier_filter, "-")
 326           end).()
 327
 328     [version, pre_release, build_metadata]
 329     |> Enum.filter(fn string -> string && string != "" end)
 330     |> Enum.join()
 331   end
 332
 333   defp add_copyright(_) do
 334     year = NaiveDateTime.utc_now().year
 335     template = ~s[\
 336 # Pleroma: A lightweight social networking server
 337 # Copyright © 2017-#{year} Pleroma Authors <https://pleroma.social/>
 338 # SPDX-License-Identifier: AGPL-3.0-only
 339 # Akkoma: Magically expressive social media
 340 # Copyright © 2022-#{year} Akkoma Authors <https://akkoma.dev/>
 341 # SPDX-License-Identifier: AGPL-3.0-only
 342
 343 ] |> String.replace("\n", "\\n")
 344
 345     find = "find lib test priv -type f \\( -name '*.ex' -or -name '*.exs' \\) -exec "
 346     grep = "grep -L '# Copyright © [0-9\-]* Pleroma' {} \\;"
 347     xargs = "xargs -n1 sed -i'' '1s;^;#{template};'"
 348
 349     :os.cmd(String.to_charlist("#{find}#{grep} | #{xargs}"))
 350   end
 351
 352   defp bump_copyright(_) do
 353     year = NaiveDateTime.utc_now().year
 354     find = "find lib test priv -type f \\( -name '*.ex' -or -name '*.exs' \\)"
 355
 356     xargs =
 357       "xargs sed -i'' 's;# Copyright © [0-9\-]* Pleroma.*$;# Copyright © 2017-#{year} Pleroma Authors <https://pleroma.social/>;'"
 358
 359     :os.cmd(String.to_charlist("#{find} | #{xargs}"))
 360   end
 361 end