git.squeep.com Git - akkoma/blob - lib/pleroma/web/pleroma_api/controllers/pleroma_api_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.PleromaAPI.PleromaAPIController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper, only: [add_link_headers: 2, fetch_integer_param: 2]
   9
  10   alias Pleroma.Conversation.Participation
  11   alias Pleroma.Notification
  12   alias Pleroma.User
  13   alias Pleroma.Web.ActivityPub.ActivityPub
  14   alias Pleroma.Web.CommonAPI
  15   alias Pleroma.Web.MastodonAPI.ConversationView
  16   alias Pleroma.Web.MastodonAPI.NotificationView
  17   alias Pleroma.Web.MastodonAPI.StatusView
  18
  19   def conversation(%{assigns: %{user: user}} = conn, %{"id" => participation_id}) do
  20     with %Participation{} = participation <- Participation.get(participation_id),
  21          true <- user.id == participation.user_id do
  22       conn
  23       |> put_view(ConversationView)
  24       |> render("participation.json", %{participation: participation, for: user})
  25     end
  26   end
  27
  28   def conversation_statuses(
  29         %{assigns: %{user: user}} = conn,
  30         %{"id" => participation_id} = params
  31       ) do
  32     participation = Participation.get(participation_id, preload: [:conversation])
  33
  34     if user.id == participation.user_id do
  35       params =
  36         params
  37         |> Map.put("blocking_user", user)
  38         |> Map.put("muting_user", user)
  39         |> Map.put("user", user)
  40
  41       activities =
  42         participation.conversation.ap_id
  43         |> ActivityPub.fetch_activities_for_context(params)
  44         |> Enum.reverse()
  45
  46       conn
  47       |> add_link_headers(activities)
  48       |> put_view(StatusView)
  49       |> render("index.json", %{activities: activities, for: user, as: :activity})
  50     end
  51   end
  52
  53   def update_conversation(
  54         %{assigns: %{user: user}} = conn,
  55         %{"id" => participation_id, "recipients" => recipients}
  56       ) do
  57     participation =
  58       participation_id
  59       |> Participation.get()
  60
  61     with true <- user.id == participation.user_id,
  62          {:ok, participation} <- Participation.set_recipients(participation, recipients) do
  63       conn
  64       |> put_view(ConversationView)
  65       |> render("participation.json", %{participation: participation, for: user})
  66     end
  67   end
  68
  69   def read_notification(%{assigns: %{user: user}} = conn, %{"id" => notification_id}) do
  70     with {:ok, notification} <- Notification.read_one(user, notification_id) do
  71       conn
  72       |> put_view(NotificationView)
  73       |> render("show.json", %{notification: notification, for: user})
  74     else
  75       {:error, message} ->
  76         conn
  77         |> put_status(:bad_request)
  78         |> json(%{"error" => message})
  79     end
  80   end
  81
  82   def read_notification(%{assigns: %{user: user}} = conn, %{"max_id" => max_id}) do
  83     with notifications <- Notification.set_read_up_to(user, max_id) do
  84       notifications = Enum.take(notifications, 80)
  85
  86       conn
  87       |> put_view(NotificationView)
  88       |> render("index.json", %{notifications: notifications, for: user})
  89     end
  90   end
  91
  92   def update_now_playing(%{assigns: %{user: user}} = conn, %{"title" => _} = params) do
  93     params =
  94       if !params["length"] do
  95         params
  96       else
  97         params
  98         |> Map.put("length", fetch_integer_param(params, "length"))
  99       end
 100
 101     with {:ok, activity} <- CommonAPI.listen(user, params) do
 102       conn
 103       |> put_view(StatusView)
 104       |> render("listen.json", %{activity: activity, for: user})
 105     else
 106       {:error, message} ->
 107         conn
 108         |> put_status(:bad_request)
 109         |> json(%{"error" => message})
 110     end
 111   end
 112
 113   def user_now_playing(%{assigns: %{user: reading_user}} = conn, params) do
 114     with %User{} = user <- User.get_cached_by_nickname_or_id(params["id"], for: reading_user) do
 115       params = Map.put(params, "type", ["Listen"])
 116
 117       activities = ActivityPub.fetch_user_abstract_activities(user, reading_user, params)
 118
 119       conn
 120       |> add_link_headers(activities)
 121       |> put_view(StatusView)
 122       |> render("listens.json", %{
 123         activities: activities,
 124         for: reading_user,
 125         as: :activity
 126       })
 127     end
 128   end
 129 end