git.squeep.com Git - akkoma/blob - lib/pleroma/web/web_finger.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.WebFinger do
   6   alias Pleroma.HTTP
   7   alias Pleroma.User
   8   alias Pleroma.Web
   9   alias Pleroma.Web.Federator.Publisher
  10   alias Pleroma.Web.XML
  11   alias Pleroma.XmlBuilder
  12   require Jason
  13   require Logger
  14
  15   def host_meta do
  16     base_url = Web.base_url()
  17
  18     {
  19       :XRD,
  20       %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
  21       {
  22         :Link,
  23         %{
  24           rel: "lrdd",
  25           type: "application/xrd+xml",
  26           template: "#{base_url}/.well-known/webfinger?resource={uri}"
  27         }
  28       }
  29     }
  30     |> XmlBuilder.to_doc()
  31   end
  32
  33   def webfinger(resource, fmt) when fmt in ["XML", "JSON"] do
  34     host = Pleroma.Web.Endpoint.host()
  35     regex = ~r/(acct:)?(?<username>[a-z0-9A-Z_\.-]+)@#{host}/
  36
  37     with %{"username" => username} <- Regex.named_captures(regex, resource),
  38          %User{} = user <- User.get_cached_by_nickname(username) do
  39       {:ok, represent_user(user, fmt)}
  40     else
  41       _e ->
  42         with %User{} = user <- User.get_cached_by_ap_id(resource) do
  43           {:ok, represent_user(user, fmt)}
  44         else
  45           _e ->
  46             {:error, "Couldn't find user"}
  47         end
  48     end
  49   end
  50
  51   defp gather_links(%User{} = user) do
  52     [
  53       %{
  54         "rel" => "http://webfinger.net/rel/profile-page",
  55         "type" => "text/html",
  56         "href" => user.ap_id
  57       }
  58     ] ++ Publisher.gather_webfinger_links(user)
  59   end
  60
  61   defp gather_aliases(%User{} = user) do
  62     [user.ap_id | user.also_known_as]
  63   end
  64
  65   def represent_user(user, "JSON") do
  66     {:ok, user} = User.ensure_keys_present(user)
  67
  68     %{
  69       "subject" => "acct:#{user.nickname}@#{Pleroma.Web.Endpoint.host()}",
  70       "aliases" => gather_aliases(user),
  71       "links" => gather_links(user)
  72     }
  73   end
  74
  75   def represent_user(user, "XML") do
  76     {:ok, user} = User.ensure_keys_present(user)
  77
  78     aliases =
  79       user
  80       |> gather_aliases()
  81       |> Enum.map(&{:Alias, &1})
  82
  83     links =
  84       gather_links(user)
  85       |> Enum.map(fn link -> {:Link, link} end)
  86
  87     {
  88       :XRD,
  89       %{xmlns: "http://docs.oasis-open.org/ns/xri/xrd-1.0"},
  90       [
  91         {:Subject, "acct:#{user.nickname}@#{Pleroma.Web.Endpoint.host()}"}
  92       ] ++ aliases ++ links
  93     }
  94     |> XmlBuilder.to_doc()
  95   end
  96
  97   defp webfinger_from_xml(doc) do
  98     subject = XML.string_from_xpath("//Subject", doc)
  99
 100     subscribe_address =
 101       ~s{//Link[@rel="http://ostatus.org/schema/1.0/subscribe"]/@template}
 102       |> XML.string_from_xpath(doc)
 103
 104     ap_id =
 105       ~s{//Link[@rel="self" and @type="application/activity+json"]/@href}
 106       |> XML.string_from_xpath(doc)
 107
 108     data = %{
 109       "subject" => subject,
 110       "subscribe_address" => subscribe_address,
 111       "ap_id" => ap_id
 112     }
 113
 114     {:ok, data}
 115   end
 116
 117   defp webfinger_from_json(doc) do
 118     data =
 119       Enum.reduce(doc["links"], %{"subject" => doc["subject"]}, fn link, data ->
 120         case {link["type"], link["rel"]} do
 121           {"application/activity+json", "self"} ->
 122             Map.put(data, "ap_id", link["href"])
 123
 124           {"application/ld+json; profile=\"https://www.w3.org/ns/activitystreams\"", "self"} ->
 125             Map.put(data, "ap_id", link["href"])
 126
 127           {nil, "http://ostatus.org/schema/1.0/subscribe"} ->
 128             Map.put(data, "subscribe_address", link["template"])
 129
 130           _ ->
 131             Logger.debug("Unhandled type: #{inspect(link["type"])}")
 132             data
 133         end
 134       end)
 135
 136     {:ok, data}
 137   end
 138
 139   def get_template_from_xml(body) do
 140     xpath = "//Link[@rel='lrdd']/@template"
 141
 142     with doc when doc != :error <- XML.parse_document(body),
 143          template when template != nil <- XML.string_from_xpath(xpath, doc) do
 144       {:ok, template}
 145     end
 146   end
 147
 148   def find_lrdd_template(domain) do
 149     with {:ok, %{status: status, body: body}} when status in 200..299 <-
 150            HTTP.get("http://#{domain}/.well-known/host-meta") do
 151       get_template_from_xml(body)
 152     else
 153       _ ->
 154         with {:ok, %{body: body, status: status}} when status in 200..299 <-
 155                HTTP.get("https://#{domain}/.well-known/host-meta") do
 156           get_template_from_xml(body)
 157         else
 158           e -> {:error, "Can't find LRDD template: #{inspect(e)}"}
 159         end
 160     end
 161   end
 162
 163   defp get_address_from_domain(domain, encoded_account) when is_binary(domain) do
 164     case find_lrdd_template(domain) do
 165       {:ok, template} ->
 166         String.replace(template, "{uri}", encoded_account)
 167
 168       _ ->
 169         "https://#{domain}/.well-known/webfinger?resource=#{encoded_account}"
 170     end
 171   end
 172
 173   defp get_address_from_domain(_, _), do: nil
 174
 175   @spec finger(String.t()) :: {:ok, map()} | {:error, any()}
 176   def finger(account) do
 177     account = String.trim_leading(account, "@")
 178
 179     domain =
 180       with [_name, domain] <- String.split(account, "@") do
 181         domain
 182       else
 183         _e ->
 184           URI.parse(account).host
 185       end
 186
 187     encoded_account = URI.encode("acct:#{account}")
 188
 189     with address when is_binary(address) <- get_address_from_domain(domain, encoded_account),
 190          response <-
 191            HTTP.get(
 192              address,
 193              [{"accept", "application/xrd+xml,application/jrd+json"}]
 194            ),
 195          {:ok, %{status: status, body: body}} when status in 200..299 <- response do
 196       doc = XML.parse_document(body)
 197
 198       if doc != :error do
 199         webfinger_from_xml(doc)
 200       else
 201         with {:ok, doc} <- Jason.decode(body) do
 202           webfinger_from_json(doc)
 203         end
 204       end
 205     else
 206       e ->
 207         Logger.debug(fn -> "Couldn't finger #{account}" end)
 208         Logger.debug(fn -> inspect(e) end)
 209         {:error, e}
 210     end
 211   end
 212 end