git.squeep.com Git - akkoma/blob - lib/pleroma/web/pleroma_api/controllers/emoji_reaction_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.PleromaAPI.EmojiReactionController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.Object
  10   alias Pleroma.Plugs.OAuthScopesPlug
  11   alias Pleroma.Web.CommonAPI
  12   alias Pleroma.Web.MastodonAPI.StatusView
  13
  14   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  15   plug(OAuthScopesPlug, %{scopes: ["write:statuses"]} when action in [:create, :delete])
  16
  17   plug(
  18     OAuthScopesPlug,
  19     %{scopes: ["read:statuses"], fallback: :proceed_unauthenticated}
  20     when action == :index
  21   )
  22
  23   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.EmojiReactionOperation
  24
  25   action_fallback(Pleroma.Web.MastodonAPI.FallbackController)
  26
  27   def index(%{assigns: %{user: user}} = conn, %{id: activity_id} = params) do
  28     with %Activity{} = activity <- Activity.get_by_id_with_object(activity_id),
  29          %Object{data: %{"reactions" => reactions}} when is_list(reactions) <-
  30            Object.normalize(activity) do
  31       reactions = filter(reactions, params)
  32       render(conn, "index.json", emoji_reactions: reactions, user: user)
  33     else
  34       _e -> json(conn, [])
  35     end
  36   end
  37
  38   defp filter(reactions, %{emoji: emoji}) when is_binary(emoji) do
  39     Enum.filter(reactions, fn [e, _] -> e == emoji end)
  40   end
  41
  42   defp filter(reactions, _), do: reactions
  43
  44   def create(%{assigns: %{user: user}} = conn, %{id: activity_id, emoji: emoji}) do
  45     with {:ok, _activity} <- CommonAPI.react_with_emoji(activity_id, user, emoji) do
  46       activity = Activity.get_by_id(activity_id)
  47
  48       conn
  49       |> put_view(StatusView)
  50       |> render("show.json", activity: activity, for: user, as: :activity)
  51     end
  52   end
  53
  54   def delete(%{assigns: %{user: user}} = conn, %{id: activity_id, emoji: emoji}) do
  55     with {:ok, _activity} <- CommonAPI.unreact_with_emoji(activity_id, user, emoji) do
  56       activity = Activity.get_by_id(activity_id)
  57
  58       conn
  59       |> put_view(StatusView)
  60       |> render("show.json", activity: activity, for: user, as: :activity)
  61     end
  62   end
  63 end