git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("2.1.50"),
   8       elixir: "~> 1.9",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: warnings_as_errors(Mix.env())],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/static/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load, eldap: :transient],
  40           steps: [:assemble, &put_otp_version/1, &copy_files/1, &copy_nginx_config/1]
  41         ]
  42       ]
  43     ]
  44   end
  45
  46   def put_otp_version(%{path: target_path} = release) do
  47     File.write!(
  48       Path.join([target_path, "OTP_VERSION"]),
  49       Pleroma.OTPVersion.version()
  50     )
  51
  52     release
  53   end
  54
  55   def copy_files(%{path: target_path} = release) do
  56     File.cp_r!("./rel/files", target_path)
  57     release
  58   end
  59
  60   def copy_nginx_config(%{path: target_path} = release) do
  61     File.cp!(
  62       "./installation/pleroma.nginx",
  63       Path.join([target_path, "installation", "pleroma.nginx"])
  64     )
  65
  66     release
  67   end
  68
  69   # Configuration for the OTP application.
  70   #
  71   # Type `mix help compile.app` for more information.
  72   def application do
  73     [
  74       mod: {Pleroma.Application, []},
  75       extra_applications: [
  76         :logger,
  77         :runtime_tools,
  78         :comeonin,
  79         :quack,
  80         :fast_sanitize,
  81         :ssl
  82       ],
  83       included_applications: [:ex_syslogger]
  84     ]
  85   end
  86
  87   # Specifies which paths to compile per environment.
  88   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  89   defp elixirc_paths(:test), do: ["lib", "test/support"]
  90   defp elixirc_paths(_), do: ["lib"]
  91
  92   defp warnings_as_errors(:prod), do: false
  93   defp warnings_as_errors(_), do: true
  94
  95   # Specifies OAuth dependencies.
  96   defp oauth_deps do
  97     oauth_strategy_packages =
  98       System.get_env("OAUTH_CONSUMER_STRATEGIES")
  99       |> to_string()
 100       |> String.split()
 101       |> Enum.map(fn strategy_entry ->
 102         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
 103           dependency
 104         else
 105           [strategy] -> "ueberauth_#{strategy}"
 106         end
 107       end)
 108
 109     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
 110   end
 111
 112   # Specifies your project dependencies.
 113   #
 114   # Type `mix help deps` for examples and options.
 115   defp deps do
 116     [
 117       {:phoenix, "~> 1.5.5"},
 118       {:tzdata, "~> 1.0.3"},
 119       {:plug_cowboy, "~> 2.3"},
 120       {:phoenix_pubsub, "~> 2.0"},
 121       {:phoenix_ecto, "~> 4.0"},
 122       {:ecto_enum, "~> 1.4"},
 123       {:ecto_sql, "~> 3.4.4"},
 124       {:postgrex, ">= 0.15.5"},
 125       {:oban, "~> 2.1.0"},
 126       {:gettext, "~> 0.18"},
 127       {:pbkdf2_elixir, "~> 1.2"},
 128       {:bcrypt_elixir, "~> 2.2"},
 129       {:trailing_format_plug, "~> 0.0.7"},
 130       {:fast_sanitize, "~> 0.2.0"},
 131       {:html_entities, "~> 0.5", override: true},
 132       {:phoenix_html, "~> 2.14"},
 133       {:calendar, "~> 1.0"},
 134       {:cachex, "~> 3.2"},
 135       {:poison, "~> 3.0", override: true},
 136       {:tesla, "~> 1.4.0", override: true},
 137       {:castore, "~> 0.1"},
 138       {:cowlib, "~> 2.9", override: true},
 139       {:gun,
 140        github: "ninenines/gun", ref: "921c47146b2d9567eac7e9a4d2ccc60fffd4f327", override: true},
 141       {:jason, "~> 1.2"},
 142       {:mogrify, "~> 0.7.4"},
 143       {:ex_aws, "~> 2.1"},
 144       {:ex_aws_s3, "~> 2.0"},
 145       {:sweet_xml, "~> 0.6.6"},
 146       {:earmark, "1.4.3"},
 147       {:bbcode_pleroma, "~> 0.2.0"},
 148       {:crypt,
 149        git: "https://github.com/msantos/crypt.git",
 150        ref: "f63a705f92c26955977ee62a313012e309a4d77a"},
 151       {:cors_plug, "~> 2.0"},
 152       {:web_push_encryption, "~> 0.3"},
 153       {:swoosh, "~> 1.0"},
 154       {:phoenix_swoosh, "~> 0.3"},
 155       {:gen_smtp, "~> 0.13"},
 156       {:ex_syslogger, "~> 1.4"},
 157       {:floki, "~> 0.27"},
 158       {:timex, "~> 3.6"},
 159       {:ueberauth, "~> 0.4"},
 160       {:linkify, "~> 0.2.0"},
 161       {:http_signatures, "~> 0.1.0"},
 162       {:telemetry, "~> 0.3"},
 163       {:poolboy, "~> 1.5"},
 164       {:prometheus, "~> 4.6"},
 165       {:prometheus_ex,
 166        git: "https://git.pleroma.social/pleroma/elixir-libraries/prometheus.ex.git",
 167        ref: "a4e9beb3c1c479d14b352fd9d6dd7b1f6d7deee5",
 168        override: true},
 169       {:prometheus_plugs, "~> 1.1"},
 170       {:prometheus_phoenix, "~> 1.3"},
 171       # Note: once `prometheus_phx` is integrated into `prometheus_phoenix`, remove the former:
 172       {:prometheus_phx,
 173        git: "https://git.pleroma.social/pleroma/elixir-libraries/prometheus-phx.git",
 174        branch: "no-logging"},
 175       {:prometheus_ecto, "~> 1.4"},
 176       {:recon, "~> 2.5"},
 177       {:quack, "~> 0.1.1"},
 178       {:joken, "~> 2.0"},
 179       {:benchee, "~> 1.0"},
 180       {:pot, "~> 0.11"},
 181       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 182       {:ex_const, "~> 0.2"},
 183       {:plug_static_index_html, "~> 1.0.0"},
 184       {:flake_id, "~> 0.1.0"},
 185       {:concurrent_limiter,
 186        git: "https://git.pleroma.social/pleroma/elixir-libraries/concurrent_limiter.git",
 187        ref: "d81be41024569330f296fc472e24198d7499ba78"},
 188       {:remote_ip,
 189        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 190        ref: "b647d0deecaa3acb140854fe4bda5b7e1dc6d1c8"},
 191       {:captcha,
 192        git: "https://git.pleroma.social/pleroma/elixir-libraries/elixir-captcha.git",
 193        ref: "e0f16822d578866e186a0974d65ad58cddc1e2ab"},
 194       {:restarter, path: "./restarter"},
 195       {:majic,
 196        git: "https://git.pleroma.social/pleroma/elixir-libraries/majic.git", branch: "develop"},
 197       {:open_api_spex,
 198        git: "https://git.pleroma.social/pleroma/elixir-libraries/open_api_spex.git",
 199        ref: "f296ac0924ba3cf79c7a588c4c252889df4c2edd"},
 200
 201       ## dev & test
 202       {:ex_doc, "~> 0.22", only: :dev, runtime: false},
 203       {:ex_machina, "~> 2.4", only: :test},
 204       {:credo, "~> 1.4", only: [:dev, :test], runtime: false},
 205       {:mock, "~> 0.3.5", only: :test},
 206       # temporary downgrade for excoveralls, hackney until hackney max_connections bug will be fixed
 207       {:excoveralls, "0.12.3", only: :test},
 208       {:hackney, "1.15.2", override: true},
 209       {:mox, "~> 0.5", only: :test},
 210       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test}
 211     ] ++ oauth_deps()
 212   end
 213
 214   # Aliases are shortcuts or tasks specific to the current project.
 215   # For example, to create, migrate and run the seeds file at once:
 216   #
 217   #     $ mix ecto.setup
 218   #
 219   # See the documentation for `Mix` for more info on aliases.
 220   defp aliases do
 221     [
 222       "ecto.migrate": ["pleroma.ecto.migrate"],
 223       "ecto.rollback": ["pleroma.ecto.rollback"],
 224       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 225       "ecto.reset": ["ecto.drop", "ecto.setup"],
 226       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 227       docs: ["pleroma.docs", "docs"],
 228       analyze: ["credo --strict --only=warnings,todo,fixme,consistency,readability"]
 229     ]
 230   end
 231
 232   # Builds a version string made of:
 233   # * the application version
 234   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 235   # * branch name
 236   # * build metadata:
 237   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 238   #   * the mix environment if different than prod
 239   defp version(version) do
 240     identifier_filter = ~r/[^0-9a-z\-]+/i
 241
 242     git_available? = match?({_output, 0}, System.cmd("sh", ["-c", "command -v git"]))
 243
 244     git_pre_release =
 245       if git_available? do
 246         {tag, tag_err} =
 247           System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true)
 248
 249         {describe, describe_err} = System.cmd("git", ["describe", "--tags", "--abbrev=8"])
 250         {commit_hash, commit_hash_err} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 251
 252         # Pre-release version, denoted from patch version with a hyphen
 253         cond do
 254           tag_err == 0 and describe_err == 0 ->
 255             describe
 256             |> String.trim()
 257             |> String.replace(String.trim(tag), "")
 258             |> String.trim_leading("-")
 259             |> String.trim()
 260
 261           commit_hash_err == 0 ->
 262             "0-g" <> String.trim(commit_hash)
 263
 264           true ->
 265             nil
 266         end
 267       end
 268
 269     # Branch name as pre-release version component, denoted with a dot
 270     branch_name =
 271       with true <- git_available?,
 272            {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 273            branch_name <- String.trim(branch_name),
 274            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 275            true <-
 276              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 277                String.starts_with?(name, branch_name)
 278              end) do
 279         branch_name =
 280           branch_name
 281           |> String.trim()
 282           |> String.replace(identifier_filter, "-")
 283
 284         branch_name
 285       else
 286         _ -> ""
 287       end
 288
 289     build_name =
 290       cond do
 291         name = Application.get_env(:pleroma, :build_name) -> name
 292         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 293         true -> nil
 294       end
 295
 296     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 297     env_override = System.get_env("PLEROMA_BUILD_ENV")
 298
 299     env_name =
 300       case env_override do
 301         nil -> env_name
 302         env_override when env_override in ["", "prod"] -> nil
 303         env_override -> env_override
 304       end
 305
 306     # Pre-release version, denoted by appending a hyphen
 307     # and a series of dot separated identifiers
 308     pre_release =
 309       [git_pre_release, branch_name]
 310       |> Enum.filter(fn string -> string && string != "" end)
 311       |> Enum.join(".")
 312       |> (fn
 313             "" -> nil
 314             string -> "-" <> String.replace(string, identifier_filter, "-")
 315           end).()
 316
 317     # Build metadata, denoted with a plus sign
 318     build_metadata =
 319       [build_name, env_name]
 320       |> Enum.filter(fn string -> string && string != "" end)
 321       |> Enum.join(".")
 322       |> (fn
 323             "" -> nil
 324             string -> "+" <> String.replace(string, identifier_filter, "-")
 325           end).()
 326
 327     [version, pre_release, build_metadata]
 328     |> Enum.filter(fn string -> string && string != "" end)
 329     |> Enum.join()
 330   end
 331 end