git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/controllers/util_controller.ex

   1 defmodule Pleroma.Web.TwitterAPI.UtilController do
   2   use Pleroma.Web, :controller
   3   require Logger
   4   alias Pleroma.Web
   5   alias Pleroma.Web.OStatus
   6   alias Pleroma.Web.WebFinger
   7   alias Pleroma.Web.CommonAPI
   8   alias Comeonin.Pbkdf2
   9   alias Pleroma.Formatter
  10   alias Pleroma.Web.ActivityPub.ActivityPub
  11   alias Pleroma.{Repo, PasswordResetToken, User}
  12
  13   def show_password_reset(conn, %{"token" => token}) do
  14     with %{used: false} = token <- Repo.get_by(PasswordResetToken, %{token: token}),
  15          %User{} = user <- Repo.get(User, token.user_id) do
  16       render(conn, "password_reset.html", %{
  17         token: token,
  18         user: user
  19       })
  20     else
  21       _e -> render(conn, "invalid_token.html")
  22     end
  23   end
  24
  25   def password_reset(conn, %{"data" => data}) do
  26     with {:ok, _} <- PasswordResetToken.reset_password(data["token"], data) do
  27       render(conn, "password_reset_success.html")
  28     else
  29       _e -> render(conn, "password_reset_failed.html")
  30     end
  31   end
  32
  33   def help_test(conn, _params) do
  34     json(conn, "ok")
  35   end
  36
  37   def remote_subscribe(conn, %{"nickname" => nick, "profile" => _}) do
  38     with %User{} = user <- User.get_cached_by_nickname(nick), avatar = User.avatar_url(user) do
  39       conn
  40       |> render("subscribe.html", %{nickname: nick, avatar: avatar, error: false})
  41     else
  42       _e ->
  43         render(conn, "subscribe.html", %{
  44           nickname: nick,
  45           avatar: nil,
  46           error: "Could not find user"
  47         })
  48     end
  49   end
  50
  51   def remote_subscribe(conn, %{"user" => %{"nickname" => nick, "profile" => profile}}) do
  52     with {:ok, %{"subscribe_address" => template}} <- WebFinger.finger(profile),
  53          %User{ap_id: ap_id} <- User.get_cached_by_nickname(nick) do
  54       conn
  55       |> Phoenix.Controller.redirect(external: String.replace(template, "{uri}", ap_id))
  56     else
  57       _e ->
  58         render(conn, "subscribe.html", %{
  59           nickname: nick,
  60           avatar: nil,
  61           error: "Something went wrong."
  62         })
  63     end
  64   end
  65
  66   def remote_follow(%{assigns: %{user: user}} = conn, %{"acct" => acct}) do
  67     {err, followee} = OStatus.find_or_make_user(acct)
  68     avatar = User.avatar_url(followee)
  69     name = followee.nickname
  70     id = followee.id
  71
  72     if !!user do
  73       conn
  74       |> render("follow.html", %{error: err, acct: acct, avatar: avatar, name: name, id: id})
  75     else
  76       conn
  77       |> render("follow_login.html", %{
  78         error: false,
  79         acct: acct,
  80         avatar: avatar,
  81         name: name,
  82         id: id
  83       })
  84     end
  85   end
  86
  87   def do_remote_follow(conn, %{
  88         "authorization" => %{"name" => username, "password" => password, "id" => id}
  89       }) do
  90     followee = Repo.get(User, id)
  91     avatar = User.avatar_url(followee)
  92     name = followee.nickname
  93
  94     with %User{} = user <- User.get_cached_by_nickname(username),
  95          true <- Pbkdf2.checkpw(password, user.password_hash),
  96          %User{} = _followed <- Repo.get(User, id),
  97          {:ok, follower} <- User.follow(user, followee),
  98          {:ok, _activity} <- ActivityPub.follow(follower, followee) do
  99       conn
 100       |> render("followed.html", %{error: false})
 101     else
 102       _e ->
 103         conn
 104         |> render("follow_login.html", %{
 105           error: "Wrong username or password",
 106           id: id,
 107           name: name,
 108           avatar: avatar
 109         })
 110     end
 111   end
 112
 113   def do_remote_follow(%{assigns: %{user: user}} = conn, %{"user" => %{"id" => id}}) do
 114     with %User{} = followee <- Repo.get(User, id),
 115          {:ok, follower} <- User.follow(user, followee),
 116          {:ok, _activity} <- ActivityPub.follow(follower, followee) do
 117       conn
 118       |> render("followed.html", %{error: false})
 119     else
 120       e ->
 121         Logger.debug("Remote follow failed with error #{inspect(e)}")
 122
 123         conn
 124         |> render("followed.html", %{error: inspect(e)})
 125     end
 126   end
 127
 128   @instance Application.get_env(:pleroma, :instance)
 129   def config(conn, _params) do
 130     case get_format(conn) do
 131       "xml" ->
 132         response = """
 133         <config>
 134           <site>
 135             <name>#{Keyword.get(@instance, :name)}</name>
 136             <site>#{Web.base_url()}</site>
 137             <textlimit>#{Keyword.get(@instance, :limit)}</textlimit>
 138             <closed>#{!Keyword.get(@instance, :registrations_open)}</closed>
 139           </site>
 140         </config>
 141         """
 142
 143         conn
 144         |> put_resp_content_type("application/xml")
 145         |> send_resp(200, response)
 146
 147       _ ->
 148         json(conn, %{
 149           site: %{
 150             name: Keyword.get(@instance, :name),
 151             server: Web.base_url(),
 152             textlimit: to_string(Keyword.get(@instance, :limit)),
 153             closed: if(Keyword.get(@instance, :registrations_open), do: "0", else: "1")
 154           }
 155         })
 156     end
 157   end
 158
 159   def version(conn, _params) do
 160     version = Keyword.get(@instance, :version)
 161
 162     case get_format(conn) do
 163       "xml" ->
 164         response = "<version>#{version}</version>"
 165
 166         conn
 167         |> put_resp_content_type("application/xml")
 168         |> send_resp(200, response)
 169
 170       _ ->
 171         json(conn, version)
 172     end
 173   end
 174
 175   def emoji(conn, _params) do
 176     json(conn, Enum.into(Formatter.get_custom_emoji(), %{}))
 177   end
 178
 179   def follow_import(conn, %{"list" => %Plug.Upload{} = listfile}) do
 180     follow_import(conn, %{"list" => File.read!(listfile.path)})
 181   end
 182
 183   def follow_import(%{assigns: %{user: user}} = conn, %{"list" => list}) do
 184     Task.start(fn ->
 185       String.split(list)
 186       |> Enum.map(fn account ->
 187         with %User{} = follower <- User.get_cached_by_ap_id(user.ap_id),
 188              %User{} = followed <- User.get_or_fetch(account),
 189              {:ok, follower} <- User.follow(follower, followed) do
 190           ActivityPub.follow(follower, followed)
 191         else
 192           _e -> Logger.debug("follow_import: following #{account} failed")
 193         end
 194       end)
 195     end)
 196
 197     json(conn, "job started")
 198   end
 199
 200   def delete_account(%{assigns: %{user: user}} = conn, params) do
 201     case CommonAPI.Utils.confirm_current_password(user, params) do
 202       {:ok, user} ->
 203         case User.delete(user) do
 204           :ok -> json(conn, %{status: "success"})
 205           :error -> json(conn, %{error: "Unable to delete user."})
 206         end
 207
 208       {:error, msg} ->
 209         json(conn, %{error: msg})
 210     end
 211   end
 212 end