git.squeep.com Git - akkoma/blob - lib/pleroma/web/rich_media/parser.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.RichMedia.Parser do
   6   require Logger
   7
   8   defp parsers do
   9     Pleroma.Config.get([:rich_media, :parsers])
  10   end
  11
  12   def parse(nil), do: {:error, "No URL provided"}
  13
  14   if Pleroma.Config.get(:env) == :test do
  15     @spec parse(String.t()) :: {:ok, map()} | {:error, any()}
  16     def parse(url), do: parse_url(url)
  17   else
  18     @spec parse(String.t()) :: {:ok, map()} | {:error, any()}
  19     def parse(url) do
  20       with {:ok, data} <- get_cached_or_parse(url),
  21            {:ok, _} <- set_ttl_based_on_image(data, url) do
  22         {:ok, data}
  23       else
  24         {:error, {:invalid_metadata, data}} = e ->
  25           Logger.debug(fn -> "Incomplete or invalid metadata for #{url}: #{inspect(data)}" end)
  26           e
  27
  28         error ->
  29           Logger.error(fn -> "Rich media error for #{url}: #{inspect(error)}" end)
  30           error
  31       end
  32     end
  33
  34     defp get_cached_or_parse(url) do
  35       case Cachex.fetch!(:rich_media_cache, url, fn _ -> {:commit, parse_url(url)} end) do
  36         {:ok, _data} = res ->
  37           res
  38
  39         {:error, :body_too_large} = e ->
  40           e
  41
  42         {:error, {:content_type, _}} = e ->
  43           e
  44
  45         # The TTL is not set for the errors above, since they are unlikely to change
  46         # with time
  47         {:error, _} = e ->
  48           ttl = Pleroma.Config.get([:rich_media, :failure_backoff], 60_000)
  49           Cachex.expire(:rich_media_cache, url, ttl)
  50           e
  51       end
  52     end
  53   end
  54
  55   @doc """
  56   Set the rich media cache based on the expiration time of image.
  57
  58   Adopt behaviour `Pleroma.Web.RichMedia.Parser.TTL`
  59
  60   ## Example
  61
  62       defmodule MyModule do
  63         @behaviour Pleroma.Web.RichMedia.Parser.TTL
  64         def ttl(data, url) do
  65           image_url = Map.get(data, :image)
  66           # do some parsing in the url and get the ttl of the image
  67           # and return ttl is unix time
  68           parse_ttl_from_url(image_url)
  69         end
  70       end
  71
  72   Define the module in the config
  73
  74       config :pleroma, :rich_media,
  75         ttl_setters: [MyModule]
  76   """
  77   @spec set_ttl_based_on_image(map(), String.t()) ::
  78           {:ok, Integer.t() | :noop} | {:error, :no_key}
  79   def set_ttl_based_on_image(data, url) do
  80     case get_ttl_from_image(data, url) do
  81       {:ok, ttl} when is_number(ttl) ->
  82         ttl = ttl * 1000
  83
  84         case Cachex.expire_at(:rich_media_cache, url, ttl) do
  85           {:ok, true} -> {:ok, ttl}
  86           {:ok, false} -> {:error, :no_key}
  87         end
  88
  89       _ ->
  90         {:ok, :noop}
  91     end
  92   end
  93
  94   defp get_ttl_from_image(data, url) do
  95     [:rich_media, :ttl_setters]
  96     |> Pleroma.Config.get()
  97     |> Enum.reduce({:ok, nil}, fn
  98       module, {:ok, _ttl} ->
  99         module.ttl(data, url)
 100
 101       _, error ->
 102         error
 103     end)
 104   end
 105
 106   def parse_url(url) do
 107     with {:ok, %Tesla.Env{body: html}} <- Pleroma.Web.RichMedia.Helpers.rich_media_get(url),
 108          {:ok, html} <- Floki.parse_document(html) do
 109       html
 110       |> maybe_parse()
 111       |> Map.put("url", url)
 112       |> clean_parsed_data()
 113       |> check_parsed_data()
 114     end
 115   end
 116
 117   defp maybe_parse(html) do
 118     Enum.reduce_while(parsers(), %{}, fn parser, acc ->
 119       case parser.parse(html, acc) do
 120         data when data != %{} -> {:halt, data}
 121         _ -> {:cont, acc}
 122       end
 123     end)
 124   end
 125
 126   defp check_parsed_data(%{"title" => title} = data)
 127        when is_binary(title) and title != "" do
 128     {:ok, data}
 129   end
 130
 131   defp check_parsed_data(data) do
 132     {:error, {:invalid_metadata, data}}
 133   end
 134
 135   defp clean_parsed_data(data) do
 136     data
 137     |> Enum.reject(fn {key, val} ->
 138       not match?({:ok, _}, Jason.encode(%{key => val}))
 139     end)
 140     |> Map.new()
 141   end
 142 end