git.squeep.com Git - akkoma/blob - lib/pleroma/web/pleroma_api/controllers/emoji_reaction_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.PleromaAPI.EmojiReactionController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.Object
  10   alias Pleroma.User
  11   alias Pleroma.Web.CommonAPI
  12   alias Pleroma.Web.MastodonAPI.StatusView
  13   alias Pleroma.Web.Plugs.OAuthScopesPlug
  14
  15   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  16   plug(OAuthScopesPlug, %{scopes: ["write:statuses"]} when action in [:create, :delete])
  17
  18   plug(
  19     OAuthScopesPlug,
  20     %{scopes: ["read:statuses"], fallback: :proceed_unauthenticated}
  21     when action == :index
  22   )
  23
  24   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.EmojiReactionOperation
  25
  26   action_fallback(Pleroma.Web.MastodonAPI.FallbackController)
  27
  28   def index(%{assigns: %{user: user}} = conn, %{id: activity_id} = params) do
  29     with true <- Pleroma.Config.get([:instance, :show_reactions]),
  30          %Activity{} = activity <- Activity.get_by_id_with_object(activity_id),
  31          %Object{data: %{"reactions" => reactions}} when is_list(reactions) <-
  32            Object.normalize(activity, fetch: false) do
  33       reactions =
  34         reactions
  35         |> filter(params)
  36         |> filter_allowed_users(user, Map.get(params, :with_muted, false))
  37
  38       render(conn, "index.json", emoji_reactions: reactions, user: user)
  39     else
  40       _e -> json(conn, [])
  41     end
  42   end
  43
  44   def filter_allowed_users(reactions, user, with_muted) do
  45     exclude_ap_ids =
  46       if is_nil(user) do
  47         []
  48       else
  49         User.cached_blocked_users_ap_ids(user) ++
  50           if not with_muted, do: User.cached_muted_users_ap_ids(user), else: []
  51       end
  52
  53     filter_emoji = fn emoji, users, url ->
  54       case Enum.reject(users, &(&1 in exclude_ap_ids)) do
  55         [] -> nil
  56         users -> {emoji, users, url}
  57       end
  58     end
  59
  60     reactions
  61     |> Stream.map(fn
  62       [emoji, users, url] when is_list(users) -> filter_emoji.(emoji, users, url)
  63       {emoji, users, url} when is_list(users) -> filter_emoji.(emoji, users, url)
  64       {emoji, users} when is_list(users) -> filter_emoji.(emoji, users, nil)
  65       _ -> nil
  66     end)
  67     |> Stream.reject(&is_nil/1)
  68   end
  69
  70   defp filter(reactions, %{emoji: emoji}) when is_binary(emoji) do
  71     Enum.filter(reactions, fn [e, _, _] -> e == emoji end)
  72   end
  73
  74   defp filter(reactions, _), do: reactions
  75
  76   def create(%{assigns: %{user: user}} = conn, %{id: activity_id, emoji: emoji}) do
  77     emoji =
  78       emoji
  79       |> Pleroma.Emoji.fully_qualify_emoji()
  80       |> Pleroma.Emoji.maybe_quote()
  81
  82     with {:ok, _activity} <- CommonAPI.react_with_emoji(activity_id, user, emoji) do
  83       activity = Activity.get_by_id(activity_id)
  84
  85       conn
  86       |> put_view(StatusView)
  87       |> render("show.json", activity: activity, for: user, as: :activity)
  88     end
  89   end
  90
  91   def delete(%{assigns: %{user: user}} = conn, %{id: activity_id, emoji: emoji}) do
  92     emoji =
  93       emoji
  94       |> Pleroma.Emoji.fully_qualify_emoji()
  95       |> Pleroma.Emoji.maybe_quote()
  96
  97     with {:ok, _activity} <- CommonAPI.unreact_with_emoji(activity_id, user, emoji) do
  98       activity = Activity.get_by_id(activity_id)
  99
 100       conn
 101       |> put_view(StatusView)
 102       |> render("show.json", activity: activity, for: user, as: :activity)
 103     end
 104   end
 105 end