git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/controllers/util_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.UtilController do
   6   use Pleroma.Web, :controller
   7
   8   require Logger
   9
  10   alias Pleroma.Config
  11   alias Pleroma.Emoji
  12   alias Pleroma.Healthcheck
  13   alias Pleroma.Notification
  14   alias Pleroma.Plugs.OAuthScopesPlug
  15   alias Pleroma.User
  16   alias Pleroma.Web.CommonAPI
  17   alias Pleroma.Web.WebFinger
  18
  19   plug(Pleroma.Web.FederatingPlug when action == :remote_subscribe)
  20
  21   plug(
  22     OAuthScopesPlug,
  23     %{scopes: ["follow", "write:follows"]}
  24     when action == :follow_import
  25   )
  26
  27   plug(OAuthScopesPlug, %{scopes: ["follow", "write:blocks"]} when action == :blocks_import)
  28
  29   plug(
  30     OAuthScopesPlug,
  31     %{scopes: ["write:accounts"]}
  32     when action in [
  33            :change_email,
  34            :change_password,
  35            :delete_account,
  36            :update_notificaton_settings,
  37            :disable_account
  38          ]
  39   )
  40
  41   plug(OAuthScopesPlug, %{scopes: ["write:notifications"]} when action == :notifications_read)
  42
  43   def remote_subscribe(conn, %{"nickname" => nick, "profile" => _}) do
  44     with %User{} = user <- User.get_cached_by_nickname(nick),
  45          avatar = User.avatar_url(user) do
  46       conn
  47       |> render("subscribe.html", %{nickname: nick, avatar: avatar, error: false})
  48     else
  49       _e ->
  50         render(conn, "subscribe.html", %{
  51           nickname: nick,
  52           avatar: nil,
  53           error: "Could not find user"
  54         })
  55     end
  56   end
  57
  58   def remote_subscribe(conn, %{"user" => %{"nickname" => nick, "profile" => profile}}) do
  59     with {:ok, %{"subscribe_address" => template}} <- WebFinger.finger(profile),
  60          %User{ap_id: ap_id} <- User.get_cached_by_nickname(nick) do
  61       conn
  62       |> Phoenix.Controller.redirect(external: String.replace(template, "{uri}", ap_id))
  63     else
  64       _e ->
  65         render(conn, "subscribe.html", %{
  66           nickname: nick,
  67           avatar: nil,
  68           error: "Something went wrong."
  69         })
  70     end
  71   end
  72
  73   def notifications_read(%{assigns: %{user: user}} = conn, %{"id" => notification_id}) do
  74     with {:ok, _} <- Notification.read_one(user, notification_id) do
  75       json(conn, %{status: "success"})
  76     else
  77       {:error, message} ->
  78         conn
  79         |> put_resp_content_type("application/json")
  80         |> send_resp(403, Jason.encode!(%{"error" => message}))
  81     end
  82   end
  83
  84   def frontend_configurations(conn, _params) do
  85     config =
  86       Config.get(:frontend_configurations, %{})
  87       |> Enum.into(%{})
  88
  89     json(conn, config)
  90   end
  91
  92   def emoji(conn, _params) do
  93     emoji =
  94       Enum.reduce(Emoji.get_all(), %{}, fn {code, %Emoji{file: file, tags: tags}}, acc ->
  95         Map.put(acc, code, %{image_url: file, tags: tags})
  96       end)
  97
  98     json(conn, emoji)
  99   end
 100
 101   def update_notificaton_settings(%{assigns: %{user: user}} = conn, params) do
 102     with {:ok, _} <- User.update_notification_settings(user, params) do
 103       json(conn, %{status: "success"})
 104     end
 105   end
 106
 107   def follow_import(conn, %{"list" => %Plug.Upload{} = listfile}) do
 108     follow_import(conn, %{"list" => File.read!(listfile.path)})
 109   end
 110
 111   def follow_import(%{assigns: %{user: follower}} = conn, %{"list" => list}) do
 112     followed_identifiers =
 113       list
 114       |> String.split("\n")
 115       |> Enum.map(&(&1 |> String.split(",") |> List.first()))
 116       |> List.delete("Account address")
 117       |> Enum.map(&(&1 |> String.trim() |> String.trim_leading("@")))
 118       |> Enum.reject(&(&1 == ""))
 119
 120     User.follow_import(follower, followed_identifiers)
 121     json(conn, "job started")
 122   end
 123
 124   def blocks_import(conn, %{"list" => %Plug.Upload{} = listfile}) do
 125     blocks_import(conn, %{"list" => File.read!(listfile.path)})
 126   end
 127
 128   def blocks_import(%{assigns: %{user: blocker}} = conn, %{"list" => list}) do
 129     blocked_identifiers = list |> String.split() |> Enum.map(&String.trim_leading(&1, "@"))
 130     User.blocks_import(blocker, blocked_identifiers)
 131     json(conn, "job started")
 132   end
 133
 134   def change_password(%{assigns: %{user: user}} = conn, params) do
 135     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 136       {:ok, user} ->
 137         with {:ok, _user} <-
 138                User.reset_password(user, %{
 139                  password: params["new_password"],
 140                  password_confirmation: params["new_password_confirmation"]
 141                }) do
 142           json(conn, %{status: "success"})
 143         else
 144           {:error, changeset} ->
 145             {_, {error, _}} = Enum.at(changeset.errors, 0)
 146             json(conn, %{error: "New password #{error}."})
 147
 148           _ ->
 149             json(conn, %{error: "Unable to change password."})
 150         end
 151
 152       {:error, msg} ->
 153         json(conn, %{error: msg})
 154     end
 155   end
 156
 157   def change_email(%{assigns: %{user: user}} = conn, params) do
 158     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 159       {:ok, user} ->
 160         with {:ok, _user} <- User.change_email(user, params["email"]) do
 161           json(conn, %{status: "success"})
 162         else
 163           {:error, changeset} ->
 164             {_, {error, _}} = Enum.at(changeset.errors, 0)
 165             json(conn, %{error: "Email #{error}."})
 166
 167           _ ->
 168             json(conn, %{error: "Unable to change email."})
 169         end
 170
 171       {:error, msg} ->
 172         json(conn, %{error: msg})
 173     end
 174   end
 175
 176   def delete_account(%{assigns: %{user: user}} = conn, params) do
 177     password = params["password"] || ""
 178
 179     case CommonAPI.Utils.confirm_current_password(user, password) do
 180       {:ok, user} ->
 181         User.delete(user)
 182         json(conn, %{status: "success"})
 183
 184       {:error, msg} ->
 185         json(conn, %{error: msg})
 186     end
 187   end
 188
 189   def disable_account(%{assigns: %{user: user}} = conn, params) do
 190     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 191       {:ok, user} ->
 192         User.deactivate_async(user)
 193         json(conn, %{status: "success"})
 194
 195       {:error, msg} ->
 196         json(conn, %{error: msg})
 197     end
 198   end
 199
 200   def captcha(conn, _params) do
 201     json(conn, Pleroma.Captcha.new())
 202   end
 203
 204   def healthcheck(conn, _params) do
 205     with true <- Config.get([:instance, :healthcheck]),
 206          %{healthy: true} = info <- Healthcheck.system_info() do
 207       json(conn, info)
 208     else
 209       %{healthy: false} = info ->
 210         service_unavailable(conn, info)
 211
 212       _ ->
 213         service_unavailable(conn, %{})
 214     end
 215   end
 216
 217   defp service_unavailable(conn, info) do
 218     conn
 219     |> put_status(:service_unavailable)
 220     |> json(info)
 221   end
 222 end