git.squeep.com Git - akkoma/blob - mix.exs

   1 defmodule Pleroma.Mixfile do
   2   use Mix.Project
   3
   4   def project do
   5     [
   6       app: :pleroma,
   7       version: version("2.3.0"),
   8       elixir: "~> 1.9",
   9       elixirc_paths: elixirc_paths(Mix.env()),
  10       compilers: [:phoenix, :gettext] ++ Mix.compilers(),
  11       elixirc_options: [warnings_as_errors: warnings_as_errors(Mix.env())],
  12       xref: [exclude: [:eldap]],
  13       start_permanent: Mix.env() == :prod,
  14       aliases: aliases(),
  15       deps: deps(),
  16       test_coverage: [tool: ExCoveralls],
  17       preferred_cli_env: ["coveralls.html": :test],
  18       # Docs
  19       name: "Pleroma",
  20       homepage_url: "https://pleroma.social/",
  21       source_url: "https://git.pleroma.social/pleroma/pleroma",
  22       docs: [
  23         source_url_pattern:
  24           "https://git.pleroma.social/pleroma/pleroma/blob/develop/%{path}#L%{line}",
  25         logo: "priv/static/images/logo.png",
  26         extras: ["README.md", "CHANGELOG.md"] ++ Path.wildcard("docs/**/*.md"),
  27         groups_for_extras: [
  28           "Installation manuals": Path.wildcard("docs/installation/*.md"),
  29           Configuration: Path.wildcard("docs/config/*.md"),
  30           Administration: Path.wildcard("docs/admin/*.md"),
  31           "Pleroma's APIs and Mastodon API extensions": Path.wildcard("docs/api/*.md")
  32         ],
  33         main: "readme",
  34         output: "priv/static/doc"
  35       ],
  36       releases: [
  37         pleroma: [
  38           include_executables_for: [:unix],
  39           applications: [ex_syslogger: :load, syslog: :load, eldap: :transient],
  40           steps: [:assemble, &put_otp_version/1, &copy_files/1, &copy_nginx_config/1],
  41           config_providers: [{Pleroma.Config.ReleaseRuntimeProvider, nil}]
  42         ]
  43       ]
  44     ]
  45   end
  46
  47   def put_otp_version(%{path: target_path} = release) do
  48     File.write!(
  49       Path.join([target_path, "OTP_VERSION"]),
  50       Pleroma.OTPVersion.version()
  51     )
  52
  53     release
  54   end
  55
  56   def copy_files(%{path: target_path} = release) do
  57     File.cp_r!("./rel/files", target_path)
  58     release
  59   end
  60
  61   def copy_nginx_config(%{path: target_path} = release) do
  62     File.cp!(
  63       "./installation/pleroma.nginx",
  64       Path.join([target_path, "installation", "pleroma.nginx"])
  65     )
  66
  67     release
  68   end
  69
  70   # Configuration for the OTP application.
  71   #
  72   # Type `mix help compile.app` for more information.
  73   def application do
  74     [
  75       mod: {Pleroma.Application, []},
  76       extra_applications: [
  77         :logger,
  78         :runtime_tools,
  79         :comeonin,
  80         :quack,
  81         :fast_sanitize,
  82         :ssl
  83       ],
  84       included_applications: [:ex_syslogger]
  85     ]
  86   end
  87
  88   # Specifies which paths to compile per environment.
  89   defp elixirc_paths(:benchmark), do: ["lib", "benchmarks"]
  90   defp elixirc_paths(:test), do: ["lib", "test/support"]
  91   defp elixirc_paths(_), do: ["lib"]
  92
  93   defp warnings_as_errors(:prod), do: false
  94   defp warnings_as_errors(_), do: true
  95
  96   # Specifies OAuth dependencies.
  97   defp oauth_deps do
  98     oauth_strategy_packages =
  99       System.get_env("OAUTH_CONSUMER_STRATEGIES")
 100       |> to_string()
 101       |> String.split()
 102       |> Enum.map(fn strategy_entry ->
 103         with [_strategy, dependency] <- String.split(strategy_entry, ":") do
 104           dependency
 105         else
 106           [strategy] -> "ueberauth_#{strategy}"
 107         end
 108       end)
 109
 110     for s <- oauth_strategy_packages, do: {String.to_atom(s), ">= 0.0.0"}
 111   end
 112
 113   # Specifies your project dependencies.
 114   #
 115   # Type `mix help deps` for examples and options.
 116   defp deps do
 117     [
 118       {:phoenix, "~> 1.5.5"},
 119       {:tzdata, "~> 1.0.3"},
 120       {:plug_cowboy, "~> 2.3"},
 121       {:phoenix_pubsub, "~> 2.0"},
 122       {:phoenix_ecto, "~> 4.0"},
 123       {:ecto_enum, "~> 1.4"},
 124       {:ecto_sql, "~> 3.4.4"},
 125       {:postgrex, ">= 0.15.5"},
 126       {:oban, "~> 2.3.4"},
 127       {:gettext, "~> 0.18"},
 128       {:bcrypt_elixir, "~> 2.2"},
 129       {:trailing_format_plug, "~> 0.0.7"},
 130       {:fast_sanitize, "~> 0.2.0"},
 131       {:html_entities, "~> 0.5", override: true},
 132       {:phoenix_html, "~> 2.14"},
 133       {:calendar, "~> 1.0"},
 134       {:cachex, "~> 3.2"},
 135       {:poison, "~> 3.0", override: true},
 136       {:tesla, "~> 1.4.0", override: true},
 137       {:castore, "~> 0.1"},
 138       {:cowlib, "~> 2.9", override: true},
 139       {:gun,
 140        github: "ninenines/gun", ref: "921c47146b2d9567eac7e9a4d2ccc60fffd4f327", override: true},
 141       {:jason, "~> 1.2"},
 142       {:mogrify, "~> 0.7.4"},
 143       {:ex_aws, "~> 2.1.6"},
 144       {:ex_aws_s3, "~> 2.0"},
 145       {:sweet_xml, "~> 0.6.6"},
 146       {:earmark, "1.4.3"},
 147       {:bbcode_pleroma, "~> 0.2.0"},
 148       {:crypt,
 149        git: "https://git.pleroma.social/pleroma/elixir-libraries/crypt.git",
 150        ref: "cf2aa3f11632e8b0634810a15b3e612c7526f6a3"},
 151       {:cors_plug, "~> 2.0"},
 152       {:web_push_encryption, "~> 0.3"},
 153       {:swoosh, "~> 1.0"},
 154       {:phoenix_swoosh, "~> 0.3"},
 155       {:gen_smtp, "~> 0.13"},
 156       {:ex_syslogger, "~> 1.4"},
 157       {:floki, "~> 0.27"},
 158       {:timex, "~> 3.6"},
 159       {:ueberauth, "~> 0.4"},
 160       {:linkify, "~> 0.5.0"},
 161       {:http_signatures, "~> 0.1.0"},
 162       {:telemetry, "~> 0.3"},
 163       {:poolboy, "~> 1.5"},
 164       {:prometheus, "~> 4.6"},
 165       {:prometheus_ex,
 166        git: "https://git.pleroma.social/pleroma/elixir-libraries/prometheus.ex.git",
 167        ref: "a4e9beb3c1c479d14b352fd9d6dd7b1f6d7deee5",
 168        override: true},
 169       {:prometheus_plugs, "~> 1.1"},
 170       {:prometheus_phoenix, "~> 1.3"},
 171       # Note: once `prometheus_phx` is integrated into `prometheus_phoenix`, remove the former:
 172       {:prometheus_phx,
 173        git: "https://git.pleroma.social/pleroma/elixir-libraries/prometheus-phx.git",
 174        branch: "no-logging"},
 175       {:prometheus_ecto, "~> 1.4"},
 176       {:recon, "~> 2.5"},
 177       {:quack, "~> 0.1.1"},
 178       {:joken, "~> 2.0"},
 179       {:benchee, "~> 1.0"},
 180       {:pot, "~> 0.11"},
 181       {:esshd, "~> 0.1.0", runtime: Application.get_env(:esshd, :enabled, false)},
 182       {:ex_const, "~> 0.2"},
 183       {:plug_static_index_html, "~> 1.0.0"},
 184       {:flake_id, "~> 0.1.0"},
 185       {:concurrent_limiter,
 186        git: "https://git.pleroma.social/pleroma/elixir-libraries/concurrent_limiter.git",
 187        ref: "d81be41024569330f296fc472e24198d7499ba78"},
 188       {:remote_ip,
 189        git: "https://git.pleroma.social/pleroma/remote_ip.git",
 190        ref: "b647d0deecaa3acb140854fe4bda5b7e1dc6d1c8"},
 191       {:captcha,
 192        git: "https://git.pleroma.social/pleroma/elixir-libraries/elixir-captcha.git",
 193        ref: "e0f16822d578866e186a0974d65ad58cddc1e2ab"},
 194       {:restarter, path: "./restarter"},
 195       {:majic,
 196        git: "https://git.pleroma.social/pleroma/elixir-libraries/majic.git",
 197        ref: "289cda1b6d0d70ccb2ba508a2b0bd24638db2880"},
 198       {:open_api_spex,
 199        git: "https://git.pleroma.social/pleroma/elixir-libraries/open_api_spex.git",
 200        ref: "f296ac0924ba3cf79c7a588c4c252889df4c2edd"},
 201       {:eblurhash,
 202        git: "https://github.com/zotonic/eblurhash.git",
 203        ref: "04a0b76eadf4de1be17726f39b6313b88708fd12"},
 204
 205       ## dev & test
 206       {:ex_doc, "~> 0.22", only: :dev, runtime: false},
 207       {:ex_machina, "~> 2.4", only: :test},
 208       {:credo, "~> 1.4", only: [:dev, :test], runtime: false},
 209       {:mock, "~> 0.3.5", only: :test},
 210       # temporary downgrade for excoveralls, hackney until hackney max_connections bug will be fixed
 211       {:excoveralls, "0.12.3", only: :test},
 212       {:hackney,
 213        git: "https://git.pleroma.social/pleroma/elixir-libraries/hackney.git",
 214        ref: "7d7119f0651515d6d7669c78393fd90950a3ec6e",
 215        override: true},
 216       {:mox, "~> 1.0", only: :test},
 217       {:websocket_client, git: "https://github.com/jeremyong/websocket_client.git", only: :test}
 218     ] ++ oauth_deps()
 219   end
 220
 221   # Aliases are shortcuts or tasks specific to the current project.
 222   # For example, to create, migrate and run the seeds file at once:
 223   #
 224   #     $ mix ecto.setup
 225   #
 226   # See the documentation for `Mix` for more info on aliases.
 227   defp aliases do
 228     [
 229       "ecto.migrate": ["pleroma.ecto.migrate"],
 230       "ecto.rollback": ["pleroma.ecto.rollback"],
 231       "ecto.setup": ["ecto.create", "ecto.migrate", "run priv/repo/seeds.exs"],
 232       "ecto.reset": ["ecto.drop", "ecto.setup"],
 233       test: ["ecto.create --quiet", "ecto.migrate", "test"],
 234       docs: ["pleroma.docs", "docs"],
 235       analyze: ["credo --strict --only=warnings,todo,fixme,consistency,readability"],
 236       copyright: &add_copyright/1,
 237       "copyright.bump": &bump_copyright/1
 238     ]
 239   end
 240
 241   # Builds a version string made of:
 242   # * the application version
 243   # * a pre-release if ahead of the tag: the describe string (-count-commithash)
 244   # * branch name
 245   # * build metadata:
 246   #   * a build name if `PLEROMA_BUILD_NAME` or `:pleroma, :build_name` is defined
 247   #   * the mix environment if different than prod
 248   defp version(version) do
 249     identifier_filter = ~r/[^0-9a-z\-]+/i
 250
 251     git_available? = match?({_output, 0}, System.cmd("sh", ["-c", "command -v git"]))
 252
 253     git_pre_release =
 254       if git_available? do
 255         {tag, tag_err} =
 256           System.cmd("git", ["describe", "--tags", "--abbrev=0"], stderr_to_stdout: true)
 257
 258         {describe, describe_err} = System.cmd("git", ["describe", "--tags", "--abbrev=8"])
 259         {commit_hash, commit_hash_err} = System.cmd("git", ["rev-parse", "--short", "HEAD"])
 260
 261         # Pre-release version, denoted from patch version with a hyphen
 262         cond do
 263           tag_err == 0 and describe_err == 0 ->
 264             describe
 265             |> String.trim()
 266             |> String.replace(String.trim(tag), "")
 267             |> String.trim_leading("-")
 268             |> String.trim()
 269
 270           commit_hash_err == 0 ->
 271             "0-g" <> String.trim(commit_hash)
 272
 273           true ->
 274             nil
 275         end
 276       end
 277
 278     # Branch name as pre-release version component, denoted with a dot
 279     branch_name =
 280       with true <- git_available?,
 281            {branch_name, 0} <- System.cmd("git", ["rev-parse", "--abbrev-ref", "HEAD"]),
 282            branch_name <- String.trim(branch_name),
 283            branch_name <- System.get_env("PLEROMA_BUILD_BRANCH") || branch_name,
 284            true <-
 285              !Enum.any?(["master", "HEAD", "release/", "stable"], fn name ->
 286                String.starts_with?(name, branch_name)
 287              end) do
 288         branch_name =
 289           branch_name
 290           |> String.trim()
 291           |> String.replace(identifier_filter, "-")
 292
 293         branch_name
 294       else
 295         _ -> ""
 296       end
 297
 298     build_name =
 299       cond do
 300         name = Application.get_env(:pleroma, :build_name) -> name
 301         name = System.get_env("PLEROMA_BUILD_NAME") -> name
 302         true -> nil
 303       end
 304
 305     env_name = if Mix.env() != :prod, do: to_string(Mix.env())
 306     env_override = System.get_env("PLEROMA_BUILD_ENV")
 307
 308     env_name =
 309       case env_override do
 310         nil -> env_name
 311         env_override when env_override in ["", "prod"] -> nil
 312         env_override -> env_override
 313       end
 314
 315     # Pre-release version, denoted by appending a hyphen
 316     # and a series of dot separated identifiers
 317     pre_release =
 318       [git_pre_release, branch_name]
 319       |> Enum.filter(fn string -> string && string != "" end)
 320       |> Enum.join(".")
 321       |> (fn
 322             "" -> nil
 323             string -> "-" <> String.replace(string, identifier_filter, "-")
 324           end).()
 325
 326     # Build metadata, denoted with a plus sign
 327     build_metadata =
 328       [build_name, env_name]
 329       |> Enum.filter(fn string -> string && string != "" end)
 330       |> Enum.join(".")
 331       |> (fn
 332             "" -> nil
 333             string -> "+" <> String.replace(string, identifier_filter, "-")
 334           end).()
 335
 336     [version, pre_release, build_metadata]
 337     |> Enum.filter(fn string -> string && string != "" end)
 338     |> Enum.join()
 339   end
 340
 341   defp add_copyright(_) do
 342     year = NaiveDateTime.utc_now().year
 343     template = ~s[\
 344 # Pleroma: A lightweight social networking server
 345 # Copyright © 2017-#{year} Pleroma Authors <https://pleroma.social/>
 346 # SPDX-License-Identifier: AGPL-3.0-only
 347
 348 ] |> String.replace("\n", "\\n")
 349
 350     find = "find lib test priv -type f \\( -name '*.ex' -or -name '*.exs' \\) -exec "
 351     grep = "grep -L '# Copyright © [0-9\-]* Pleroma' {} \\;"
 352     xargs = "xargs -n1 sed -i'' '1s;^;#{template};'"
 353
 354     :os.cmd(String.to_charlist("#{find}#{grep} | #{xargs}"))
 355   end
 356
 357   defp bump_copyright(_) do
 358     year = NaiveDateTime.utc_now().year
 359     find = "find lib test priv -type f \\( -name '*.ex' -or -name '*.exs' \\)"
 360
 361     xargs =
 362       "xargs sed -i'' 's;# Copyright © [0-9\-]* Pleroma.*$;# Copyright © 2017-#{year} Pleroma Authors <https://pleroma.social/>;'"
 363
 364     :os.cmd(String.to_charlist("#{find} | #{xargs}"))
 365   end
 366 end