git.squeep.com Git - akkoma/blob - lib/pleroma/web/oauth/token.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.OAuth.Token do
   6   use Ecto.Schema
   7
   8   import Ecto.Changeset
   9
  10   alias Pleroma.Repo
  11   alias Pleroma.User
  12   alias Pleroma.Web.OAuth.App
  13   alias Pleroma.Web.OAuth.Authorization
  14   alias Pleroma.Web.OAuth.Token
  15   alias Pleroma.Web.OAuth.Token.Query
  16
  17   @type t :: %__MODULE__{}
  18
  19   schema "oauth_tokens" do
  20     field(:token, :string)
  21     field(:refresh_token, :string)
  22     field(:scopes, {:array, :string}, default: [])
  23     field(:valid_until, :naive_datetime_usec)
  24     belongs_to(:user, User, type: FlakeId.Ecto.CompatType)
  25     belongs_to(:app, App)
  26
  27     timestamps()
  28   end
  29
  30   @doc "Gets token for app by access token"
  31   @spec get_by_token(App.t(), String.t()) :: {:ok, t()} | {:error, :not_found}
  32   def get_by_token(%App{id: app_id} = _app, token) do
  33     Query.get_by_app(app_id)
  34     |> Query.get_by_token(token)
  35     |> Repo.find_resource()
  36   end
  37
  38   @doc "Gets token for app by refresh token"
  39   @spec get_by_refresh_token(App.t(), String.t()) :: {:ok, t()} | {:error, :not_found}
  40   def get_by_refresh_token(%App{id: app_id} = _app, token) do
  41     Query.get_by_app(app_id)
  42     |> Query.get_by_refresh_token(token)
  43     |> Query.preload([:user])
  44     |> Repo.find_resource()
  45   end
  46
  47   @spec exchange_token(App.t(), Authorization.t()) :: {:ok, Token.t()} | {:error, Changeset.t()}
  48   def exchange_token(app, auth) do
  49     with {:ok, auth} <- Authorization.use_token(auth),
  50          true <- auth.app_id == app.id do
  51       user = if auth.user_id, do: User.get_cached_by_id(auth.user_id), else: %User{}
  52
  53       create(
  54         app,
  55         user,
  56         %{scopes: auth.scopes}
  57       )
  58     end
  59   end
  60
  61   defp put_token(changeset) do
  62     changeset
  63     |> change(%{token: Token.Utils.generate_token()})
  64     |> validate_required([:token])
  65     |> unique_constraint(:token)
  66   end
  67
  68   defp put_refresh_token(changeset, attrs) do
  69     refresh_token = Map.get(attrs, :refresh_token, Token.Utils.generate_token())
  70
  71     changeset
  72     |> change(%{refresh_token: refresh_token})
  73     |> validate_required([:refresh_token])
  74     |> unique_constraint(:refresh_token)
  75   end
  76
  77   defp put_valid_until(changeset, attrs) do
  78     expires_in =
  79       Map.get(attrs, :valid_until, NaiveDateTime.add(NaiveDateTime.utc_now(), expires_in()))
  80
  81     changeset
  82     |> change(%{valid_until: expires_in})
  83     |> validate_required([:valid_until])
  84   end
  85
  86   @spec create(App.t(), User.t(), map()) :: {:ok, Token} | {:error, Changeset.t()}
  87   def create(%App{} = app, %User{} = user, attrs \\ %{}) do
  88     with {:ok, token} <- do_create(app, user, attrs) do
  89       if Pleroma.Config.get([:oauth2, :clean_expired_tokens]) do
  90         Pleroma.Workers.PurgeExpiredOAuthToken.enqueue(%{
  91           token_id: token.id,
  92           valid_until: DateTime.from_naive!(token.valid_until, "Etc/UTC")
  93         })
  94       end
  95
  96       {:ok, token}
  97     end
  98   end
  99
 100   defp do_create(app, user, attrs) do
 101     %__MODULE__{user_id: user.id, app_id: app.id}
 102     |> cast(%{scopes: attrs[:scopes] || app.scopes}, [:scopes])
 103     |> validate_required([:scopes, :app_id])
 104     |> put_valid_until(attrs)
 105     |> put_token()
 106     |> put_refresh_token(attrs)
 107     |> Repo.insert()
 108   end
 109
 110   def delete_user_tokens(%User{id: user_id}) do
 111     Query.get_by_user(user_id)
 112     |> Repo.delete_all()
 113   end
 114
 115   def delete_user_token(%User{id: user_id}, token_id) do
 116     Query.get_by_user(user_id)
 117     |> Query.get_by_id(token_id)
 118     |> Repo.delete_all()
 119   end
 120
 121   def get_user_tokens(%User{id: user_id}) do
 122     Query.get_by_user(user_id)
 123     |> Query.preload([:app])
 124     |> Repo.all()
 125   end
 126
 127   def is_expired?(%__MODULE__{valid_until: valid_until}) do
 128     NaiveDateTime.diff(NaiveDateTime.utc_now(), valid_until) > 0
 129   end
 130
 131   def is_expired?(_), do: false
 132
 133   defp expires_in, do: Pleroma.Config.get([:oauth2, :token_expires_in], 600)
 134 end