git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/controllers/util_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.UtilController do
   6   use Pleroma.Web, :controller
   7
   8   require Logger
   9
  10   alias Pleroma.Config
  11   alias Pleroma.Emoji
  12   alias Pleroma.Healthcheck
  13   alias Pleroma.Notification
  14   alias Pleroma.User
  15   alias Pleroma.Web.CommonAPI
  16   alias Pleroma.Web.Plugs.OAuthScopesPlug
  17   alias Pleroma.Web.WebFinger
  18
  19   plug(Pleroma.Web.Plugs.FederatingPlug when action == :remote_subscribe)
  20
  21   plug(
  22     OAuthScopesPlug,
  23     %{scopes: ["write:accounts"]}
  24     when action in [
  25            :change_email,
  26            :change_password,
  27            :delete_account,
  28            :update_notificaton_settings,
  29            :disable_account
  30          ]
  31   )
  32
  33   plug(OAuthScopesPlug, %{scopes: ["write:notifications"]} when action == :notifications_read)
  34
  35   def remote_subscribe(conn, %{"nickname" => nick, "profile" => _}) do
  36     with %User{} = user <- User.get_cached_by_nickname(nick),
  37          avatar = User.avatar_url(user) do
  38       conn
  39       |> render("subscribe.html", %{nickname: nick, avatar: avatar, error: false})
  40     else
  41       _e ->
  42         render(conn, "subscribe.html", %{
  43           nickname: nick,
  44           avatar: nil,
  45           error: "Could not find user"
  46         })
  47     end
  48   end
  49
  50   def remote_subscribe(conn, %{"user" => %{"nickname" => nick, "profile" => profile}}) do
  51     with {:ok, %{"subscribe_address" => template}} <- WebFinger.finger(profile),
  52          %User{ap_id: ap_id} <- User.get_cached_by_nickname(nick) do
  53       conn
  54       |> Phoenix.Controller.redirect(external: String.replace(template, "{uri}", ap_id))
  55     else
  56       _e ->
  57         render(conn, "subscribe.html", %{
  58           nickname: nick,
  59           avatar: nil,
  60           error: "Something went wrong."
  61         })
  62     end
  63   end
  64
  65   def notifications_read(%{assigns: %{user: user}} = conn, %{"id" => notification_id}) do
  66     with {:ok, _} <- Notification.read_one(user, notification_id) do
  67       json(conn, %{status: "success"})
  68     else
  69       {:error, message} ->
  70         conn
  71         |> put_resp_content_type("application/json")
  72         |> send_resp(403, Jason.encode!(%{"error" => message}))
  73     end
  74   end
  75
  76   def frontend_configurations(conn, _params) do
  77     render(conn, "frontend_configurations.json")
  78   end
  79
  80   def emoji(conn, _params) do
  81     emoji =
  82       Enum.reduce(Emoji.get_all(), %{}, fn {code, %Emoji{file: file, tags: tags}}, acc ->
  83         Map.put(acc, code, %{image_url: file, tags: tags})
  84       end)
  85
  86     json(conn, emoji)
  87   end
  88
  89   def update_notificaton_settings(%{assigns: %{user: user}} = conn, params) do
  90     with {:ok, _} <- User.update_notification_settings(user, params) do
  91       json(conn, %{status: "success"})
  92     end
  93   end
  94
  95   def change_password(%{assigns: %{user: user}} = conn, params) do
  96     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
  97       {:ok, user} ->
  98         with {:ok, _user} <-
  99                User.reset_password(user, %{
 100                  password: params["new_password"],
 101                  password_confirmation: params["new_password_confirmation"]
 102                }) do
 103           json(conn, %{status: "success"})
 104         else
 105           {:error, changeset} ->
 106             {_, {error, _}} = Enum.at(changeset.errors, 0)
 107             json(conn, %{error: "New password #{error}."})
 108
 109           _ ->
 110             json(conn, %{error: "Unable to change password."})
 111         end
 112
 113       {:error, msg} ->
 114         json(conn, %{error: msg})
 115     end
 116   end
 117
 118   def change_email(%{assigns: %{user: user}} = conn, params) do
 119     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 120       {:ok, user} ->
 121         with {:ok, _user} <- User.change_email(user, params["email"]) do
 122           json(conn, %{status: "success"})
 123         else
 124           {:error, changeset} ->
 125             {_, {error, _}} = Enum.at(changeset.errors, 0)
 126             json(conn, %{error: "Email #{error}."})
 127
 128           _ ->
 129             json(conn, %{error: "Unable to change email."})
 130         end
 131
 132       {:error, msg} ->
 133         json(conn, %{error: msg})
 134     end
 135   end
 136
 137   def delete_account(%{assigns: %{user: user}} = conn, params) do
 138     password = params["password"] || ""
 139
 140     case CommonAPI.Utils.confirm_current_password(user, password) do
 141       {:ok, user} ->
 142         User.delete(user)
 143         json(conn, %{status: "success"})
 144
 145       {:error, msg} ->
 146         json(conn, %{error: msg})
 147     end
 148   end
 149
 150   def disable_account(%{assigns: %{user: user}} = conn, params) do
 151     case CommonAPI.Utils.confirm_current_password(user, params["password"]) do
 152       {:ok, user} ->
 153         User.set_activation_async(user, false)
 154         json(conn, %{status: "success"})
 155
 156       {:error, msg} ->
 157         json(conn, %{error: msg})
 158     end
 159   end
 160
 161   def captcha(conn, _params) do
 162     json(conn, Pleroma.Captcha.new())
 163   end
 164
 165   def healthcheck(conn, _params) do
 166     with true <- Config.get([:instance, :healthcheck]),
 167          %{healthy: true} = info <- Healthcheck.system_info() do
 168       json(conn, info)
 169     else
 170       %{healthy: false} = info ->
 171         service_unavailable(conn, info)
 172
 173       _ ->
 174         service_unavailable(conn, %{})
 175     end
 176   end
 177
 178   defp service_unavailable(conn, info) do
 179     conn
 180     |> put_status(:service_unavailable)
 181     |> json(info)
 182   end
 183 end