git.squeep.com Git - akkoma/blob - lib/pleroma/web/twitter_api/controllers/remote_follow_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.TwitterAPI.RemoteFollowController do
   6   use Pleroma.Web, :controller
   7
   8   require Logger
   9
  10   alias Pleroma.Activity
  11   alias Pleroma.Object.Fetcher
  12   alias Pleroma.Plugs.OAuthScopesPlug
  13   alias Pleroma.User
  14   alias Pleroma.Web.Auth.Authenticator
  15   alias Pleroma.Web.CommonAPI
  16
  17   @status_types ["Article", "Event", "Note", "Video", "Page", "Question"]
  18
  19   plug(OAuthScopesPlug, %{scopes: ["follow", "write:follows"]} when action in [:do_follow])
  20
  21   # GET /ostatus_subscribe
  22   #
  23   def follow(%{assigns: %{user: user}} = conn, %{"acct" => acct}) do
  24     case is_status?(acct) do
  25       true -> follow_status(conn, user, acct)
  26       _ -> follow_account(conn, user, acct)
  27     end
  28   end
  29
  30   defp follow_status(conn, _user, acct) do
  31     with {:ok, object} <- Fetcher.fetch_object_from_id(acct),
  32          %Activity{id: activity_id} <- Activity.get_create_by_object_ap_id(object.data["id"]) do
  33       redirect(conn, to: o_status_path(conn, :notice, activity_id))
  34     else
  35       error ->
  36         handle_follow_error(conn, error)
  37     end
  38   end
  39
  40   defp follow_account(conn, user, acct) do
  41     with {:ok, followee} <- User.get_or_fetch(acct) do
  42       render(conn, follow_template(user), %{error: false, followee: followee, acct: acct})
  43     else
  44       {:error, _reason} ->
  45         render(conn, follow_template(user), %{error: :error})
  46     end
  47   end
  48
  49   defp follow_template(%User{} = _user), do: "follow.html"
  50   defp follow_template(_), do: "follow_login.html"
  51
  52   defp is_status?(acct) do
  53     case Fetcher.fetch_and_contain_remote_object_from_id(acct) do
  54       {:ok, %{"type" => type}} when type in @status_types ->
  55         true
  56
  57       _ ->
  58         false
  59     end
  60   end
  61
  62   # POST  /ostatus_subscribe
  63   #
  64   def do_follow(conn, %{"authorization" => %{"name" => _, "password" => _, "id" => id}}) do
  65     with {:fetch_user, %User{} = followee} <- {:fetch_user, User.get_cached_by_id(id)},
  66          {_, {:ok, user}, _} <- {:auth, Authenticator.get_user(conn), followee},
  67          {:ok, _, _, _} <- CommonAPI.follow(user, followee) do
  68       render(conn, "followed.html", %{error: false})
  69     else
  70       error ->
  71         handle_follow_error(conn, error)
  72     end
  73   end
  74
  75   def do_follow(%{assigns: %{user: user}} = conn, %{"user" => %{"id" => id}}) do
  76     with {:fetch_user, %User{} = followee} <- {:fetch_user, User.get_cached_by_id(id)},
  77          {:ok, _, _, _} <- CommonAPI.follow(user, followee) do
  78       render(conn, "followed.html", %{error: false})
  79     else
  80       error ->
  81         handle_follow_error(conn, error)
  82     end
  83   end
  84
  85   defp handle_follow_error(conn, {:auth, _, followee} = _) do
  86     render(conn, "follow_login.html", %{error: "Wrong username or password", followee: followee})
  87   end
  88
  89   defp handle_follow_error(conn, {:fetch_user, error} = _) do
  90     Logger.debug("Remote follow failed with error #{inspect(error)}")
  91     render(conn, "followed.html", %{error: "Could not find user"})
  92   end
  93
  94   defp handle_follow_error(conn, {:error, "Could not follow user:" <> _} = _) do
  95     render(conn, "followed.html", %{error: "Error following account"})
  96   end
  97
  98   defp handle_follow_error(conn, error) do
  99     Logger.debug("Remote follow failed with error #{inspect(error)}")
 100     render(conn, "followed.html", %{error: "Something went wrong."})
 101   end
 102 end