git.squeep.com Git - akkoma/blob - lib/pleroma/workers/purge_expired_activity.ex

   1 defmodule Pleroma.Workers.PurgeExpiredActivity do
   2   @moduledoc """
   3   Worker which purges expired activity.
   4   """
   5
   6   use Oban.Worker, queue: :activity_expiration, max_attempts: 1
   7
   8   import Ecto.Query
   9
  10   def enqueue(args) do
  11     with true <- enabled?(),
  12          args when is_map(args) <- validate_expires_at(args) do
  13       {scheduled_at, args} = Map.pop(args, :expires_at)
  14
  15       args
  16       |> __MODULE__.new(scheduled_at: scheduled_at)
  17       |> Oban.insert()
  18     end
  19   end
  20
  21   @impl true
  22   def perform(%Oban.Job{args: %{"activity_id" => id}}) do
  23     with %Pleroma.Activity{} = activity <- find_activity(id),
  24          %Pleroma.User{} = user <- find_user(activity.object.data["actor"]),
  25          false <- pinned_by_actor?(activity, user) do
  26       Pleroma.Web.CommonAPI.delete(activity.id, user)
  27     else
  28       :pinned_by_actor ->
  29         # if activity is pinned, schedule deletion on next day
  30         enqueue(%{activity_id: id, expires_at: DateTime.add(DateTime.utc_now(), 24 * 3600)})
  31
  32         :ok
  33
  34       error ->
  35         error
  36     end
  37   end
  38
  39   defp enabled? do
  40     with false <- Pleroma.Config.get([__MODULE__, :enabled], false) do
  41       {:error, :expired_activities_disabled}
  42     end
  43   end
  44
  45   defp validate_expires_at(%{validate: false} = args), do: Map.delete(args, :validate)
  46
  47   defp validate_expires_at(args) do
  48     if expires_late_enough?(args[:expires_at]) do
  49       args
  50     else
  51       {:error, :expiration_too_close}
  52     end
  53   end
  54
  55   defp find_activity(id) do
  56     with nil <- Pleroma.Activity.get_by_id_with_object(id) do
  57       {:error, :activity_not_found}
  58     end
  59   end
  60
  61   defp find_user(ap_id) do
  62     with nil <- Pleroma.User.get_by_ap_id(ap_id) do
  63       {:error, :user_not_found}
  64     end
  65   end
  66
  67   defp pinned_by_actor?(activity, user) do
  68     with true <- Pleroma.Activity.pinned_by_actor?(activity, user) do
  69       :pinned_by_actor
  70     end
  71   end
  72
  73   def get_expiration(id) do
  74     from(j in Oban.Job,
  75       where: j.state == "scheduled",
  76       where: j.queue == "activity_expiration",
  77       where: fragment("?->>'activity_id' = ?", j.args, ^id)
  78     )
  79     |> Pleroma.Repo.one()
  80   end
  81
  82   @spec expires_late_enough?(DateTime.t()) :: boolean()
  83   def expires_late_enough?(scheduled_at) do
  84     now = DateTime.utc_now()
  85     diff = DateTime.diff(scheduled_at, now, :millisecond)
  86     diff > :timer.hours(1)
  87   end
  88 end