git.squeep.com Git - akkoma/blob - lib/pleroma/web/web_finger.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.WebFinger do
   6   alias Pleroma.HTTP
   7   alias Pleroma.User
   8   alias Pleroma.Web
   9   alias Pleroma.Web.Federator.Publisher
  10   alias Pleroma.Web.XML
  11   alias Pleroma.XmlBuilder
  12   require Jason
  13   require Logger
  14
  15   def host_meta do
  16     base_url = Web.base_url()
  17
  18     {
  19       :XRD,
  20       %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
  21       {
  22         :Link,
  23         %{
  24           rel: "lrdd",
  25           type: "application/xrd+xml",
  26           template: "#{base_url}/.well-known/webfinger?resource={uri}"
  27         }
  28       }
  29     }
  30     |> XmlBuilder.to_doc()
  31   end
  32
  33   def webfinger(resource, fmt) when fmt in ["XML", "JSON"] do
  34     host = Pleroma.Web.Endpoint.host()
  35     regex = ~r/(acct:)?(?<username>[a-z0-9A-Z_\.-]+)@#{host}/
  36
  37     with %{"username" => username} <- Regex.named_captures(regex, resource),
  38          %User{} = user <- User.get_cached_by_nickname(username) do
  39       {:ok, represent_user(user, fmt)}
  40     else
  41       _e ->
  42         with %User{} = user <- User.get_cached_by_ap_id(resource) do
  43           {:ok, represent_user(user, fmt)}
  44         else
  45           _e ->
  46             {:error, "Couldn't find user"}
  47         end
  48     end
  49   end
  50
  51   defp gather_links(%User{} = user) do
  52     [
  53       %{
  54         "rel" => "http://webfinger.net/rel/profile-page",
  55         "type" => "text/html",
  56         "href" => user.ap_id
  57       }
  58     ] ++ Publisher.gather_webfinger_links(user)
  59   end
  60
  61   def represent_user(user, "JSON") do
  62     {:ok, user} = User.ensure_keys_present(user)
  63
  64     %{
  65       "subject" => "acct:#{user.nickname}@#{Pleroma.Web.Endpoint.host()}",
  66       "aliases" => [user.ap_id],
  67       "links" => gather_links(user)
  68     }
  69   end
  70
  71   def represent_user(user, "XML") do
  72     {:ok, user} = User.ensure_keys_present(user)
  73
  74     links =
  75       gather_links(user)
  76       |> Enum.map(fn link -> {:Link, link} end)
  77
  78     {
  79       :XRD,
  80       %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
  81       [
  82         {:Subject, "acct:#{user.nickname}@#{Pleroma.Web.Endpoint.host()}"},
  83         {:Alias, user.ap_id}
  84       ] ++ links
  85     }
  86     |> XmlBuilder.to_doc()
  87   end
  88
  89   defp webfinger_from_xml(doc) do
  90     subject = XML.string_from_xpath("//Subject", doc)
  91
  92     subscribe_address =
  93       ~s{//Link[@rel="http://ostatus.org/schema/1.0/subscribe"]/@template}
  94       |> XML.string_from_xpath(doc)
  95
  96     ap_id =
  97       ~s{//Link[@rel="self" and @type="application/activity+json"]/@href}
  98       |> XML.string_from_xpath(doc)
  99
 100     data = %{
 101       "subject" => subject,
 102       "subscribe_address" => subscribe_address,
 103       "ap_id" => ap_id
 104     }
 105
 106     {:ok, data}
 107   end
 108
 109   defp webfinger_from_json(doc) do
 110     data =
 111       Enum.reduce(doc["links"], %{"subject" => doc["subject"]}, fn link, data ->
 112         case {link["type"], link["rel"]} do
 113           {"application/activity+json", "self"} ->
 114             Map.put(data, "ap_id", link["href"])
 115
 116           {"application/ld+json; profile=\"https://www.w3.org/ns/activitystreams\"", "self"} ->
 117             Map.put(data, "ap_id", link["href"])
 118
 119           _ ->
 120             Logger.debug("Unhandled type: #{inspect(link["type"])}")
 121             data
 122         end
 123       end)
 124
 125     {:ok, data}
 126   end
 127
 128   def get_template_from_xml(body) do
 129     xpath = "//Link[@rel='lrdd']/@template"
 130
 131     with doc when doc != :error <- XML.parse_document(body),
 132          template when template != nil <- XML.string_from_xpath(xpath, doc) do
 133       {:ok, template}
 134     end
 135   end
 136
 137   def find_lrdd_template(domain) do
 138     with {:ok, %{status: status, body: body}} when status in 200..299 <-
 139            HTTP.get("http://#{domain}/.well-known/host-meta") do
 140       get_template_from_xml(body)
 141     else
 142       _ ->
 143         with {:ok, %{body: body, status: status}} when status in 200..299 <-
 144                HTTP.get("https://#{domain}/.well-known/host-meta") do
 145           get_template_from_xml(body)
 146         else
 147           e -> {:error, "Can't find LRDD template: #{inspect(e)}"}
 148         end
 149     end
 150   end
 151
 152   defp get_address_from_domain(domain, encoded_account) when is_binary(domain) do
 153     case find_lrdd_template(domain) do
 154       {:ok, template} ->
 155         String.replace(template, "{uri}", encoded_account)
 156
 157       _ ->
 158         "https://#{domain}/.well-known/webfinger?resource=#{encoded_account}"
 159     end
 160   end
 161
 162   defp get_address_from_domain(_, _), do: nil
 163
 164   @spec finger(String.t()) :: {:ok, map()} | {:error, any()}
 165   def finger(account) do
 166     account = String.trim_leading(account, "@")
 167
 168     domain =
 169       with [_name, domain] <- String.split(account, "@") do
 170         domain
 171       else
 172         _e ->
 173           URI.parse(account).host
 174       end
 175
 176     encoded_account = URI.encode("acct:#{account}")
 177
 178     with address when is_binary(address) <- get_address_from_domain(domain, encoded_account),
 179          response <-
 180            HTTP.get(
 181              address,
 182              [{"accept", "application/xrd+xml,application/jrd+json"}]
 183            ),
 184          {:ok, %{status: status, body: body}} when status in 200..299 <- response do
 185       doc = XML.parse_document(body)
 186
 187       if doc != :error do
 188         webfinger_from_xml(doc)
 189       else
 190         with {:ok, doc} <- Jason.decode(body) do
 191           webfinger_from_json(doc)
 192         end
 193       end
 194     else
 195       e ->
 196         Logger.debug(fn -> "Couldn't finger #{account}" end)
 197         Logger.debug(fn -> inspect(e) end)
 198         {:error, e}
 199     end
 200   end
 201 end