git.squeep.com Git - akkoma/blob - lib/pleroma/web/rich_media/helpers.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright _ 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.RichMedia.Helpers do
   6   alias Pleroma.Activity
   7   alias Pleroma.Config
   8   alias Pleroma.HTML
   9   alias Pleroma.Object
  10   alias Pleroma.Web.RichMedia.Parser
  11
  12   @spec validate_page_url(URI.t() | binary()) :: :ok | :error
  13   defp validate_page_url(page_url) when is_binary(page_url) do
  14     validate_tld = Pleroma.Config.get([Pleroma.Formatter, :validate_tld])
  15
  16     page_url
  17     |> Linkify.Parser.url?(validate_tld: validate_tld)
  18     |> parse_uri(page_url)
  19   end
  20
  21   defp validate_page_url(%URI{host: host, scheme: "https", authority: authority})
  22        when is_binary(authority) do
  23     cond do
  24       host in Config.get([:rich_media, :ignore_hosts], []) ->
  25         :error
  26
  27       get_tld(host) in Config.get([:rich_media, :ignore_tld], []) ->
  28         :error
  29
  30       true ->
  31         :ok
  32     end
  33   end
  34
  35   defp validate_page_url(_), do: :error
  36
  37   defp parse_uri(true, url) do
  38     url
  39     |> URI.parse()
  40     |> validate_page_url
  41   end
  42
  43   defp parse_uri(_, _), do: :error
  44
  45   defp get_tld(host) do
  46     host
  47     |> String.split(".")
  48     |> Enum.reverse()
  49     |> hd
  50   end
  51
  52   def fetch_data_for_activity(%Activity{data: %{"type" => "Create"}} = activity) do
  53     with true <- Config.get([:rich_media, :enabled]),
  54          %Object{} = object <- Object.normalize(activity),
  55          false <- object.data["sensitive"] || false,
  56          {:ok, page_url} <- HTML.extract_first_external_url(object, object.data["content"]),
  57          :ok <- validate_page_url(page_url),
  58          {:ok, rich_media} <- Parser.parse(page_url) do
  59       %{page_url: page_url, rich_media: rich_media}
  60     else
  61       _ -> %{}
  62     end
  63   end
  64
  65   def fetch_data_for_activity(_), do: %{}
  66
  67   def perform(:fetch, %Activity{} = activity) do
  68     fetch_data_for_activity(activity)
  69     :ok
  70   end
  71 end