git.squeep.com Git - akkoma/blob - lib/pleroma/web/rich_media/parsers/ttl/aws_signed_url.ex

   1 defmodule Pleroma.Web.RichMedia.Parser.TTL.AwsSignedUrl do
   2   @behaviour Pleroma.Web.RichMedia.Parser.TTL
   3
   4   @impl Pleroma.Web.RichMedia.Parser.TTL
   5   def ttl(data, _url) do
   6     image = Map.get(data, :image)
   7
   8     if is_aws_signed_url(image) do
   9       image
  10       |> parse_query_params()
  11       |> format_query_params()
  12       |> get_expiration_timestamp()
  13     end
  14   end
  15
  16   defp is_aws_signed_url(""), do: nil
  17   defp is_aws_signed_url(nil), do: nil
  18
  19   defp is_aws_signed_url(image) when is_binary(image) do
  20     %URI{host: host, query: query} = URI.parse(image)
  21
  22     if String.contains?(host, "amazonaws.com") and
  23          String.contains?(query, "X-Amz-Expires") do
  24       image
  25     else
  26       nil
  27     end
  28   end
  29
  30   defp is_aws_signed_url(_), do: nil
  31
  32   defp parse_query_params(image) do
  33     %URI{query: query} = URI.parse(image)
  34     query
  35   end
  36
  37   defp format_query_params(query) do
  38     query
  39     |> String.split(~r/&|=/)
  40     |> Enum.chunk_every(2)
  41     |> Map.new(fn [k, v] -> {k, v} end)
  42   end
  43
  44   defp get_expiration_timestamp(params) when is_map(params) do
  45     {:ok, date} =
  46       params
  47       |> Map.get("X-Amz-Date")
  48       |> Timex.parse("{ISO:Basic:Z}")
  49
  50     Timex.to_unix(date) + String.to_integer(Map.get(params, "X-Amz-Expires"))
  51   end
  52 end