git.squeep.com Git - akkoma/blob - lib/pleroma/web/pleroma_api/pleroma_api_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.PleromaAPI.PleromaAPIController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper, only: [add_link_headers: 2]
   9
  10   alias Pleroma.Conversation.Participation
  11   alias Pleroma.Notification
  12   alias Pleroma.Plugs.OAuthScopesPlug
  13   alias Pleroma.Web.ActivityPub.ActivityPub
  14   alias Pleroma.Web.MastodonAPI.ConversationView
  15   alias Pleroma.Web.MastodonAPI.NotificationView
  16   alias Pleroma.Web.MastodonAPI.StatusView
  17
  18   plug(
  19     OAuthScopesPlug,
  20     %{scopes: ["read:statuses"]} when action in [:conversation, :conversation_statuses]
  21   )
  22
  23   plug(
  24     OAuthScopesPlug,
  25     %{scopes: ["write:conversations"]} when action in [:conversations, :conversation_read]
  26   )
  27
  28   plug(OAuthScopesPlug, %{scopes: ["write:notifications"]} when action == :read_notification)
  29
  30   def conversation(%{assigns: %{user: user}} = conn, %{"id" => participation_id}) do
  31     with %Participation{} = participation <- Participation.get(participation_id),
  32          true <- user.id == participation.user_id do
  33       conn
  34       |> put_view(ConversationView)
  35       |> render("participation.json", %{participation: participation, for: user})
  36     end
  37   end
  38
  39   def conversation_statuses(
  40         %{assigns: %{user: user}} = conn,
  41         %{"id" => participation_id} = params
  42       ) do
  43     participation = Participation.get(participation_id, preload: [:conversation])
  44
  45     if user.id == participation.user_id do
  46       params =
  47         params
  48         |> Map.put("blocking_user", user)
  49         |> Map.put("muting_user", user)
  50         |> Map.put("user", user)
  51
  52       activities =
  53         participation.conversation.ap_id
  54         |> ActivityPub.fetch_activities_for_context(params)
  55         |> Enum.reverse()
  56
  57       conn
  58       |> add_link_headers(activities)
  59       |> put_view(StatusView)
  60       |> render("index.json", %{activities: activities, for: user, as: :activity})
  61     end
  62   end
  63
  64   def update_conversation(
  65         %{assigns: %{user: user}} = conn,
  66         %{"id" => participation_id, "recipients" => recipients}
  67       ) do
  68     participation =
  69       participation_id
  70       |> Participation.get()
  71
  72     with true <- user.id == participation.user_id,
  73          {:ok, participation} <- Participation.set_recipients(participation, recipients) do
  74       conn
  75       |> put_view(ConversationView)
  76       |> render("participation.json", %{participation: participation, for: user})
  77     end
  78   end
  79
  80   def read_notification(%{assigns: %{user: user}} = conn, %{"id" => notification_id}) do
  81     with {:ok, notification} <- Notification.read_one(user, notification_id) do
  82       conn
  83       |> put_view(NotificationView)
  84       |> render("show.json", %{notification: notification, for: user})
  85     else
  86       {:error, message} ->
  87         conn
  88         |> put_status(:bad_request)
  89         |> json(%{"error" => message})
  90     end
  91   end
  92
  93   def read_notification(%{assigns: %{user: user}} = conn, %{"max_id" => max_id}) do
  94     with notifications <- Notification.set_read_up_to(user, max_id) do
  95       notifications = Enum.take(notifications, 80)
  96
  97       conn
  98       |> put_view(NotificationView)
  99       |> render("index.json", %{notifications: notifications, for: user})
 100     end
 101   end
 102 end