git.squeep.com Git - akkoma/blob - lib/pleroma/web/static_fe/static_fe_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.StaticFE.StaticFEController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.ActivityPub
  12   alias Pleroma.Web.Router.Helpers
  13
  14   plug(:put_layout, :static_fe)
  15   plug(:put_view, Pleroma.Web.StaticFE.StaticFEView)
  16   plug(:assign_id)
  17   action_fallback(:not_found)
  18
  19   defp get_title(%Object{data: %{"name" => name}}) when is_binary(name),
  20     do: name
  21
  22   defp get_title(%Object{data: %{"summary" => summary}}) when is_binary(summary),
  23     do: summary
  24
  25   defp get_title(_), do: nil
  26
  27   def get_counts(%Activity{} = activity) do
  28     %Object{data: data} = Object.normalize(activity)
  29
  30     %{
  31       likes: data["like_count"] || 0,
  32       replies: data["repliesCount"] || 0,
  33       announces: data["announcement_count"] || 0
  34     }
  35   end
  36
  37   def represent(%Activity{} = activity, selected) do
  38     {:ok, user} = User.get_or_fetch(activity.object.data["actor"])
  39
  40     %{
  41       user: user,
  42       title: get_title(activity.object),
  43       content: activity.object.data["content"] || nil,
  44       attachment: activity.object.data["attachment"],
  45       link: Helpers.o_status_url(Pleroma.Web.Endpoint, :notice, activity.id),
  46       published: activity.object.data["published"],
  47       sensitive: activity.object.data["sensitive"],
  48       selected: selected,
  49       counts: get_counts(activity)
  50     }
  51   end
  52
  53   def show_notice(%{assigns: %{notice_id: notice_id}} = conn, _params) do
  54     instance_name = Pleroma.Config.get([:instance, :name], "Pleroma")
  55     activity = Activity.get_by_id_with_object(notice_id)
  56     context = activity.object.data["context"]
  57     activities = ActivityPub.fetch_activities_for_context(context, %{})
  58
  59     represented =
  60       for a <- Enum.reverse(activities) do
  61         represent(a, a.object.id == activity.object.id)
  62       end
  63
  64     render(conn, "conversation.html", %{activities: represented, instance_name: instance_name})
  65   end
  66
  67   def show_user(%{assigns: %{username_or_id: username_or_id}} = conn, _params) do
  68     instance_name = Pleroma.Config.get([:instance, :name], "Pleroma")
  69     %User{} = user = User.get_cached_by_nickname_or_id(username_or_id)
  70
  71     timeline =
  72       for activity <- ActivityPub.fetch_user_activities(user, nil, %{}) do
  73         represent(activity, false)
  74       end
  75
  76     render(conn, "profile.html", %{user: user, timeline: timeline, instance_name: instance_name})
  77   end
  78
  79   def assign_id(%{path_info: ["notice", notice_id]} = conn, _opts),
  80     do: assign(conn, :notice_id, notice_id)
  81
  82   def assign_id(%{path_info: ["users", user_id]} = conn, _opts),
  83     do: assign(conn, :username_or_id, user_id)
  84
  85   def assign_id(%{path_info: [user_id]} = conn, _opts),
  86     do: assign(conn, :username_or_id, user_id)
  87
  88   def assign_id(conn, _opts), do: conn
  89
  90   # Fallback for unhandled types
  91   def not_found(conn, _opts) do
  92     conn
  93     |> put_status(404)
  94     |> text("Not found")
  95   end
  96 end