git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.Controller do
   2   use Pleroma.Web, :controller
   3
   4   import Pleroma.Web.ControllerHelper, only: [json_response: 3]
   5
   6   alias Pleroma.Web.TwitterAPI.{TwitterAPI, UserView, ActivityView, NotificationView}
   7   alias Pleroma.Web.CommonAPI
   8   alias Pleroma.{Repo, Activity, Object, User, Notification}
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Utils
  11   alias Ecto.Changeset
  12
  13   require Logger
  14
  15   plug(:only_if_public_instance when action in [:public_timeline, :public_and_external_timeline])
  16   action_fallback(:errors)
  17
  18   def verify_credentials(%{assigns: %{user: user}} = conn, _params) do
  19     token = Phoenix.Token.sign(conn, "user socket", user.id)
  20
  21     conn
  22     |> put_view(UserView)
  23     |> render("show.json", %{user: user, token: token})
  24   end
  25
  26   def status_update(%{assigns: %{user: user}} = conn, %{"status" => _} = status_data) do
  27     with media_ids <- extract_media_ids(status_data),
  28          {:ok, activity} <-
  29            TwitterAPI.create_status(user, Map.put(status_data, "media_ids", media_ids)) do
  30       conn
  31       |> json(ActivityView.render("activity.json", activity: activity, for: user))
  32     else
  33       _ -> empty_status_reply(conn)
  34     end
  35   end
  36
  37   def status_update(conn, _status_data) do
  38     empty_status_reply(conn)
  39   end
  40
  41   defp empty_status_reply(conn) do
  42     bad_request_reply(conn, "Client must provide a 'status' parameter with a value.")
  43   end
  44
  45   defp extract_media_ids(status_data) do
  46     with media_ids when not is_nil(media_ids) <- status_data["media_ids"],
  47          split_ids <- String.split(media_ids, ","),
  48          clean_ids <- Enum.reject(split_ids, fn id -> String.length(id) == 0 end) do
  49       clean_ids
  50     else
  51       _e -> []
  52     end
  53   end
  54
  55   def public_and_external_timeline(%{assigns: %{user: user}} = conn, params) do
  56     params =
  57       params
  58       |> Map.put("type", ["Create", "Announce"])
  59       |> Map.put("blocking_user", user)
  60
  61     activities = ActivityPub.fetch_public_activities(params)
  62
  63     conn
  64     |> put_view(ActivityView)
  65     |> render("index.json", %{activities: activities, for: user})
  66   end
  67
  68   def public_timeline(%{assigns: %{user: user}} = conn, params) do
  69     params =
  70       params
  71       |> Map.put("type", ["Create", "Announce"])
  72       |> Map.put("local_only", true)
  73       |> Map.put("blocking_user", user)
  74
  75     activities = ActivityPub.fetch_public_activities(params)
  76
  77     conn
  78     |> put_view(ActivityView)
  79     |> render("index.json", %{activities: activities, for: user})
  80   end
  81
  82   def friends_timeline(%{assigns: %{user: user}} = conn, params) do
  83     params =
  84       params
  85       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
  86       |> Map.put("blocking_user", user)
  87       |> Map.put("user", user)
  88
  89     activities =
  90       ActivityPub.fetch_activities([user.ap_id | user.following], params)
  91       |> ActivityPub.contain_timeline(user)
  92
  93     conn
  94     |> put_view(ActivityView)
  95     |> render("index.json", %{activities: activities, for: user})
  96   end
  97
  98   def show_user(conn, params) do
  99     with {:ok, shown} <- TwitterAPI.get_user(params) do
 100       params =
 101         if user = conn.assigns.user do
 102           %{user: shown, for: user}
 103         else
 104           %{user: shown}
 105         end
 106
 107       conn
 108       |> put_view(UserView)
 109       |> render("show.json", params)
 110     else
 111       {:error, msg} ->
 112         bad_request_reply(conn, msg)
 113     end
 114   end
 115
 116   def user_timeline(%{assigns: %{user: user}} = conn, params) do
 117     case TwitterAPI.get_user(user, params) do
 118       {:ok, target_user} ->
 119         activities = ActivityPub.fetch_user_activities(target_user, user, params)
 120
 121         conn
 122         |> put_view(ActivityView)
 123         |> render("index.json", %{activities: activities, for: user})
 124
 125       {:error, msg} ->
 126         bad_request_reply(conn, msg)
 127     end
 128   end
 129
 130   def mentions_timeline(%{assigns: %{user: user}} = conn, params) do
 131     params =
 132       params
 133       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
 134       |> Map.put("blocking_user", user)
 135
 136     activities = ActivityPub.fetch_activities([user.ap_id], params)
 137
 138     conn
 139     |> put_view(ActivityView)
 140     |> render("index.json", %{activities: activities, for: user})
 141   end
 142
 143   def dm_timeline(%{assigns: %{user: user}} = conn, params) do
 144     query =
 145       ActivityPub.fetch_activities_query(
 146         [user.ap_id],
 147         Map.merge(params, %{"type" => "Create", "user" => user, visibility: "direct"})
 148       )
 149
 150     activities = Repo.all(query)
 151
 152     conn
 153     |> put_view(ActivityView)
 154     |> render("index.json", %{activities: activities, for: user})
 155   end
 156
 157   def notifications(%{assigns: %{user: user}} = conn, params) do
 158     notifications = Notification.for_user(user, params)
 159
 160     conn
 161     |> put_view(NotificationView)
 162     |> render("notification.json", %{notifications: notifications, for: user})
 163   end
 164
 165   def notifications_read(%{assigns: %{user: user}} = conn, %{"latest_id" => latest_id} = params) do
 166     Notification.set_read_up_to(user, latest_id)
 167
 168     notifications = Notification.for_user(user, params)
 169
 170     conn
 171     |> put_view(NotificationView)
 172     |> render("notification.json", %{notifications: notifications, for: user})
 173   end
 174
 175   def notifications_read(%{assigns: %{user: _user}} = conn, _) do
 176     bad_request_reply(conn, "You need to specify latest_id")
 177   end
 178
 179   def follow(%{assigns: %{user: user}} = conn, params) do
 180     case TwitterAPI.follow(user, params) do
 181       {:ok, user, followed, _activity} ->
 182         conn
 183         |> put_view(UserView)
 184         |> render("show.json", %{user: followed, for: user})
 185
 186       {:error, msg} ->
 187         forbidden_json_reply(conn, msg)
 188     end
 189   end
 190
 191   def block(%{assigns: %{user: user}} = conn, params) do
 192     case TwitterAPI.block(user, params) do
 193       {:ok, user, blocked} ->
 194         conn
 195         |> put_view(UserView)
 196         |> render("show.json", %{user: blocked, for: user})
 197
 198       {:error, msg} ->
 199         forbidden_json_reply(conn, msg)
 200     end
 201   end
 202
 203   def unblock(%{assigns: %{user: user}} = conn, params) do
 204     case TwitterAPI.unblock(user, params) do
 205       {:ok, user, blocked} ->
 206         conn
 207         |> put_view(UserView)
 208         |> render("show.json", %{user: blocked, for: user})
 209
 210       {:error, msg} ->
 211         forbidden_json_reply(conn, msg)
 212     end
 213   end
 214
 215   def delete_post(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 216     with {:ok, activity} <- TwitterAPI.delete(user, id) do
 217       conn
 218       |> put_view(ActivityView)
 219       |> render("activity.json", %{activity: activity, for: user})
 220     end
 221   end
 222
 223   def unfollow(%{assigns: %{user: user}} = conn, params) do
 224     case TwitterAPI.unfollow(user, params) do
 225       {:ok, user, unfollowed} ->
 226         conn
 227         |> put_view(UserView)
 228         |> render("show.json", %{user: unfollowed, for: user})
 229
 230       {:error, msg} ->
 231         forbidden_json_reply(conn, msg)
 232     end
 233   end
 234
 235   def fetch_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 236     with %Activity{} = activity <- Repo.get(Activity, id),
 237          true <- ActivityPub.visible_for_user?(activity, user) do
 238       conn
 239       |> put_view(ActivityView)
 240       |> render("activity.json", %{activity: activity, for: user})
 241     end
 242   end
 243
 244   def fetch_conversation(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 245     id = String.to_integer(id)
 246
 247     with context when is_binary(context) <- TwitterAPI.conversation_id_to_context(id),
 248          activities <-
 249            ActivityPub.fetch_activities_for_context(context, %{
 250              "blocking_user" => user,
 251              "user" => user
 252            }) do
 253       conn
 254       |> put_view(ActivityView)
 255       |> render("index.json", %{activities: activities, for: user})
 256     end
 257   end
 258
 259   @doc """
 260   Updates metadata of uploaded media object.
 261   Derived from [Twitter API endpoint](https://developer.twitter.com/en/docs/media/upload-media/api-reference/post-media-metadata-create).
 262   """
 263   def update_media(%{assigns: %{user: user}} = conn, %{"media_id" => id} = data) do
 264     object = Repo.get(Object, id)
 265     description = get_in(data, ["alt_text", "text"]) || data["name"] || data["description"]
 266
 267     {conn, status, response_body} =
 268       cond do
 269         !object ->
 270           {halt(conn), :not_found, ""}
 271
 272         !Object.authorize_mutation(object, user) ->
 273           {halt(conn), :forbidden, "You can only update your own uploads."}
 274
 275         !is_binary(description) ->
 276           {conn, :not_modified, ""}
 277
 278         true ->
 279           new_data = Map.put(object.data, "name", description)
 280
 281           {:ok, _} =
 282             object
 283             |> Object.change(%{data: new_data})
 284             |> Repo.update()
 285
 286           {conn, :no_content, ""}
 287       end
 288
 289     conn
 290     |> put_status(status)
 291     |> json(response_body)
 292   end
 293
 294   def upload(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 295     response = TwitterAPI.upload(media, user)
 296
 297     conn
 298     |> put_resp_content_type("application/atom+xml")
 299     |> send_resp(200, response)
 300   end
 301
 302   def upload_json(%{assigns: %{user: user}} = conn, %{"media" => media}) do
 303     response = TwitterAPI.upload(media, user, "json")
 304
 305     conn
 306     |> json_reply(200, response)
 307   end
 308
 309   def get_by_id_or_ap_id(id) do
 310     activity = Repo.get(Activity, id) || Activity.get_create_activity_by_object_ap_id(id)
 311
 312     if activity.data["type"] == "Create" do
 313       activity
 314     else
 315       Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 316     end
 317   end
 318
 319   def favorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 320     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 321          {:ok, activity} <- TwitterAPI.fav(user, id) do
 322       conn
 323       |> put_view(ActivityView)
 324       |> render("activity.json", %{activity: activity, for: user})
 325     end
 326   end
 327
 328   def unfavorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 329     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 330          {:ok, activity} <- TwitterAPI.unfav(user, id) do
 331       conn
 332       |> put_view(ActivityView)
 333       |> render("activity.json", %{activity: activity, for: user})
 334     end
 335   end
 336
 337   def retweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 338     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 339          {:ok, activity} <- TwitterAPI.repeat(user, id) do
 340       conn
 341       |> put_view(ActivityView)
 342       |> render("activity.json", %{activity: activity, for: user})
 343     end
 344   end
 345
 346   def unretweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 347     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 348          {:ok, activity} <- TwitterAPI.unrepeat(user, id) do
 349       conn
 350       |> put_view(ActivityView)
 351       |> render("activity.json", %{activity: activity, for: user})
 352     end
 353   end
 354
 355   def register(conn, params) do
 356     with {:ok, user} <- TwitterAPI.register_user(params) do
 357       conn
 358       |> put_view(UserView)
 359       |> render("show.json", %{user: user})
 360     else
 361       {:error, errors} ->
 362         conn
 363         |> json_reply(400, Jason.encode!(errors))
 364     end
 365   end
 366
 367   def password_reset(conn, params) do
 368     nickname_or_email = params["email"] || params["nickname"]
 369
 370     with {:ok, _} <- TwitterAPI.password_reset(nickname_or_email) do
 371       json_response(conn, :no_content, "")
 372     end
 373   end
 374
 375   def update_avatar(%{assigns: %{user: user}} = conn, params) do
 376     {:ok, object} = ActivityPub.upload(params, type: :avatar)
 377     change = Changeset.change(user, %{avatar: object.data})
 378     {:ok, user} = User.update_and_set_cache(change)
 379     CommonAPI.update(user)
 380
 381     conn
 382     |> put_view(UserView)
 383     |> render("show.json", %{user: user, for: user})
 384   end
 385
 386   def update_banner(%{assigns: %{user: user}} = conn, params) do
 387     with {:ok, object} <- ActivityPub.upload(%{"img" => params["banner"]}, type: :banner),
 388          new_info <- %{"banner" => object.data},
 389          info_cng <- User.Info.profile_update(user.info, new_info),
 390          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 391          {:ok, user} <- User.update_and_set_cache(changeset) do
 392       CommonAPI.update(user)
 393       %{"url" => [%{"href" => href} | _]} = object.data
 394       response = %{url: href} |> Jason.encode!()
 395
 396       conn
 397       |> json_reply(200, response)
 398     end
 399   end
 400
 401   def update_background(%{assigns: %{user: user}} = conn, params) do
 402     with {:ok, object} <- ActivityPub.upload(params, type: :background),
 403          new_info <- %{"background" => object.data},
 404          info_cng <- User.Info.profile_update(user.info, new_info),
 405          changeset <- Ecto.Changeset.change(user) |> Ecto.Changeset.put_embed(:info, info_cng),
 406          {:ok, _user} <- User.update_and_set_cache(changeset) do
 407       %{"url" => [%{"href" => href} | _]} = object.data
 408       response = %{url: href} |> Jason.encode!()
 409
 410       conn
 411       |> json_reply(200, response)
 412     end
 413   end
 414
 415   def external_profile(%{assigns: %{user: current_user}} = conn, %{"profileurl" => uri}) do
 416     with {:ok, user_map} <- TwitterAPI.get_external_profile(current_user, uri),
 417          response <- Jason.encode!(user_map) do
 418       conn
 419       |> json_reply(200, response)
 420     else
 421       _e ->
 422         conn
 423         |> put_status(404)
 424         |> json(%{error: "Can't find user"})
 425     end
 426   end
 427
 428   def followers(%{assigns: %{user: for_user}} = conn, params) do
 429     with {:ok, user} <- TwitterAPI.get_user(for_user, params),
 430          {:ok, followers} <- User.get_followers(user) do
 431       followers =
 432         cond do
 433           for_user && user.id == for_user.id -> followers
 434           user.info.hide_network -> []
 435           true -> followers
 436         end
 437
 438       conn
 439       |> put_view(UserView)
 440       |> render("index.json", %{users: followers, for: conn.assigns[:user]})
 441     else
 442       _e -> bad_request_reply(conn, "Can't get followers")
 443     end
 444   end
 445
 446   def friends(%{assigns: %{user: for_user}} = conn, params) do
 447     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 448          {:ok, friends} <- User.get_friends(user) do
 449       friends =
 450         cond do
 451           for_user && user.id == for_user.id -> friends
 452           user.info.hide_network -> []
 453           true -> friends
 454         end
 455
 456       conn
 457       |> put_view(UserView)
 458       |> render("index.json", %{users: friends, for: conn.assigns[:user]})
 459     else
 460       _e -> bad_request_reply(conn, "Can't get friends")
 461     end
 462   end
 463
 464   def friend_requests(conn, params) do
 465     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 466          {:ok, friend_requests} <- User.get_follow_requests(user) do
 467       conn
 468       |> put_view(UserView)
 469       |> render("index.json", %{users: friend_requests, for: conn.assigns[:user]})
 470     else
 471       _e -> bad_request_reply(conn, "Can't get friend requests")
 472     end
 473   end
 474
 475   def approve_friend_request(conn, %{"user_id" => uid} = _params) do
 476     with followed <- conn.assigns[:user],
 477          uid when is_number(uid) <- String.to_integer(uid),
 478          %User{} = follower <- Repo.get(User, uid),
 479          {:ok, follower} <- User.maybe_follow(follower, followed),
 480          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 481          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 482          {:ok, _activity} <-
 483            ActivityPub.accept(%{
 484              to: [follower.ap_id],
 485              actor: followed.ap_id,
 486              object: follow_activity.data["id"],
 487              type: "Accept"
 488            }) do
 489       conn
 490       |> put_view(UserView)
 491       |> render("show.json", %{user: follower, for: followed})
 492     else
 493       e -> bad_request_reply(conn, "Can't approve user: #{inspect(e)}")
 494     end
 495   end
 496
 497   def deny_friend_request(conn, %{"user_id" => uid} = _params) do
 498     with followed <- conn.assigns[:user],
 499          uid when is_number(uid) <- String.to_integer(uid),
 500          %User{} = follower <- Repo.get(User, uid),
 501          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 502          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 503          {:ok, _activity} <-
 504            ActivityPub.reject(%{
 505              to: [follower.ap_id],
 506              actor: followed.ap_id,
 507              object: follow_activity.data["id"],
 508              type: "Reject"
 509            }) do
 510       conn
 511       |> put_view(UserView)
 512       |> render("show.json", %{user: follower, for: followed})
 513     else
 514       e -> bad_request_reply(conn, "Can't deny user: #{inspect(e)}")
 515     end
 516   end
 517
 518   def friends_ids(%{assigns: %{user: user}} = conn, _params) do
 519     with {:ok, friends} <- User.get_friends(user) do
 520       ids =
 521         friends
 522         |> Enum.map(fn x -> x.id end)
 523         |> Jason.encode!()
 524
 525       json(conn, ids)
 526     else
 527       _e -> bad_request_reply(conn, "Can't get friends")
 528     end
 529   end
 530
 531   def empty_array(conn, _params) do
 532     json(conn, Jason.encode!([]))
 533   end
 534
 535   def raw_empty_array(conn, _params) do
 536     json(conn, [])
 537   end
 538
 539   defp build_info_cng(user, params) do
 540     info_params =
 541       ["no_rich_text", "locked", "hide_network"]
 542       |> Enum.reduce(%{}, fn key, res ->
 543         if value = params[key] do
 544           Map.put(res, key, value == "true")
 545         else
 546           res
 547         end
 548       end)
 549
 550     info_params =
 551       if value = params["default_scope"] do
 552         Map.put(info_params, "default_scope", value)
 553       else
 554         info_params
 555       end
 556
 557     User.Info.profile_update(user.info, info_params)
 558   end
 559
 560   defp parse_profile_bio(user, params) do
 561     if bio = params["description"] do
 562       Map.put(params, "bio", User.parse_bio(bio, user))
 563     else
 564       params
 565     end
 566   end
 567
 568   def update_profile(%{assigns: %{user: user}} = conn, params) do
 569     params = parse_profile_bio(user, params)
 570     info_cng = build_info_cng(user, params)
 571
 572     with changeset <- User.update_changeset(user, params),
 573          changeset <- Ecto.Changeset.put_embed(changeset, :info, info_cng),
 574          {:ok, user} <- User.update_and_set_cache(changeset) do
 575       CommonAPI.update(user)
 576
 577       conn
 578       |> put_view(UserView)
 579       |> render("user.json", %{user: user, for: user})
 580     else
 581       error ->
 582         Logger.debug("Can't update user: #{inspect(error)}")
 583         bad_request_reply(conn, "Can't update user")
 584     end
 585   end
 586
 587   def search(%{assigns: %{user: user}} = conn, %{"q" => _query} = params) do
 588     activities = TwitterAPI.search(user, params)
 589
 590     conn
 591     |> put_view(ActivityView)
 592     |> render("index.json", %{activities: activities, for: user})
 593   end
 594
 595   def search_user(%{assigns: %{user: user}} = conn, %{"query" => query}) do
 596     users = User.search(query, true)
 597
 598     conn
 599     |> put_view(UserView)
 600     |> render("index.json", %{users: users, for: user})
 601   end
 602
 603   defp bad_request_reply(conn, error_message) do
 604     json = error_json(conn, error_message)
 605     json_reply(conn, 400, json)
 606   end
 607
 608   defp json_reply(conn, status, json) do
 609     conn
 610     |> put_resp_content_type("application/json")
 611     |> send_resp(status, json)
 612   end
 613
 614   defp forbidden_json_reply(conn, error_message) do
 615     json = error_json(conn, error_message)
 616     json_reply(conn, 403, json)
 617   end
 618
 619   def only_if_public_instance(conn = %{conn: %{assigns: %{user: _user}}}, _), do: conn
 620
 621   def only_if_public_instance(conn, _) do
 622     if Keyword.get(Application.get_env(:pleroma, :instance), :public) do
 623       conn
 624     else
 625       conn
 626       |> forbidden_json_reply("Invalid credentials.")
 627       |> halt()
 628     end
 629   end
 630
 631   defp error_json(conn, error_message) do
 632     %{"error" => error_message, "request" => conn.request_path} |> Jason.encode!()
 633   end
 634
 635   def errors(conn, {:param_cast, _}) do
 636     conn
 637     |> put_status(400)
 638     |> json("Invalid parameters")
 639   end
 640
 641   def errors(conn, _) do
 642     conn
 643     |> put_status(500)
 644     |> json("Something went wrong")
 645   end
 646 end