git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/twitter_api_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.Controller do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.Formatter
   4   alias Pleroma.Web.TwitterAPI.{TwitterAPI, UserView, ActivityView, NotificationView}
   5   alias Pleroma.Web.CommonAPI
   6   alias Pleroma.Web.CommonAPI.Utils, as: CommonUtils
   7   alias Pleroma.{Repo, Activity, User, Notification}
   8   alias Pleroma.Web.ActivityPub.ActivityPub
   9   alias Pleroma.Web.ActivityPub.Utils
  10   alias Ecto.Changeset
  11
  12   require Logger
  13
  14   action_fallback(:errors)
  15
  16   def verify_credentials(%{assigns: %{user: user}} = conn, _params) do
  17     token = Phoenix.Token.sign(conn, "user socket", user.id)
  18     render(conn, UserView, "show.json", %{user: user, token: token})
  19   end
  20
  21   def status_update(%{assigns: %{user: user}} = conn, %{"status" => _} = status_data) do
  22     with media_ids <- extract_media_ids(status_data),
  23          {:ok, activity} <-
  24            TwitterAPI.create_status(user, Map.put(status_data, "media_ids", media_ids)) do
  25       conn
  26       |> json(ActivityView.render("activity.json", activity: activity, for: user))
  27     else
  28       _ -> empty_status_reply(conn)
  29     end
  30   end
  31
  32   def status_update(conn, _status_data) do
  33     empty_status_reply(conn)
  34   end
  35
  36   defp empty_status_reply(conn) do
  37     bad_request_reply(conn, "Client must provide a 'status' parameter with a value.")
  38   end
  39
  40   defp extract_media_ids(status_data) do
  41     with media_ids when not is_nil(media_ids) <- status_data["media_ids"],
  42          split_ids <- String.split(media_ids, ","),
  43          clean_ids <- Enum.reject(split_ids, fn id -> String.length(id) == 0 end) do
  44       clean_ids
  45     else
  46       _e -> []
  47     end
  48   end
  49
  50   def public_and_external_timeline(%{assigns: %{user: user}} = conn, params) do
  51     params =
  52       params
  53       |> Map.put("type", ["Create", "Announce"])
  54       |> Map.put("blocking_user", user)
  55
  56     activities = ActivityPub.fetch_public_activities(params)
  57
  58     conn
  59     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  60   end
  61
  62   def public_timeline(%{assigns: %{user: user}} = conn, params) do
  63     params =
  64       params
  65       |> Map.put("type", ["Create", "Announce"])
  66       |> Map.put("local_only", true)
  67       |> Map.put("blocking_user", user)
  68
  69     activities = ActivityPub.fetch_public_activities(params)
  70
  71     conn
  72     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  73   end
  74
  75   def friends_timeline(%{assigns: %{user: user}} = conn, params) do
  76     params =
  77       params
  78       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
  79       |> Map.put("blocking_user", user)
  80       |> Map.put("user", user)
  81
  82     activities = ActivityPub.fetch_activities([user.ap_id | user.following], params)
  83
  84     conn
  85     |> render(ActivityView, "index.json", %{activities: activities, for: user})
  86   end
  87
  88   def show_user(conn, params) do
  89     with {:ok, shown} <- TwitterAPI.get_user(params) do
  90       if user = conn.assigns.user do
  91         render(conn, UserView, "show.json", %{user: shown, for: user})
  92       else
  93         render(conn, UserView, "show.json", %{user: shown})
  94       end
  95     else
  96       {:error, msg} ->
  97         bad_request_reply(conn, msg)
  98     end
  99   end
 100
 101   def user_timeline(%{assigns: %{user: user}} = conn, params) do
 102     case TwitterAPI.get_user(user, params) do
 103       {:ok, target_user} ->
 104         activities = ActivityPub.fetch_user_activities(target_user, user, params)
 105
 106         conn
 107         |> render(ActivityView, "index.json", %{activities: activities, for: user})
 108
 109       {:error, msg} ->
 110         bad_request_reply(conn, msg)
 111     end
 112   end
 113
 114   def mentions_timeline(%{assigns: %{user: user}} = conn, params) do
 115     params =
 116       params
 117       |> Map.put("type", ["Create", "Announce", "Follow", "Like"])
 118       |> Map.put("blocking_user", user)
 119
 120     activities = ActivityPub.fetch_activities([user.ap_id], params)
 121
 122     conn
 123     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 124   end
 125
 126   def notifications(%{assigns: %{user: user}} = conn, params) do
 127     notifications = Notification.for_user(user, params)
 128
 129     conn
 130     |> render(NotificationView, "notification.json", %{notifications: notifications, for: user})
 131   end
 132
 133   def follow(%{assigns: %{user: user}} = conn, params) do
 134     case TwitterAPI.follow(user, params) do
 135       {:ok, user, followed, _activity} ->
 136         render(conn, UserView, "show.json", %{user: followed, for: user})
 137
 138       {:error, msg} ->
 139         forbidden_json_reply(conn, msg)
 140     end
 141   end
 142
 143   def block(%{assigns: %{user: user}} = conn, params) do
 144     case TwitterAPI.block(user, params) do
 145       {:ok, user, blocked} ->
 146         render(conn, UserView, "show.json", %{user: blocked, for: user})
 147
 148       {:error, msg} ->
 149         forbidden_json_reply(conn, msg)
 150     end
 151   end
 152
 153   def unblock(%{assigns: %{user: user}} = conn, params) do
 154     case TwitterAPI.unblock(user, params) do
 155       {:ok, user, blocked} ->
 156         render(conn, UserView, "show.json", %{user: blocked, for: user})
 157
 158       {:error, msg} ->
 159         forbidden_json_reply(conn, msg)
 160     end
 161   end
 162
 163   def delete_post(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 164     with {:ok, activity} <- TwitterAPI.delete(user, id) do
 165       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 166     end
 167   end
 168
 169   def unfollow(%{assigns: %{user: user}} = conn, params) do
 170     case TwitterAPI.unfollow(user, params) do
 171       {:ok, user, unfollowed} ->
 172         render(conn, UserView, "show.json", %{user: unfollowed, for: user})
 173
 174       {:error, msg} ->
 175         forbidden_json_reply(conn, msg)
 176     end
 177   end
 178
 179   def fetch_status(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 180     with %Activity{} = activity <- Repo.get(Activity, id),
 181          true <- ActivityPub.visible_for_user?(activity, user) do
 182       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 183     end
 184   end
 185
 186   def fetch_conversation(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 187     id = String.to_integer(id)
 188
 189     with context when is_binary(context) <- TwitterAPI.conversation_id_to_context(id),
 190          activities <-
 191            ActivityPub.fetch_activities_for_context(context, %{
 192              "blocking_user" => user,
 193              "user" => user
 194            }) do
 195       conn
 196       |> render(ActivityView, "index.json", %{activities: activities, for: user})
 197     end
 198   end
 199
 200   def upload(conn, %{"media" => media}) do
 201     response = TwitterAPI.upload(media)
 202
 203     conn
 204     |> put_resp_content_type("application/atom+xml")
 205     |> send_resp(200, response)
 206   end
 207
 208   def upload_json(conn, %{"media" => media}) do
 209     response = TwitterAPI.upload(media, "json")
 210
 211     conn
 212     |> json_reply(200, response)
 213   end
 214
 215   def get_by_id_or_ap_id(id) do
 216     activity = Repo.get(Activity, id) || Activity.get_create_activity_by_object_ap_id(id)
 217
 218     if activity.data["type"] == "Create" do
 219       activity
 220     else
 221       Activity.get_create_activity_by_object_ap_id(activity.data["object"])
 222     end
 223   end
 224
 225   def favorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 226     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 227          {:ok, activity} <- TwitterAPI.fav(user, id) do
 228       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 229     end
 230   end
 231
 232   def unfavorite(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 233     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 234          {:ok, activity} <- TwitterAPI.unfav(user, id) do
 235       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 236     end
 237   end
 238
 239   def retweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 240     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 241          {:ok, activity} <- TwitterAPI.repeat(user, id) do
 242       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 243     end
 244   end
 245
 246   def unretweet(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 247     with {_, {:ok, id}} <- {:param_cast, Ecto.Type.cast(:integer, id)},
 248          {:ok, activity} <- TwitterAPI.unrepeat(user, id) do
 249       render(conn, ActivityView, "activity.json", %{activity: activity, for: user})
 250     end
 251   end
 252
 253   def register(conn, params) do
 254     with {:ok, user} <- TwitterAPI.register_user(params) do
 255       render(conn, UserView, "show.json", %{user: user})
 256     else
 257       {:error, errors} ->
 258         conn
 259         |> json_reply(400, Jason.encode!(errors))
 260     end
 261   end
 262
 263   def update_avatar(%{assigns: %{user: user}} = conn, params) do
 264     {:ok, object} = ActivityPub.upload(params)
 265     change = Changeset.change(user, %{avatar: object.data})
 266     {:ok, user} = User.update_and_set_cache(change)
 267     CommonAPI.update(user)
 268
 269     render(conn, UserView, "show.json", %{user: user, for: user})
 270   end
 271
 272   def update_banner(%{assigns: %{user: user}} = conn, params) do
 273     with {:ok, object} <- ActivityPub.upload(%{"img" => params["banner"]}),
 274          new_info <- Map.put(user.info, "banner", object.data),
 275          change <- User.info_changeset(user, %{info: new_info}),
 276          {:ok, user} <- User.update_and_set_cache(change) do
 277       CommonAPI.update(user)
 278       %{"url" => [%{"href" => href} | _]} = object.data
 279       response = %{url: href} |> Jason.encode!()
 280
 281       conn
 282       |> json_reply(200, response)
 283     end
 284   end
 285
 286   def update_background(%{assigns: %{user: user}} = conn, params) do
 287     with {:ok, object} <- ActivityPub.upload(params),
 288          new_info <- Map.put(user.info, "background", object.data),
 289          change <- User.info_changeset(user, %{info: new_info}),
 290          {:ok, _user} <- User.update_and_set_cache(change) do
 291       %{"url" => [%{"href" => href} | _]} = object.data
 292       response = %{url: href} |> Jason.encode!()
 293
 294       conn
 295       |> json_reply(200, response)
 296     end
 297   end
 298
 299   def external_profile(%{assigns: %{user: current_user}} = conn, %{"profileurl" => uri}) do
 300     with {:ok, user_map} <- TwitterAPI.get_external_profile(current_user, uri),
 301          response <- Jason.encode!(user_map) do
 302       conn
 303       |> json_reply(200, response)
 304     else
 305       _e ->
 306         conn
 307         |> put_status(404)
 308         |> json(%{error: "Can't find user"})
 309     end
 310   end
 311
 312   def update_most_recent_notification(%{assigns: %{user: user}} = conn, %{"id" => id}) do
 313     with id when is_number(id) <- String.to_integer(id),
 314          info <- user.info,
 315          mrn <- max(id, user.info["most_recent_notification"] || 0),
 316          updated_info <- Map.put(info, "most_recent_notification", mrn),
 317          changeset <- User.info_changeset(user, %{info: updated_info}),
 318          {:ok, _user} <- User.update_and_set_cache(changeset) do
 319       conn
 320       |> json_reply(200, Jason.encode!(mrn))
 321     else
 322       _e -> bad_request_reply(conn, "Can't update.")
 323     end
 324   end
 325
 326   def followers(conn, params) do
 327     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 328          {:ok, followers} <- User.get_followers(user) do
 329       render(conn, UserView, "index.json", %{users: followers, for: conn.assigns[:user]})
 330     else
 331       _e -> bad_request_reply(conn, "Can't get followers")
 332     end
 333   end
 334
 335   def friends(conn, params) do
 336     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 337          {:ok, friends} <- User.get_friends(user) do
 338       render(conn, UserView, "index.json", %{users: friends, for: conn.assigns[:user]})
 339     else
 340       _e -> bad_request_reply(conn, "Can't get friends")
 341     end
 342   end
 343
 344   def friend_requests(conn, params) do
 345     with {:ok, user} <- TwitterAPI.get_user(conn.assigns[:user], params),
 346          {:ok, friend_requests} <- User.get_follow_requests(user) do
 347       render(conn, UserView, "index.json", %{users: friend_requests, for: conn.assigns[:user]})
 348     else
 349       _e -> bad_request_reply(conn, "Can't get friend requests")
 350     end
 351   end
 352
 353   def approve_friend_request(conn, %{"user_id" => uid} = params) do
 354     with followed <- conn.assigns[:user],
 355          uid when is_number(uid) <- String.to_integer(uid),
 356          %User{} = follower <- Repo.get(User, uid),
 357          {:ok, follower} <- User.maybe_follow(follower, followed),
 358          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 359          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "accept"),
 360          {:ok, _activity} <-
 361            ActivityPub.accept(%{
 362              to: [follower.ap_id],
 363              actor: followed.ap_id,
 364              object: follow_activity.data["id"],
 365              type: "Accept"
 366            }) do
 367       render(conn, UserView, "show.json", %{user: follower, for: followed})
 368     else
 369       e -> bad_request_reply(conn, "Can't approve user: #{inspect(e)}")
 370     end
 371   end
 372
 373   def deny_friend_request(conn, %{"user_id" => uid} = params) do
 374     with followed <- conn.assigns[:user],
 375          uid when is_number(uid) <- String.to_integer(uid),
 376          %User{} = follower <- Repo.get(User, uid),
 377          %Activity{} = follow_activity <- Utils.fetch_latest_follow(follower, followed),
 378          {:ok, follow_activity} <- Utils.update_follow_state(follow_activity, "reject"),
 379          {:ok, _activity} <-
 380            ActivityPub.reject(%{
 381              to: [follower.ap_id],
 382              actor: followed.ap_id,
 383              object: follow_activity.data["id"],
 384              type: "Reject"
 385            }) do
 386       render(conn, UserView, "show.json", %{user: follower, for: followed})
 387     else
 388       e -> bad_request_reply(conn, "Can't deny user: #{inspect(e)}")
 389     end
 390   end
 391
 392   def friends_ids(%{assigns: %{user: user}} = conn, _params) do
 393     with {:ok, friends} <- User.get_friends(user) do
 394       ids =
 395         friends
 396         |> Enum.map(fn x -> x.id end)
 397         |> Jason.encode!()
 398
 399       json(conn, ids)
 400     else
 401       _e -> bad_request_reply(conn, "Can't get friends")
 402     end
 403   end
 404
 405   def empty_array(conn, _params) do
 406     json(conn, Jason.encode!([]))
 407   end
 408
 409   def raw_empty_array(conn, _params) do
 410     json(conn, [])
 411   end
 412
 413   def update_profile(%{assigns: %{user: user}} = conn, params) do
 414     params =
 415       if bio = params["description"] do
 416         mentions = Formatter.parse_mentions(bio)
 417         tags = Formatter.parse_tags(bio)
 418
 419         emoji =
 420           (user.info["source_data"]["tag"] || [])
 421           |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 422           |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 423             {String.trim(name, ":"), url}
 424           end)
 425
 426         bio_html = CommonUtils.format_input(bio, mentions, tags)
 427         Map.put(params, "bio", bio_html |> Formatter.emojify(emoji))
 428       else
 429         params
 430       end
 431
 432     user =
 433       if locked = params["locked"] do
 434         with locked <- locked == "true",
 435              new_info <- Map.put(user.info, "locked", locked),
 436              change <- User.info_changeset(user, %{info: new_info}),
 437              {:ok, user} <- User.update_and_set_cache(change) do
 438           user
 439         else
 440           _e -> user
 441         end
 442       else
 443         user
 444       end
 445
 446     user =
 447       if default_scope = params["default_scope"] do
 448         with new_info <- Map.put(user.info, "default_scope", default_scope),
 449              change <- User.info_changeset(user, %{info: new_info}),
 450              {:ok, user} <- User.update_and_set_cache(change) do
 451           user
 452         else
 453           _e -> user
 454         end
 455       else
 456         user
 457       end
 458
 459     with changeset <- User.update_changeset(user, params),
 460          {:ok, user} <- User.update_and_set_cache(changeset) do
 461       CommonAPI.update(user)
 462       render(conn, UserView, "user.json", %{user: user, for: user})
 463     else
 464       error ->
 465         Logger.debug("Can't update user: #{inspect(error)}")
 466         bad_request_reply(conn, "Can't update user")
 467     end
 468   end
 469
 470   def search(%{assigns: %{user: user}} = conn, %{"q" => _query} = params) do
 471     activities = TwitterAPI.search(user, params)
 472
 473     conn
 474     |> render(ActivityView, "index.json", %{activities: activities, for: user})
 475   end
 476
 477   defp bad_request_reply(conn, error_message) do
 478     json = error_json(conn, error_message)
 479     json_reply(conn, 400, json)
 480   end
 481
 482   defp json_reply(conn, status, json) do
 483     conn
 484     |> put_resp_content_type("application/json")
 485     |> send_resp(status, json)
 486   end
 487
 488   defp forbidden_json_reply(conn, error_message) do
 489     json = error_json(conn, error_message)
 490     json_reply(conn, 403, json)
 491   end
 492
 493   defp error_json(conn, error_message) do
 494     %{"error" => error_message, "request" => conn.request_path} |> Jason.encode!()
 495   end
 496
 497   def errors(conn, {:param_cast, _}) do
 498     conn
 499     |> put_status(400)
 500     |> json("Invalid parameters")
 501   end
 502
 503   def errors(conn, _) do
 504     conn
 505     |> put_status(500)
 506     |> json("Something went wrong")
 507   end
 508 end