git.squeep.com Git - akkoma/blob - lib/pleroma/web/pleroma_api/controllers/emoji_file_controller.ex

   1 defmodule Pleroma.Web.PleromaAPI.EmojiFileController do
   2   use Pleroma.Web, :controller
   3
   4   alias Pleroma.Emoji.Pack
   5   alias Pleroma.Web.ApiSpec
   6
   7   plug(Pleroma.Web.ApiSpec.CastAndValidate)
   8
   9   plug(
  10     Pleroma.Plugs.OAuthScopesPlug,
  11     %{scopes: ["write"], admin: true}
  12     when action in [
  13            :create,
  14            :update,
  15            :delete
  16          ]
  17   )
  18
  19   defdelegate open_api_operation(action), to: ApiSpec.PleromaEmojiFileOperation
  20
  21   def create(%{body_params: params} = conn, %{name: pack_name}) do
  22     filename = params[:filename] || get_filename(params[:file])
  23     shortcode = params[:shortcode] || Path.basename(filename, Path.extname(filename))
  24
  25     with {:ok, pack} <- Pack.load_pack(pack_name),
  26          {:ok, file} <- get_file(params[:file]),
  27          {:ok, pack} <- Pack.add_file(pack, shortcode, filename, file) do
  28       json(conn, pack.files)
  29     else
  30       {:error, :already_exists} ->
  31         conn
  32         |> put_status(:conflict)
  33         |> json(%{error: "An emoji with the \"#{shortcode}\" shortcode already exists"})
  34
  35       {:error, :empty_values} ->
  36         conn
  37         |> put_status(:unprocessable_entity)
  38         |> json(%{error: "pack name, shortcode or filename cannot be empty"})
  39
  40       {:error, _} = error ->
  41         handle_error(conn, error, %{pack_name: pack_name})
  42     end
  43   end
  44
  45   def update(%{body_params: %{shortcode: shortcode} = params} = conn, %{name: pack_name}) do
  46     new_shortcode = params[:new_shortcode]
  47     new_filename = params[:new_filename]
  48     force = params[:force]
  49
  50     with {:ok, pack} <- Pack.load_pack(pack_name),
  51          {:ok, pack} <- Pack.update_file(pack, shortcode, new_shortcode, new_filename, force) do
  52       json(conn, pack.files)
  53     else
  54       {:error, :already_exists} ->
  55         conn
  56         |> put_status(:conflict)
  57         |> json(%{
  58           error:
  59             "New shortcode \"#{new_shortcode}\" is already used. If you want to override emoji use 'force' option"
  60         })
  61
  62       {:error, :empty_values} ->
  63         conn
  64         |> put_status(:unprocessable_entity)
  65         |> json(%{error: "new_shortcode or new_filename cannot be empty"})
  66
  67       {:error, _} = error ->
  68         handle_error(conn, error, %{pack_name: pack_name, code: shortcode})
  69     end
  70   end
  71
  72   def delete(conn, %{name: pack_name, shortcode: shortcode}) do
  73     with {:ok, pack} <- Pack.load_pack(pack_name),
  74          {:ok, pack} <- Pack.delete_file(pack, shortcode) do
  75       json(conn, pack.files)
  76     else
  77       {:error, :empty_values} ->
  78         conn
  79         |> put_status(:unprocessable_entity)
  80         |> json(%{error: "pack name or shortcode cannot be empty"})
  81
  82       {:error, _} = error ->
  83         handle_error(conn, error, %{pack_name: pack_name, code: shortcode})
  84     end
  85   end
  86
  87   defp handle_error(conn, {:error, :doesnt_exist}, %{code: emoji_code}) do
  88     conn
  89     |> put_status(:bad_request)
  90     |> json(%{error: "Emoji \"#{emoji_code}\" does not exist"})
  91   end
  92
  93   defp handle_error(conn, {:error, :not_found}, %{pack_name: pack_name}) do
  94     conn
  95     |> put_status(:not_found)
  96     |> json(%{error: "pack \"#{pack_name}\" is not found"})
  97   end
  98
  99   defp handle_error(conn, {:error, _}, _) do
 100     render_error(
 101       conn,
 102       :internal_server_error,
 103       "Unexpected error occurred while adding file to pack."
 104     )
 105   end
 106
 107   defp get_filename(%Plug.Upload{filename: filename}), do: filename
 108   defp get_filename(url) when is_binary(url), do: Path.basename(url)
 109
 110   def get_file(%Plug.Upload{} = file), do: {:ok, file}
 111
 112   def get_file(url) when is_binary(url) do
 113     with {:ok, %Tesla.Env{body: body, status: code, headers: headers}}
 114          when code in 200..299 <- Pleroma.HTTP.get(url) do
 115       path = Plug.Upload.random_file!("emoji")
 116
 117       content_type =
 118         case List.keyfind(headers, "content-type", 0) do
 119           {"content-type", value} -> value
 120           nil -> nil
 121         end
 122
 123       File.write(path, body)
 124
 125       {:ok,
 126        %Plug.Upload{
 127          filename: Path.basename(url),
 128          path: path,
 129          content_type: content_type
 130        }}
 131     end
 132   end
 133 end