git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/controllers/util_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.UtilController do
   6   use Pleroma.Web, :controller
   7
   8   require Logger
   9
  10   alias Pleroma.Config
  11   alias Pleroma.Emoji
  12   alias Pleroma.Healthcheck
  13   alias Pleroma.User
  14   alias Pleroma.Web.CommonAPI
  15   alias Pleroma.Web.Plugs.OAuthScopesPlug
  16   alias Pleroma.Web.WebFinger
  17
  18   plug(Pleroma.Web.ApiSpec.CastAndValidate when action != :remote_subscribe)
  19   plug(Pleroma.Web.Plugs.FederatingPlug when action == :remote_subscribe)
  20
  21   plug(
  22     OAuthScopesPlug,
  23     %{scopes: ["write:accounts"]}
  24     when action in [
  25            :change_email,
  26            :change_password,
  27            :delete_account,
  28            :update_notificaton_settings,
  29            :disable_account
  30          ]
  31   )
  32
  33   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.TwitterUtilOperation
  34
  35   def remote_subscribe(conn, %{"nickname" => nick, "profile" => _}) do
  36     with %User{} = user <- User.get_cached_by_nickname(nick),
  37          avatar = User.avatar_url(user) do
  38       conn
  39       |> render("subscribe.html", %{nickname: nick, avatar: avatar, error: false})
  40     else
  41       _e ->
  42         render(conn, "subscribe.html", %{
  43           nickname: nick,
  44           avatar: nil,
  45           error: "Could not find user"
  46         })
  47     end
  48   end
  49
  50   def remote_subscribe(conn, %{"user" => %{"nickname" => nick, "profile" => profile}}) do
  51     with {:ok, %{"subscribe_address" => template}} <- WebFinger.finger(profile),
  52          %User{ap_id: ap_id} <- User.get_cached_by_nickname(nick) do
  53       conn
  54       |> Phoenix.Controller.redirect(external: String.replace(template, "{uri}", ap_id))
  55     else
  56       _e ->
  57         render(conn, "subscribe.html", %{
  58           nickname: nick,
  59           avatar: nil,
  60           error: "Something went wrong."
  61         })
  62     end
  63   end
  64
  65   def remote_interaction(%{body_params: %{ap_id: ap_id, profile: profile}} = conn, _params) do
  66     with {:ok, %{"subscribe_address" => template}} <- WebFinger.finger(profile) do
  67       conn
  68       |> json(%{url: String.replace(template, "{uri}", ap_id)})
  69     else
  70       _e -> json(conn, %{error: "Couldn't find user"})
  71     end
  72   end
  73
  74   def frontend_configurations(conn, _params) do
  75     render(conn, "frontend_configurations.json")
  76   end
  77
  78   def emoji(conn, _params) do
  79     emoji =
  80       Enum.reduce(Emoji.get_all(), %{}, fn {code, %Emoji{file: file, tags: tags}}, acc ->
  81         Map.put(acc, code, %{image_url: file, tags: tags})
  82       end)
  83
  84     json(conn, emoji)
  85   end
  86
  87   def update_notificaton_settings(%{assigns: %{user: user}} = conn, params) do
  88     with {:ok, _} <- User.update_notification_settings(user, params) do
  89       json(conn, %{status: "success"})
  90     end
  91   end
  92
  93   def change_password(%{assigns: %{user: user}, body_params: body_params} = conn, %{}) do
  94     case CommonAPI.Utils.confirm_current_password(user, body_params.password) do
  95       {:ok, user} ->
  96         with {:ok, _user} <-
  97                User.reset_password(user, %{
  98                  password: body_params.new_password,
  99                  password_confirmation: body_params.new_password_confirmation
 100                }) do
 101           json(conn, %{status: "success"})
 102         else
 103           {:error, changeset} ->
 104             {_, {error, _}} = Enum.at(changeset.errors, 0)
 105             json(conn, %{error: "New password #{error}."})
 106
 107           _ ->
 108             json(conn, %{error: "Unable to change password."})
 109         end
 110
 111       {:error, msg} ->
 112         json(conn, %{error: msg})
 113     end
 114   end
 115
 116   def change_email(%{assigns: %{user: user}, body_params: body_params} = conn, %{}) do
 117     case CommonAPI.Utils.confirm_current_password(user, body_params.password) do
 118       {:ok, user} ->
 119         with {:ok, _user} <- User.change_email(user, body_params.email) do
 120           json(conn, %{status: "success"})
 121         else
 122           {:error, changeset} ->
 123             {_, {error, _}} = Enum.at(changeset.errors, 0)
 124             json(conn, %{error: "Email #{error}."})
 125
 126           _ ->
 127             json(conn, %{error: "Unable to change email."})
 128         end
 129
 130       {:error, msg} ->
 131         json(conn, %{error: msg})
 132     end
 133   end
 134
 135   def delete_account(%{assigns: %{user: user}} = conn, params) do
 136     password = params[:password] || ""
 137
 138     case CommonAPI.Utils.confirm_current_password(user, password) do
 139       {:ok, user} ->
 140         User.delete(user)
 141         json(conn, %{status: "success"})
 142
 143       {:error, msg} ->
 144         json(conn, %{error: msg})
 145     end
 146   end
 147
 148   def disable_account(%{assigns: %{user: user}} = conn, params) do
 149     case CommonAPI.Utils.confirm_current_password(user, params[:password]) do
 150       {:ok, user} ->
 151         User.set_activation_async(user, false)
 152         json(conn, %{status: "success"})
 153
 154       {:error, msg} ->
 155         json(conn, %{error: msg})
 156     end
 157   end
 158
 159   def captcha(conn, _params) do
 160     json(conn, Pleroma.Captcha.new())
 161   end
 162
 163   def healthcheck(conn, _params) do
 164     with true <- Config.get([:instance, :healthcheck]),
 165          %{healthy: true} = info <- Healthcheck.system_info() do
 166       json(conn, info)
 167     else
 168       %{healthy: false} = info ->
 169         service_unavailable(conn, info)
 170
 171       _ ->
 172         service_unavailable(conn, %{})
 173     end
 174   end
 175
 176   defp service_unavailable(conn, info) do
 177     conn
 178     |> put_status(:service_unavailable)
 179     |> json(info)
 180   end
 181 end