git.squeep.com Git - akkoma/blob - lib/pleroma/workers/purge_expired_activity.ex

   1 defmodule Pleroma.Workers.PurgeExpiredActivity do
   2   @moduledoc """
   3   Worker which purges expired activity.
   4   """
   5
   6   use Oban.Worker, queue: :activity_expiration, max_attempts: 1
   7
   8   import Ecto.Query
   9
  10   alias Pleroma.Activity
  11
  12   def enqueue(args) do
  13     with true <- enabled?(),
  14          args when is_map(args) <- validate_expires_at(args) do
  15       {scheduled_at, args} = Map.pop(args, :expires_at)
  16
  17       args
  18       |> __MODULE__.new(scheduled_at: scheduled_at)
  19       |> Oban.insert()
  20     end
  21   end
  22
  23   @impl true
  24   def perform(%Oban.Job{args: %{"activity_id" => id}}) do
  25     with %Activity{} = activity <- find_activity(id),
  26          %Pleroma.User{} = user <- find_user(activity.object.data["actor"]),
  27          false <- pinned_by_actor?(activity, user) do
  28       Pleroma.Web.CommonAPI.delete(activity.id, user)
  29     else
  30       :pinned_by_actor ->
  31         # if activity is pinned, schedule deletion on next day
  32         enqueue(%{activity_id: id, expires_at: DateTime.add(DateTime.utc_now(), 24 * 3600)})
  33
  34         :ok
  35
  36       error ->
  37         error
  38     end
  39   end
  40
  41   defp enabled? do
  42     with false <- Pleroma.Config.get([__MODULE__, :enabled], false) do
  43       {:error, :expired_activities_disabled}
  44     end
  45   end
  46
  47   defp validate_expires_at(%{validate: false} = args), do: Map.delete(args, :validate)
  48
  49   defp validate_expires_at(args) do
  50     if expires_late_enough?(args[:expires_at]) do
  51       args
  52     else
  53       {:error, :expiration_too_close}
  54     end
  55   end
  56
  57   defp find_activity(id) do
  58     with nil <- Activity.get_by_id_with_object(id) do
  59       {:error, :activity_not_found}
  60     end
  61   end
  62
  63   defp find_user(ap_id) do
  64     with nil <- Pleroma.User.get_by_ap_id(ap_id) do
  65       {:error, :user_not_found}
  66     end
  67   end
  68
  69   defp pinned_by_actor?(activity, user) do
  70     with true <- Activity.pinned_by_actor?(activity, user) do
  71       :pinned_by_actor
  72     end
  73   end
  74
  75   def get_expiration(id) do
  76     from(j in Oban.Job,
  77       where: j.state == "scheduled",
  78       where: j.queue == "activity_expiration",
  79       where: fragment("?->>'activity_id' = ?", j.args, ^id)
  80     )
  81     |> Pleroma.Repo.one()
  82   end
  83
  84   @spec expires_late_enough?(DateTime.t()) :: boolean()
  85   def expires_late_enough?(scheduled_at) do
  86     now = DateTime.utc_now()
  87     diff = DateTime.diff(scheduled_at, now, :millisecond)
  88     diff > :timer.hours(1)
  89   end
  90 end