git.squeep.com Git - akkoma/blob - lib/pleroma/workers/purge_expired_activity.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Workers.PurgeExpiredActivity do
   6   @moduledoc """
   7   Worker which purges expired activity.
   8   """
   9
  10   use Oban.Worker, queue: :activity_expiration, max_attempts: 1
  11
  12   import Ecto.Query
  13
  14   alias Pleroma.Activity
  15
  16   @spec enqueue(map()) ::
  17           {:ok, Oban.Job.t()}
  18           | {:error, :expired_activities_disabled}
  19           | {:error, :expiration_too_close}
  20   def enqueue(args) do
  21     with true <- enabled?(),
  22          args when is_map(args) <- validate_expires_at(args) do
  23       {scheduled_at, args} = Map.pop(args, :expires_at)
  24
  25       args
  26       |> new(scheduled_at: scheduled_at)
  27       |> Oban.insert()
  28     end
  29   end
  30
  31   @impl true
  32   def perform(%Oban.Job{args: %{"activity_id" => id}}) do
  33     with %Activity{} = activity <- find_activity(id),
  34          %Pleroma.User{} = user <- find_user(activity.object.data["actor"]),
  35          false <- pinned_by_actor?(activity, user) do
  36       Pleroma.Web.CommonAPI.delete(activity.id, user)
  37     else
  38       :pinned_by_actor ->
  39         # if activity is pinned, schedule deletion on next day
  40         enqueue(%{activity_id: id, expires_at: DateTime.add(DateTime.utc_now(), 24 * 3600)})
  41
  42         :ok
  43
  44       error ->
  45         error
  46     end
  47   end
  48
  49   defp enabled? do
  50     with false <- Pleroma.Config.get([__MODULE__, :enabled], false) do
  51       {:error, :expired_activities_disabled}
  52     end
  53   end
  54
  55   defp validate_expires_at(%{validate: false} = args), do: Map.delete(args, :validate)
  56
  57   defp validate_expires_at(args) do
  58     if expires_late_enough?(args[:expires_at]) do
  59       args
  60     else
  61       {:error, :expiration_too_close}
  62     end
  63   end
  64
  65   defp find_activity(id) do
  66     with nil <- Activity.get_by_id_with_object(id) do
  67       {:error, :activity_not_found}
  68     end
  69   end
  70
  71   defp find_user(ap_id) do
  72     with nil <- Pleroma.User.get_by_ap_id(ap_id) do
  73       {:error, :user_not_found}
  74     end
  75   end
  76
  77   defp pinned_by_actor?(activity, user) do
  78     with true <- Activity.pinned_by_actor?(activity, user) do
  79       :pinned_by_actor
  80     end
  81   end
  82
  83   def get_expiration(id) do
  84     from(j in Oban.Job,
  85       where: j.state == "scheduled",
  86       where: j.queue == "activity_expiration",
  87       where: fragment("?->>'activity_id' = ?", j.args, ^id)
  88     )
  89     |> Pleroma.Repo.one()
  90   end
  91
  92   @spec expires_late_enough?(DateTime.t()) :: boolean()
  93   def expires_late_enough?(scheduled_at) do
  94     now = DateTime.utc_now()
  95     diff = DateTime.diff(scheduled_at, now, :millisecond)
  96     diff > :timer.hours(1)
  97   end
  98 end