git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.Controller do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper, only: [json_response: 3]
   9
  10   alias Pleroma.Web.TwitterAPI.{TwitterAPI, UserView, ActivityView, NotificationView}
  11   alias Pleroma.Web.CommonAPI
  12   alias Pleroma.{Repo, Activity, Object, User, Notification}
  13   alias Pleroma.Web.ActivityPub.ActivityPub
  14   alias Pleroma.Web.ActivityPub.Utils
  15   alias Ecto.Changeset
  16
  17   require Logger
  18
  19   plug(:only_if_public_instance when action in [:public_timeline, :public_and_external_timeline])
  20   action_fallback(:errors)
  21
  22   def verify_credentials(%{assigns: %{user: user}} = conn, _params) do
  23     token = Phoenix.Token.sign(conn, "user socket", user.id)
  24
  25     conn
  26     |> put_view(UserView)
  27     |> render("show.json", %{user: user, token: token})
  28   end
  29
  30   def status_update(%{assigns: %{user: user}} = conn, %{"status" => _} = status_data) do
  31     with media_ids <- extract_media_ids(status_data),
  32          {:ok, activity} <-
  33            TwitterAPI.create_status(user, Map.put(status_data, "media_ids", media_ids)) do
  34       conn
  35       |> json(ActivityView.render("activity.json", activity: activity, for: user))
  36     else
  37       _ -> empty_status_reply(conn)
  38     end
  39   end
  40
  41   def status_update(conn, _status_data) do
  42     empty_status_reply(conn)
  43   end
  44
  45   defp empty_status_reply(conn) do
  46     bad_request_reply(conn, "Client must provide a 'status' parameter with a value.")
  47   end
  48
  49   defp extract_media_ids(status_data) do
  50     with media_ids when not is_nil(media_ids) <- status_data["media_ids"],
  51          split_ids <- String.split(media_ids, ","),
  52          clean_ids <- Enum.reject(split_ids, fn id -> String.length(id) == 0 end) do
  53       clean_ids
  54     else
  55       _e -> []
  56     end
  57   end
  58
  59   def public_and_external_timeline(%{assigns: %{user: user}} = conn, params) do
  60     params =
  61       params
  62       |> Map.put("type", ["Create", "Announce"])
  63       |> Map.put("blocking_user", user)
  64
  65     activities = ActivityPub.fetch_public_activities(params)
  66
  67     conn
  68     |> put_view(ActivityView)
  69     |> render("index.json", %{activities: activities, for: user})
  70   end
  71
  72   def public_timeline(%{assigns: %{user: user}} = conn, params) do
  73     params =
  74       params
  75       |> Map.put("type", ["Create", "Announce"])
  76       |> Map.put("local_only", true)
  77       |> Map.put("blocking_user", user)
  78
  79     activities = ActivityPub.fetch_public_activities(params)
  80
  81     conn
  82     |> put_view(ActivityView)
  83     |> render("index.json", %{activities: activities, for: user})
  84   end
  85
  86   def friends_timeline(%{assigns: %{user: user}} = conn, params) do
  87     params =
  88       params
  89       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
  90       |> Map.put("blocking_user", user)
  91       |> Map.put("user", user)
  92
  93     activities =
  94       ActivityPub.fetch_activities([user.ap_id | user.following], params)
  95       |> ActivityPub.contain_timeline(user)
  96
  97     conn
  98     |> put_view(ActivityView)
  99     |> render("index.json", %{activities: activities, for: user})
 100   end
 101
 102   def show_user(conn, params) do
 103     for_user = conn.assigns.user
 104
 105     with {:ok, shown} <- TwitterAPI.get_user(params),
 106          true <-
 107            User.auth_active?(shown) ||
 108              (for_user && (for_user.id == shown.id || User.superuser?(for_user))) do
 109       params =
 110         if for_user do
 111           %{user: shown, for: for_user}
 112         else
 113           %{user: shown}
 114         end
 115
 116       conn
 117       |> put_view(UserView)
 118       |> render("show.json", params)
 119     else
 120       {:error, msg} ->
 121         bad_request_reply(conn, msg)
 122
 123       false ->
 124         conn
 125         |> put_status(404)
 126         |> json(%{error: "Unconfirmed user"})
 127     end
 128   end
 129
 130   def user_timeline(%{assigns: %{user: user}} = conn, params) do
 131     case TwitterAPI.get_user(user, params) do
 132       {:ok, target_user} ->
 133         # Twitter and ActivityPub use a different name and sense for this parameter.
 134         {include_rts, params} = Map.pop(params, "include_rts")
 135
 136         params =
 137           case include_rts do
 138             x when x == "false" or x == "0" -> Map.put(params, "exclude_reblogs", "true")
 139             _ -> params
 140           end
 141
 142         activities = ActivityPub.fetch_user_activities(target_user, user, params)
 143
 144         conn
 145         |> put_view(ActivityView)
 146         |> render("index.json", %{activities: activities, for: user})
 147
 148       {:error, msg} ->
 149         bad_request_reply(conn, msg)
 150     end
 151   end
 152
 153   def mentions_timeline(%{assigns: %{user: user}} = conn, params) do
 154     params =
 155       params
 156       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
 157       |> Map.put("blocking_user", user)
 158
 159     activities = ActivityPub.fetch_activities([user.ap_id], params)
 160
 161     conn
 162     |> put_view(ActivityView)
 163     |> render("index.json", %{activities: activities, for: user})
 164   end
 165
 166   def dm_timeline(%{assigns: %{user: user}} = conn, params) do
 167     query =
 168       ActivityPub.fetch_activities_query(
 169         [user.ap_id],
 170         Map.merge(params, %{"type" => "Create", "user" => user, visibility: "direct"})
 171       )
 172
 173     activities = Repo.all(query)
 174
 175     conn
 176     |> put_view(ActivityView)
 177     |> render("index.json", %{activities: activities, for: user})
 178   end
 179
 180   def notifications(%{assigns: %{user: user}} = conn, params) do
 181     notifications = Notification.for_user(user, params)
 182
 183     conn
 184     |> put_view(NotificationView)
 185     |> render("notification.json", %{notifications: notifications, for: user})
 186   end
 187
 188   def notifications_read(%{assigns: %{user: user}} = conn, %{"latest_id" => latest_id} = params) do
 189     Notification.set_read_up_to(user, latest_id)
 190
 191     notifications = Notification.for_user(user, params)
 192
 193     conn
 194     |> put_view(NotificationView)
 195     |> render("notification.json", %{notifications: notifications, for: user})
 196   end
 197
 198   def notifications_read(%{assigns: %{user: _user}} = conn, _) do
 199     bad_request_reply(conn, "You need to specify latest_id")
 200   end
 201
 202   def follow(%{assigns: %{user: user}} = conn, params) do
 203     case TwitterAPI.follow(user, params) do
 204       {:ok, user, followed, _activity} ->
 205         conn
 206         |> put_view(UserView)
 207         |> render("show.json", %{user: followed, for: user})
 208
 209       {:error, msg} ->
 210         forbidden_json_reply(conn, msg)
 211     end
 212   end
 213
 214   def block(%{assigns: %{user: user}} = conn, params) do
 215     case TwitterAPI.block(user, params) do
 216       {:ok, user, blocked} ->
 217         conn
 218         |> put_view(UserView)
 219         |> render("show.json", %{user: blocked, for: user})
 220
 221       {:error, msg} ->
 222         forbidden_json_reply(conn, msg)
 223     end
 224   end
 225
 226   def unblock(%{assigns: %{user: user}} = conn, params) do
 227     case TwitterAPI.unblock(user, params) do
 228       {:ok, user, blocked} ->
 229         conn
 230         |> put_view(UserView)
 231         |> render("show.json", %{user: blocked, for: user})
 232
 233       {:error, msg} ->
 234         forbidden_json_reply(conn, msg)
 235     end
 236   end
 237
 238   def delete_post(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 239     with {:ok, activity} <- TwitterAPI.delete(user, id) do
 240       conn
 241       |> put_view(ActivityView)
 242       |> render("activity.json", %{activity: activity, for: user})
 243     end
 244   end
 245
 246   def unfollow(%{assigns: %{user: user}} = conn, params) do
 247     case TwitterAPI.unfollow(user, params) do
 248       {:ok, user, unfollowed} ->
 249         conn
 250         |> put_view(UserView)
 251         |> render("show.json", %{user: unfollowed, for: user})
 252
 253       {:error, msg} ->
 254         forbidden_json_reply(conn, msg)
 255     end
 256   end
 257
 258   def fetch_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 259     with %Activity{} = activity <- Repo.get(Activity, id),
 260          true <- ActivityPub.visible_for_user?(activity, user) do
 261       conn
 262       |> put_view(ActivityView)
 263       |> render("activity.json", %{activity: activity, for: user})
 264     end
 265   end
 266
 267   def fetch_conversation(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 268     id = String.to_integer(id)
 269
 270     with context when is_binary(context) <- TwitterAPI.conversation_id_to_context(id),
 271          activities <-
 272            ActivityPub.fetch_activities_for_context(context, %{
 273              "blocking_user" => user,
 274              "user" => user
 275            }) do
 276       conn
 277       |> put_view(ActivityView)
 278       |> render("index.json", %{activities: activities, for: user})
 279     end
 280   end
 281
 282   @doc """
 283   Updates metadata of uploaded media object.
 284   Derived from [Twitter API endpoint](https://developer.twitter.com/en/docs/media/upload-media/api-reference/post-media-metadata-create).
 285   """
 286   def update_media(%{assigns: %{user: user}} = conn, %{"media_id" => id} = data) do
 287     object = Repo.get(Object, id)
 288     description = get_in(data, ["alt_text", "text"]) || data["name"] || data["description"]
 289
 290     {conn, status, response_body} =
 291       cond do
 292         !object ->
 293           {halt(conn), :not_found, ""}
 294
 295         !Object.authorize_mutation(object, user) ->
 296           {halt(conn), :forbidden, "You can only update your own uploads."}
 297
 298         !is_binary(description) ->
 299           {conn, :not_modified, ""}
 300
 301         true ->
 302           new_data = Map.put(object.data, "name", description)
 303
 304           {:ok, _} =
 305             object
 306             |> Object.change(%{data: new_data})
 307             |> Repo.update()
 308
 309           {conn, :no_content, ""}
 310       end
 311
 312     conn
 313     |> put_status(status)
 314     |> json(response_body)
 315   end
 316
 317   def upload(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 318     response = TwitterAPI.upload(media, user)
 319
 320     conn
 321     |> put_resp_content_type("application/atom+xml")
 322     |> send_resp(200, response)
 323   end
 324
 325   def upload_json(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 326     response = TwitterAPI.upload(media, user, "json")
 327
 328     conn
 329     |> json_reply(200, response)
 330   end
 331
 332   def get_by_id_or_ap_id(id) do
 333     activity = Repo.get(Activity, id) || Activity.get_create_by_object_ap_id(id)
 334
 335     if activity.data["type"] == "Create" do
 336       activity
 337     else
 338       Activity.get_create_by_object_ap_id(activity.data["object"])
 339     end
 340   end
 341
 342   def favorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 343     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 344          {:ok, activity} <- TwitterAPI.fav(user, id) do
 345       conn
 346       |> put_view(ActivityView)
 347       |> render("activity.json", %{activity: activity, for: user})
 348     end
 349   end
 350
 351   def unfavorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 352     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 353          {:ok, activity} <- TwitterAPI.unfav(user, id) do
 354       conn
 355       |> put_view(ActivityView)
 356       |> render("activity.json", %{activity: activity, for: user})
 357     end
 358   end
 359
 360   def retweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 361     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 362          {:ok, activity} <- TwitterAPI.repeat(user, id) do
 363       conn
 364       |> put_view(ActivityView)
 365       |> render("activity.json", %{activity: activity, for: user})
 366     end
 367   end
 368
 369   def unretweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 370     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 371          {:ok, activity} <- TwitterAPI.unrepeat(user, id) do
 372       conn
 373       |> put_view(ActivityView)
 374       |> render("activity.json", %{activity: activity, for: user})
 375     end
 376   end
 377
 378   def pin(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 379     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 380          {:ok, activity} <- TwitterAPI.pin(user, id) do
 381       conn
 382       |> put_view(ActivityView)
 383       |> render("activity.json", %{activity: activity, for: user})
 384     else
 385       {:error, message} -> bad_request_reply(conn, message)
 386       err -> err
 387     end
 388   end
 389
 390   def unpin(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 391     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 392          {:ok, activity} <- TwitterAPI.unpin(user, id) do
 393       conn
 394       |> put_view(ActivityView)
 395       |> render("activity.json", %{activity: activity, for: user})
 396     else
 397       {:error, message} -> bad_request_reply(conn, message)
 398       err -> err
 399     end
 400   end
 401
 402   def register(conn, params) do
 403     with {:ok, user} <- TwitterAPI.register_user(params) do
 404       conn
 405       |> put_view(UserView)
 406       |> render("show.json", %{user: user})
 407     else
 408       {:error, errors} ->
 409         conn
 410         |> json_reply(400, Jason.encode!(errors))
 411     end
 412   end
 413
 414   def password_reset(conn, params) do
 415     nickname_or_email = params["email"] || params["nickname"]
 416
 417     with {:ok, _} <- TwitterAPI.password_reset(nickname_or_email) do
 418       json_response(conn, :no_content, "")
 419     end
 420   end
 421
 422   def confirm_email(conn, %{"user_id" => uid, "token" => token}) do
 423     with %User{} = user <- Repo.get(User, uid),
 424          true <- user.local,
 425          true <- user.info.confirmation_pending,
 426          true <- user.info.confirmation_token == token,
 427          info_change <- User.Info.confirmation_changeset(user.info, :confirmed),
 428          changeset <- Changeset.change(user) |> Changeset.put_embed(:info, info_change),
 429          {:ok, _} <- User.update_and_set_cache(changeset) do
 430       conn
 431       |> redirect(to: "/")
 432     end
 433   end
 434
 435   def resend_confirmation_email(conn, params) do
 436     nickname_or_email = params["email"] || params["nickname"]
 437
 438     with %User{} = user <- User.get_by_nickname_or_email(nickname_or_email),
 439          {:ok, _} <- User.try_send_confirmation_email(user) do
 440       conn
 441       |> json_response(:no_content, "")
 442     end
 443   end
 444
 445   def update_avatar(%{assigns: %{user: user}} = conn, params) do
 446     {:ok, object} = ActivityPub.upload(params, type: :avatar)
 447     change = Changeset.change(user, %{avatar: object.data})
 448     {:ok, user} = User.update_and_set_cache(change)
 449     CommonAPI.update(user)
 450
 451     conn
 452     |> put_view(UserView)
 453     |> render("show.json", %{user: user, for: user})
 454   end
 455
 456   def update_banner(%{assigns: %{user: user}} = conn, params) do
 457     with {:ok, object} <- ActivityPub.upload(%{"img" => params["banner"]}, type: :banner),
 458          new_info <- %{"banner" => object.data},
 459          info_cng <- User.Info.profile_update(user.info, new_info),
 460          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 461          {:ok, user} <- User.update_and_set_cache(changeset) do
 462       CommonAPI.update(user)
 463       %{"url" => [%{"href" => href} | _]} = object.data
 464       response = %{url: href} |> Jason.encode!()
 465
 466       conn
 467       |> json_reply(200, response)
 468     end
 469   end
 470
 471   def update_background(%{assigns: %{user: user}} = conn, params) do
 472     with {:ok, object} <- ActivityPub.upload(params, type: :background),
 473          new_info <- %{"background" => object.data},
 474          info_cng <- User.Info.profile_update(user.info, new_info),
 475          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 476          {:ok, _user} <- User.update_and_set_cache(changeset) do
 477       %{"url" => [%{"href" => href} | _]} = object.data
 478       response = %{url: href} |> Jason.encode!()
 479
 480       conn
 481       |> json_reply(200, response)
 482     end
 483   end
 484
 485   def external_profile(%{assigns: %{user: current_user}} = conn, %{"profileurl" => uri}) do
 486     with {:ok, user_map} <- TwitterAPI.get_external_profile(current_user, uri),
 487          response <- Jason.encode!(user_map) do
 488       conn
 489       |> json_reply(200, response)
 490     else
 491       _e ->
 492         conn
 493         |> put_status(404)
 494         |> json(%{error: "Can't find user"})
 495     end
 496   end
 497
 498   def followers(%{assigns: %{user: for_user}} = conn, params) do
 499     {:ok, page} = Ecto.Type.cast(:integer, params["page"] || 1)
 500
 501     with {:ok, user} <- TwitterAPI.get_user(for_user, params),
 502          {:ok, followers} <- User.get_followers(user, page) do
 503       followers =
 504         cond do
 505           for_user && user.id == for_user.id -> followers
 506           user.info.hide_network -> []
 507           true -> followers
 508         end
 509
 510       conn
 511       |> put_view(UserView)
 512       |> render("index.json", %{users: followers, for: conn.assigns[:user]})
 513     else
 514       _e -> bad_request_reply(conn, "Can't get followers")
 515     end
 516   end
 517
 518   def friends(%{assigns: %{user: for_user}} = conn, params) do
 519     {:ok, page} = Ecto.Type.cast(:integer, params["page"] || 1)
 520
 521     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 522          {:ok, friends} <- User.get_friends(user, page) do
 523       friends =
 524         cond do
 525           for_user && user.id == for_user.id -> friends
 526           user.info.hide_network -> []
 527           true -> friends
 528         end
 529
 530       conn
 531       |> put_view(UserView)
 532       |> render("index.json", %{users: friends, for: conn.assigns[:user]})
 533     else
 534       _e -> bad_request_reply(conn, "Can't get friends")
 535     end
 536   end
 537
 538   def blocks(%{assigns: %{user: user}} = conn, _params) do
 539     with blocked_users <- User.blocked_users(user) do
 540       conn
 541       |> put_view(UserView)
 542       |> render("index.json", %{users: blocked_users, for: user})
 543     end
 544   end
 545
 546   def friend_requests(conn, params) do
 547     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 548          {:ok, friend_requests} <- User.get_follow_requests(user) do
 549       conn
 550       |> put_view(UserView)
 551       |> render("index.json", %{users: friend_requests, for: conn.assigns[:user]})
 552     else
 553       _e -> bad_request_reply(conn, "Can't get friend requests")
 554     end
 555   end
 556
 557   def approve_friend_request(conn, %{"user_id" => uid} = _params) do
 558     with followed <- conn.assigns[:user],
 559          uid when is_number(uid) <- String.to_integer(uid),
 560          %User{} = follower <- Repo.get(User, uid),
 561          {:ok, follower} <- User.maybe_follow(follower, followed),
 562          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 563          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 564          {:ok, _activity} <-
 565            ActivityPub.accept(%{
 566              to: [follower.ap_id],
 567              actor: followed.ap_id,
 568              object: follow_activity.data["id"],
 569              type: "Accept"
 570            }) do
 571       conn
 572       |> put_view(UserView)
 573       |> render("show.json", %{user: follower, for: followed})
 574     else
 575       e -> bad_request_reply(conn, "Can't approve user: #{inspect(e)}")
 576     end
 577   end
 578
 579   def deny_friend_request(conn, %{"user_id" => uid} = _params) do
 580     with followed <- conn.assigns[:user],
 581          uid when is_number(uid) <- String.to_integer(uid),
 582          %User{} = follower <- Repo.get(User, uid),
 583          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 584          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 585          {:ok, _activity} <-
 586            ActivityPub.reject(%{
 587              to: [follower.ap_id],
 588              actor: followed.ap_id,
 589              object: follow_activity.data["id"],
 590              type: "Reject"
 591            }) do
 592       conn
 593       |> put_view(UserView)
 594       |> render("show.json", %{user: follower, for: followed})
 595     else
 596       e -> bad_request_reply(conn, "Can't deny user: #{inspect(e)}")
 597     end
 598   end
 599
 600   def friends_ids(%{assigns: %{user: user}} = conn, _params) do
 601     with {:ok, friends} <- User.get_friends(user) do
 602       ids =
 603         friends
 604         |> Enum.map(fn x -> x.id end)
 605         |> Jason.encode!()
 606
 607       json(conn, ids)
 608     else
 609       _e -> bad_request_reply(conn, "Can't get friends")
 610     end
 611   end
 612
 613   def empty_array(conn, _params) do
 614     json(conn, Jason.encode!([]))
 615   end
 616
 617   def raw_empty_array(conn, _params) do
 618     json(conn, [])
 619   end
 620
 621   defp build_info_cng(user, params) do
 622     info_params =
 623       ["no_rich_text", "locked", "hide_network"]
 624       |> Enum.reduce(%{}, fn key, res ->
 625         if value = params[key] do
 626           Map.put(res, key, value == "true")
 627         else
 628           res
 629         end
 630       end)
 631
 632     info_params =
 633       if value = params["default_scope"] do
 634         Map.put(info_params, "default_scope", value)
 635       else
 636         info_params
 637       end
 638
 639     User.Info.profile_update(user.info, info_params)
 640   end
 641
 642   defp parse_profile_bio(user, params) do
 643     if bio = params["description"] do
 644       Map.put(params, "bio", User.parse_bio(bio, user))
 645     else
 646       params
 647     end
 648   end
 649
 650   def update_profile(%{assigns: %{user: user}} = conn, params) do
 651     params = parse_profile_bio(user, params)
 652     info_cng = build_info_cng(user, params)
 653
 654     with changeset <- User.update_changeset(user, params),
 655          changeset <- Ecto.Changeset.put_embed(changeset, :info, info_cng),
 656          {:ok, user} <- User.update_and_set_cache(changeset) do
 657       CommonAPI.update(user)
 658
 659       conn
 660       |> put_view(UserView)
 661       |> render("user.json", %{user: user, for: user})
 662     else
 663       error ->
 664         Logger.debug("Can't update user: #{inspect(error)}")
 665         bad_request_reply(conn, "Can't update user")
 666     end
 667   end
 668
 669   def search(%{assigns: %{user: user}} = conn, %{"q" => _query} = params) do
 670     activities = TwitterAPI.search(user, params)
 671
 672     conn
 673     |> put_view(ActivityView)
 674     |> render("index.json", %{activities: activities, for: user})
 675   end
 676
 677   def search_user(%{assigns: %{user: user}} = conn, %{"query" => query}) do
 678     users = User.search(query, true, user)
 679
 680     conn
 681     |> put_view(UserView)
 682     |> render("index.json", %{users: users, for: user})
 683   end
 684
 685   defp bad_request_reply(conn, error_message) do
 686     json = error_json(conn, error_message)
 687     json_reply(conn, 400, json)
 688   end
 689
 690   defp json_reply(conn, status, json) do
 691     conn
 692     |> put_resp_content_type("application/json")
 693     |> send_resp(status, json)
 694   end
 695
 696   defp forbidden_json_reply(conn, error_message) do
 697     json = error_json(conn, error_message)
 698     json_reply(conn, 403, json)
 699   end
 700
 701   def only_if_public_instance(%{assigns: %{user: %User{}}} = conn, _), do: conn
 702
 703   def only_if_public_instance(conn, _) do
 704     if Keyword.get(Application.get_env(:pleroma, :instance), :public) do
 705       conn
 706     else
 707       conn
 708       |> forbidden_json_reply("Invalid credentials.")
 709       |> halt()
 710     end
 711   end
 712
 713   defp error_json(conn, error_message) do
 714     %{"error" => error_message, "request" => conn.request_path} |> Jason.encode!()
 715   end
 716
 717   def errors(conn, {:param_cast, _}) do
 718     conn
 719     |> put_status(400)
 720     |> json("Invalid parameters")
 721   end
 722
 723   def errors(conn, _) do
 724     conn
 725     |> put_status(500)
 726     |> json("Something went wrong")
 727   end
 728 end