git.squeep.com Git - akkoma/blob - lib/pleroma/workers/purge_expired_activity.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Workers.PurgeExpiredActivity do
   6   @moduledoc """
   7   Worker which purges expired activity.
   8   """
   9
  10   use Oban.Worker, queue: :activity_expiration, max_attempts: 1
  11
  12   import Ecto.Query
  13
  14   alias Pleroma.Activity
  15
  16   @spec enqueue(map()) ::
  17           {:ok, Oban.Job.t()}
  18           | {:error, :expired_activities_disabled}
  19           | {:error, :expiration_too_close}
  20   def enqueue(args) do
  21     with true <- enabled?(),
  22          args when is_map(args) <- validate_expires_at(args) do
  23       {scheduled_at, args} = Map.pop(args, :expires_at)
  24
  25       args
  26       |> new(scheduled_at: scheduled_at)
  27       |> Oban.insert()
  28     end
  29   end
  30
  31   @impl true
  32   def perform(%Oban.Job{args: %{"activity_id" => id}}) do
  33     with %Activity{} = activity <- find_activity(id),
  34          %Pleroma.User{} = user <- find_user(activity.object.data["actor"]) do
  35       Pleroma.Web.CommonAPI.delete(activity.id, user)
  36     end
  37   end
  38
  39   defp enabled? do
  40     with false <- Pleroma.Config.get([__MODULE__, :enabled], false) do
  41       {:error, :expired_activities_disabled}
  42     end
  43   end
  44
  45   defp validate_expires_at(%{validate: false} = args), do: Map.delete(args, :validate)
  46
  47   defp validate_expires_at(args) do
  48     if expires_late_enough?(args[:expires_at]) do
  49       args
  50     else
  51       {:error, :expiration_too_close}
  52     end
  53   end
  54
  55   defp find_activity(id) do
  56     with nil <- Activity.get_by_id_with_object(id) do
  57       {:error, :activity_not_found}
  58     end
  59   end
  60
  61   defp find_user(ap_id) do
  62     with nil <- Pleroma.User.get_by_ap_id(ap_id) do
  63       {:error, :user_not_found}
  64     end
  65   end
  66
  67   def get_expiration(id) do
  68     from(j in Oban.Job,
  69       where: j.state == "scheduled",
  70       where: j.queue == "activity_expiration",
  71       where: fragment("?->>'activity_id' = ?", j.args, ^id)
  72     )
  73     |> Pleroma.Repo.one()
  74   end
  75
  76   @spec expires_late_enough?(DateTime.t()) :: boolean()
  77   def expires_late_enough?(scheduled_at) do
  78     now = DateTime.utc_now()
  79     diff = DateTime.diff(scheduled_at, now, :millisecond)
  80     min_lifetime = Pleroma.Config.get([__MODULE__, :min_lifetime], 600)
  81     diff > :timer.seconds(min_lifetime)
  82   end
  83 end