git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("0.9.0"),
   8       elixir: "~> 1.7",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: true],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ]
  36     ]
  37   end
  38
  39   # Configuration for the OTP application.
  40   #
  41   # Type `mix help compile.app` for more information.
  42   def application do
  43     [
  44       mod: {Pleroma.Application, []},
  45       extra_applications: [:logger, :runtime_tools, :comeonin, :quack],
  46       included_applications: [:ex_syslogger]
  47     ]
  48   end
  49
  50   # Specifies which paths to compile per environment.
  51   defp elixirc_paths(:test), do: ["lib", "test/support"]
  52   defp elixirc_paths(_), do: ["lib"]
  53
  54   # Specifies OAuth dependencies.
  55   defp oauth_deps do
  56     oauth_strategy_packages =
  57       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  58       |> to_string()
  59       |> String.split()
  60       |> Enum.map(fn strategy_entry ->
  61         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
  62           dependency
  63         else
  64           [strategy] -> "ueberauth_#{strategy}"
  65         end
  66       end)
  67
  68     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
  69   end
  70
  71   # Specifies your project dependencies.
  72   #
  73   # Type `mix help deps` for examples and options.
  74   defp deps do
  75     [
  76       {:phoenix, "~> 1.4.1"},
  77       {:plug_cowboy, "~> 2.0"},
  78       {:phoenix_pubsub, "~> 1.1"},
  79       {:phoenix_ecto, "~> 4.0"},
  80       {:ecto_sql, "~> 3.1"},
  81       {:postgrex, ">= 0.13.5"},
  82       {:gettext, "~> 0.15"},
  83       {:comeonin, "~> 4.1.1"},
  84       {:pbkdf2_elixir, "~> 0.12.3"},
  85       {:trailing_format_plug, "~> 0.0.7"},
  86       {:html_sanitize_ex, "~> 1.3.0"},
  87       {:html_entities, "~> 0.4"},
  88       {:phoenix_html, "~> 2.10"},
  89       {:calendar, "~> 0.17.4"},
  90       {:cachex, "~> 3.0.2"},
  91       {:httpoison, "~> 1.2.0"},
  92       {:poison, "~> 3.0", override: true},
  93       {:tesla, "~> 1.2"},
  94       {:jason, "~> 1.0"},
  95       {:mogrify, "~> 0.6.1"},
  96       {:ex_aws, "~> 2.0"},
  97       {:ex_aws_s3, "~> 2.0"},
  98       {:earmark, "~> 1.3"},
  99       {:bbcode, "~> 0.1"},
 100       {:ex_machina, "~> 2.3", only: :test},
 101       {:credo, "~> 0.9.3", only: [:dev, :test]},
 102       {:mock, "~> 0.3.3", only: :test},
 103       {:crypt,
 104        git: "https://github.com/msantos/crypt", ref: "1f2b58927ab57e72910191a7ebaeff984382a1d3"},
 105       {:cors_plug, "~> 1.5"},
 106       {:ex_doc, "~> 0.20.2", only: :dev, runtime: false},
 107       {:web_push_encryption, "~> 0.2.1"},
 108       {:swoosh, "~> 0.20"},
 109       {:phoenix_swoosh, "~> 0.2"},
 110       {:gen_smtp, "~> 0.13"},
 111       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test},
 112       {:floki, "~> 0.20.0"},
 113       {:ex_syslogger, github: "slashmili/ex_syslogger", tag: "1.4.0"},
 114       {:timex, "~> 3.5"},
 115       {:ueberauth, "~> 0.4"},
 116       {:auto_linker,
 117        git: "https://git.pleroma.social/pleroma/auto_linker.git",
 118        ref: "c00c4e75b35367fa42c95ffd9b8c455bf9995829"},
 119       {:http_signatures,
 120        git: "https://git.pleroma.social/pleroma/http_signatures.git",
 121        ref: "9789401987096ead65646b52b5a2ca6bf52fc531"},
 122       {:pleroma_job_queue, "~> 0.2.0"},
 123       {:telemetry, "~> 0.3"},
 124       {:prometheus_ex, "~> 3.0"},
 125       {:prometheus_plugs, "~> 1.1"},
 126       {:prometheus_phoenix, "~> 1.2"},
 127       {:prometheus_ecto, "~> 1.4"},
 128       {:prometheus_process_collector, "~> 1.4"},
 129       {:recon, github: "ferd/recon", tag: "2.4.0"},
 130       {:quack, "~> 0.1.1"},
 131       {:quantum, "~> 2.3"},
 132       {:joken, "~> 2.0"},
 133       {:benchee, "~> 1.0"},
 134       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 135       {:ex_rated, "~> 1.2"},
 136       {:plug_static_index_html, "~> 1.0.0"},
 137       {:excoveralls, "~> 0.11.1", only: :test}
 138     ] ++ oauth_deps()
 139   end
 140
 141   # Aliases are shortcuts or tasks specific to the current project.
 142   # For example, to create, migrate and run the seeds file at once:
 143   #
 144   #     $ mix ecto.setup
 145   #
 146   # See the documentation for `Mix` for more info on aliases.
 147   defp aliases do
 148     [
 149       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 150       "ecto.reset": ["ecto.drop", "ecto.setup"],
 151       test: ["ecto.create --quiet", "ecto.migrate", "test"]
 152     ]
 153   end
 154
 155   # Builds a version string made of:
 156   # * the application version
 157   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 158   # * build info:
 159   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 160   #   * the mix environment if different than prod
 161   defp version(version) do
 162     {git_tag, git_pre_release} =
 163       with {tag, 0} <-
 164              System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true),
 165            tag = String.trim(tag),
 166            {describe, 0} <- System.cmd("git", ["describe", "--tags", "--abbrev=8"]),
 167            describe = String.trim(describe),
 168            ahead <- String.replace(describe, tag, "") do
 169         {String.replace_prefix(tag, "v", ""), if(ahead != "", do: String.trim(ahead))}
 170       else
 171         _ -> {nil, nil}
 172       end
 173
 174     if git_tag && version != git_tag do
 175       Mix.shell().error(
 176         "Application version #{inspect(version)} does not match git tag #{inspect(git_tag)}"
 177       )
 178     end
 179
 180     build_name =
 181       cond do
 182         name = Application.get_env(:pleroma, :build_name) -> name
 183         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 184         true -> nil
 185       end
 186
 187     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 188
 189     build =
 190       [build_name, env_name]
 191       |> Enum.filter(fn string -> string && string != "" end)
 192       |> Enum.join("-")
 193       |> (fn
 194             "" -> nil
 195             string -> "+" <> string
 196           end).()
 197
 198     [version, git_pre_release, build]
 199     |> Enum.filter(fn string -> string && string != "" end)
 200     |> Enum.join()
 201   end
 202 end