git.squeep.com Git - akkoma/blob - lib/pleroma/web/plugs/frontend_static.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Plugs.FrontendStatic do
   6   require Pleroma.Constants
   7
   8   @moduledoc """
   9   This is a shim to call `Plug.Static` but with runtime `from` configuration`. It dispatches to the different frontends.
  10   """
  11   @behaviour Plug
  12
  13   def file_path(path, frontend_type \\ :primary) do
  14     if configuration = Pleroma.Config.get([:frontends, frontend_type]) do
  15       instance_static_path = Pleroma.Config.get([:instance, :static_dir], "instance/static")
  16
  17       Path.join([
  18         instance_static_path,
  19         "frontends",
  20         configuration["name"],
  21         configuration["ref"],
  22         path
  23       ])
  24     else
  25       nil
  26     end
  27   end
  28
  29   def init(opts) do
  30     opts
  31     |> Keyword.put(:from, "__unconfigured_frontend_static_plug")
  32     |> Plug.Static.init()
  33     |> Map.put(:frontend_type, opts[:frontend_type])
  34     |> Map.put(:if, Keyword.get(opts, :if, true))
  35   end
  36
  37   def call(conn, opts) do
  38     with false <- api_route?(conn.path_info),
  39          false <- invalid_path?(conn.path_info),
  40          true <- enabled?(opts[:if]),
  41          frontend_type <- Map.get(opts, :frontend_type, :primary),
  42          path when not is_nil(path) <- file_path("", frontend_type) do
  43       call_static(conn, opts, path)
  44     else
  45       _ ->
  46         conn
  47     end
  48   end
  49
  50   defp enabled?(if_opt) when is_function(if_opt), do: if_opt.()
  51   defp enabled?(true), do: true
  52   defp enabled?(_), do: false
  53
  54   defp invalid_path?(list) do
  55     invalid_path?(list, :binary.compile_pattern(["/", "\\", ":", "\0"]))
  56   end
  57
  58   defp invalid_path?([h | _], _match) when h in [".", "..", ""], do: true
  59   defp invalid_path?([h | t], match), do: String.contains?(h, match) or invalid_path?(t)
  60   defp invalid_path?([], _match), do: false
  61
  62   defp api_route?([]), do: false
  63
  64   defp api_route?([h | t]) do
  65     api_routes = Pleroma.Web.Router.get_api_routes()
  66     if h in api_routes, do: true, else: api_route?(t)
  67   end
  68
  69   defp call_static(conn, opts, from) do
  70     opts = Map.put(opts, :from, from)
  71     Plug.Static.call(conn, opts)
  72   end
  73 end