git.squeep.com Git - akkoma/blob - lib/pleroma/workers/purge_expired_activity.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Workers.PurgeExpiredActivity do
   6   @moduledoc """
   7   Worker which purges expired activity.
   8   """
   9
  10   use Oban.Worker, queue: :activity_expiration, max_attempts: 1
  11
  12   import Ecto.Query
  13
  14   alias Pleroma.Activity
  15
  16   def enqueue(args) do
  17     with true <- enabled?(),
  18          args when is_map(args) <- validate_expires_at(args) do
  19       {scheduled_at, args} = Map.pop(args, :expires_at)
  20
  21       args
  22       |> __MODULE__.new(scheduled_at: scheduled_at)
  23       |> Oban.insert()
  24     end
  25   end
  26
  27   @impl true
  28   def perform(%Oban.Job{args: %{"activity_id" => id}}) do
  29     with %Activity{} = activity <- find_activity(id),
  30          %Pleroma.User{} = user <- find_user(activity.object.data["actor"]),
  31          false <- pinned_by_actor?(activity, user) do
  32       Pleroma.Web.CommonAPI.delete(activity.id, user)
  33     else
  34       :pinned_by_actor ->
  35         # if activity is pinned, schedule deletion on next day
  36         enqueue(%{activity_id: id, expires_at: DateTime.add(DateTime.utc_now(), 24 * 3600)})
  37
  38         :ok
  39
  40       error ->
  41         error
  42     end
  43   end
  44
  45   defp enabled? do
  46     with false <- Pleroma.Config.get([__MODULE__, :enabled], false) do
  47       {:error, :expired_activities_disabled}
  48     end
  49   end
  50
  51   defp validate_expires_at(%{validate: false} = args), do: Map.delete(args, :validate)
  52
  53   defp validate_expires_at(args) do
  54     if expires_late_enough?(args[:expires_at]) do
  55       args
  56     else
  57       {:error, :expiration_too_close}
  58     end
  59   end
  60
  61   defp find_activity(id) do
  62     with nil <- Activity.get_by_id_with_object(id) do
  63       {:error, :activity_not_found}
  64     end
  65   end
  66
  67   defp find_user(ap_id) do
  68     with nil <- Pleroma.User.get_by_ap_id(ap_id) do
  69       {:error, :user_not_found}
  70     end
  71   end
  72
  73   defp pinned_by_actor?(activity, user) do
  74     with true <- Activity.pinned_by_actor?(activity, user) do
  75       :pinned_by_actor
  76     end
  77   end
  78
  79   def get_expiration(id) do
  80     from(j in Oban.Job,
  81       where: j.state == "scheduled",
  82       where: j.queue == "activity_expiration",
  83       where: fragment("?->>'activity_id' = ?", j.args, ^id)
  84     )
  85     |> Pleroma.Repo.one()
  86   end
  87
  88   @spec expires_late_enough?(DateTime.t()) :: boolean()
  89   def expires_late_enough?(scheduled_at) do
  90     now = DateTime.utc_now()
  91     diff = DateTime.diff(scheduled_at, now, :millisecond)
  92     diff > :timer.hours(1)
  93   end
  94 end