git.squeep.com Git - akkoma/blob - lib/pleroma/web/oauth/oauth_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.OAuth.OAuthController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Helpers.UriHelper
   9   alias Pleroma.Registration
  10   alias Pleroma.Repo
  11   alias Pleroma.User
  12   alias Pleroma.Web.Auth.Authenticator
  13   alias Pleroma.Web.ControllerHelper
  14   alias Pleroma.Web.OAuth.App
  15   alias Pleroma.Web.OAuth.Authorization
  16   alias Pleroma.Web.OAuth.Token
  17   alias Pleroma.Web.OAuth.Token.Strategy.RefreshToken
  18   alias Pleroma.Web.OAuth.Token.Strategy.Revoke, as: RevokeToken
  19   alias Pleroma.Web.OAuth.Scopes
  20
  21   require Logger
  22
  23   if Pleroma.Config.oauth_consumer_enabled?(), do: plug(Ueberauth)
  24
  25   plug(:fetch_session)
  26   plug(:fetch_flash)
  27
  28   action_fallback(Pleroma.Web.OAuth.FallbackController)
  29
  30   @oob_token_redirect_uri "urn:ietf:wg:oauth:2.0:oob"
  31
  32   # Note: this definition is only called from error-handling methods with `conn.params` as 2nd arg
  33   def authorize(%Plug.Conn{} = conn, %{"authorization" => _} = params) do
  34     {auth_attrs, params} = Map.pop(params, "authorization")
  35     authorize(conn, Map.merge(params, auth_attrs))
  36   end
  37
  38   def authorize(%Plug.Conn{assigns: %{token: %Token{}}} = conn, params) do
  39     if ControllerHelper.truthy_param?(params["force_login"]) do
  40       do_authorize(conn, params)
  41     else
  42       handle_existing_authorization(conn, params)
  43     end
  44   end
  45
  46   def authorize(%Plug.Conn{} = conn, params), do: do_authorize(conn, params)
  47
  48   defp do_authorize(%Plug.Conn{} = conn, params) do
  49     app = Repo.get_by(App, client_id: params["client_id"])
  50     available_scopes = (app && app.scopes) || []
  51     scopes = Scopes.fetch_scopes(params, available_scopes)
  52
  53     # Note: `params` might differ from `conn.params`; use `@params` not `@conn.params` in template
  54     render(conn, Authenticator.auth_template(), %{
  55       response_type: params["response_type"],
  56       client_id: params["client_id"],
  57       available_scopes: available_scopes,
  58       scopes: scopes,
  59       redirect_uri: params["redirect_uri"],
  60       state: params["state"],
  61       params: params
  62     })
  63   end
  64
  65   defp handle_existing_authorization(
  66          %Plug.Conn{assigns: %{token: %Token{} = token}} = conn,
  67          %{"redirect_uri" => @oob_token_redirect_uri}
  68        ) do
  69     render(conn, "oob_token_exists.html", %{token: token})
  70   end
  71
  72   defp handle_existing_authorization(
  73          %Plug.Conn{assigns: %{token: %Token{} = token}} = conn,
  74          %{} = params
  75        ) do
  76     app = Repo.preload(token, :app).app
  77
  78     redirect_uri =
  79       if is_binary(params["redirect_uri"]) do
  80         params["redirect_uri"]
  81       else
  82         default_redirect_uri(app)
  83       end
  84
  85     if redirect_uri in String.split(app.redirect_uris) do
  86       redirect_uri = redirect_uri(conn, redirect_uri)
  87       url_params = %{access_token: token.token}
  88       url_params = UriHelper.append_param_if_present(url_params, :state, params["state"])
  89       url = UriHelper.append_uri_params(redirect_uri, url_params)
  90       redirect(conn, external: url)
  91     else
  92       conn
  93       |> put_flash(:error, dgettext("errors", "Unlisted redirect_uri."))
  94       |> redirect(external: redirect_uri(conn, redirect_uri))
  95     end
  96   end
  97
  98   def create_authorization(
  99         %Plug.Conn{} = conn,
 100         %{"authorization" => _} = params,
 101         opts \\ []
 102       ) do
 103     with {:ok, auth} <- do_create_authorization(conn, params, opts[:user]) do
 104       after_create_authorization(conn, auth, params)
 105     else
 106       error ->
 107         handle_create_authorization_error(conn, error, params)
 108     end
 109   end
 110
 111   def after_create_authorization(%Plug.Conn{} = conn, %Authorization{} = auth, %{
 112         "authorization" => %{"redirect_uri" => @oob_token_redirect_uri}
 113       }) do
 114     render(conn, "oob_authorization_created.html", %{auth: auth})
 115   end
 116
 117   def after_create_authorization(%Plug.Conn{} = conn, %Authorization{} = auth, %{
 118         "authorization" => %{"redirect_uri" => redirect_uri} = auth_attrs
 119       }) do
 120     app = Repo.preload(auth, :app).app
 121
 122     # An extra safety measure before we redirect (also done in `do_create_authorization/2`)
 123     if redirect_uri in String.split(app.redirect_uris) do
 124       redirect_uri = redirect_uri(conn, redirect_uri)
 125       url_params = %{code: auth.token}
 126       url_params = UriHelper.append_param_if_present(url_params, :state, auth_attrs["state"])
 127       url = UriHelper.append_uri_params(redirect_uri, url_params)
 128       redirect(conn, external: url)
 129     else
 130       conn
 131       |> put_flash(:error, dgettext("errors", "Unlisted redirect_uri."))
 132       |> redirect(external: redirect_uri(conn, redirect_uri))
 133     end
 134   end
 135
 136   defp handle_create_authorization_error(
 137          %Plug.Conn{} = conn,
 138          {:error, scopes_issue},
 139          %{"authorization" => _} = params
 140        )
 141        when scopes_issue in [:unsupported_scopes, :missing_scopes] do
 142     # Per https://github.com/tootsuite/mastodon/blob/
 143     #   51e154f5e87968d6bb115e053689767ab33e80cd/app/controllers/api/base_controller.rb#L39
 144     conn
 145     |> put_flash(:error, dgettext("errors", "This action is outside the authorized scopes"))
 146     |> put_status(:unauthorized)
 147     |> authorize(params)
 148   end
 149
 150   defp handle_create_authorization_error(
 151          %Plug.Conn{} = conn,
 152          {:auth_active, false},
 153          %{"authorization" => _} = params
 154        ) do
 155     # Per https://github.com/tootsuite/mastodon/blob/
 156     #   51e154f5e87968d6bb115e053689767ab33e80cd/app/controllers/api/base_controller.rb#L76
 157     conn
 158     |> put_flash(:error, dgettext("errors", "Your login is missing a confirmed e-mail address"))
 159     |> put_status(:forbidden)
 160     |> authorize(params)
 161   end
 162
 163   defp handle_create_authorization_error(%Plug.Conn{} = conn, error, %{"authorization" => _}) do
 164     Authenticator.handle_error(conn, error)
 165   end
 166
 167   @doc "Renew access_token with refresh_token"
 168   def token_exchange(
 169         %Plug.Conn{} = conn,
 170         %{"grant_type" => "refresh_token", "refresh_token" => token} = _params
 171       ) do
 172     with {:ok, app} <- Token.Utils.fetch_app(conn),
 173          {:ok, %{user: user} = token} <- Token.get_by_refresh_token(app, token),
 174          {:ok, token} <- RefreshToken.grant(token) do
 175       response_attrs = %{created_at: Token.Utils.format_created_at(token)}
 176
 177       json(conn, Token.Response.build(user, token, response_attrs))
 178     else
 179       _error -> render_invalid_credentials_error(conn)
 180     end
 181   end
 182
 183   def token_exchange(%Plug.Conn{} = conn, %{"grant_type" => "authorization_code"} = params) do
 184     with {:ok, app} <- Token.Utils.fetch_app(conn),
 185          fixed_token = Token.Utils.fix_padding(params["code"]),
 186          {:ok, auth} <- Authorization.get_by_token(app, fixed_token),
 187          %User{} = user <- User.get_cached_by_id(auth.user_id),
 188          {:ok, token} <- Token.exchange_token(app, auth) do
 189       response_attrs = %{created_at: Token.Utils.format_created_at(token)}
 190
 191       json(conn, Token.Response.build(user, token, response_attrs))
 192     else
 193       _error -> render_invalid_credentials_error(conn)
 194     end
 195   end
 196
 197   def token_exchange(
 198         %Plug.Conn{} = conn,
 199         %{"grant_type" => "password"} = params
 200       ) do
 201     with {:ok, %User{} = user} <- Authenticator.get_user(conn),
 202          {:ok, app} <- Token.Utils.fetch_app(conn),
 203          {:auth_active, true} <- {:auth_active, User.auth_active?(user)},
 204          {:user_active, true} <- {:user_active, !user.info.deactivated},
 205          {:password_reset_pending, false} <-
 206            {:password_reset_pending, user.info.password_reset_pending},
 207          {:ok, scopes} <- validate_scopes(app, params),
 208          {:ok, auth} <- Authorization.create_authorization(app, user, scopes),
 209          {:ok, token} <- Token.exchange_token(app, auth) do
 210       json(conn, Token.Response.build(user, token))
 211     else
 212       {:auth_active, false} ->
 213         # Per https://github.com/tootsuite/mastodon/blob/
 214         #   51e154f5e87968d6bb115e053689767ab33e80cd/app/controllers/api/base_controller.rb#L76
 215         render_error(conn, :forbidden, "Your login is missing a confirmed e-mail address")
 216
 217       {:user_active, false} ->
 218         render_error(conn, :forbidden, "Your account is currently disabled")
 219
 220       {:password_reset_pending, true} ->
 221         render_error(conn, :forbidden, "Password reset is required")
 222
 223       _error ->
 224         render_invalid_credentials_error(conn)
 225     end
 226   end
 227
 228   def token_exchange(
 229         %Plug.Conn{} = conn,
 230         %{"grant_type" => "password", "name" => name, "password" => _password} = params
 231       ) do
 232     params =
 233       params
 234       |> Map.delete("name")
 235       |> Map.put("username", name)
 236
 237     token_exchange(conn, params)
 238   end
 239
 240   def token_exchange(%Plug.Conn{} = conn, %{"grant_type" => "client_credentials"} = _params) do
 241     with {:ok, app} <- Token.Utils.fetch_app(conn),
 242          {:ok, auth} <- Authorization.create_authorization(app, %User{}),
 243          {:ok, token} <- Token.exchange_token(app, auth) do
 244       json(conn, Token.Response.build_for_client_credentials(token))
 245     else
 246       _error -> render_invalid_credentials_error(conn)
 247     end
 248   end
 249
 250   # Bad request
 251   def token_exchange(%Plug.Conn{} = conn, params), do: bad_request(conn, params)
 252
 253   def token_revoke(%Plug.Conn{} = conn, %{"token" => _token} = params) do
 254     with {:ok, app} <- Token.Utils.fetch_app(conn),
 255          {:ok, _token} <- RevokeToken.revoke(app, params) do
 256       json(conn, %{})
 257     else
 258       _error ->
 259         # RFC 7009: invalid tokens [in the request] do not cause an error response
 260         json(conn, %{})
 261     end
 262   end
 263
 264   def token_revoke(%Plug.Conn{} = conn, params), do: bad_request(conn, params)
 265
 266   # Response for bad request
 267   defp bad_request(%Plug.Conn{} = conn, _) do
 268     render_error(conn, :internal_server_error, "Bad request")
 269   end
 270
 271   @doc "Prepares OAuth request to provider for Ueberauth"
 272   def prepare_request(%Plug.Conn{} = conn, %{
 273         "provider" => provider,
 274         "authorization" => auth_attrs
 275       }) do
 276     scope =
 277       auth_attrs
 278       |> Scopes.fetch_scopes([])
 279       |> Scopes.to_string()
 280
 281     state =
 282       auth_attrs
 283       |> Map.delete("scopes")
 284       |> Map.put("scope", scope)
 285       |> Jason.encode!()
 286
 287     params =
 288       auth_attrs
 289       |> Map.drop(~w(scope scopes client_id redirect_uri))
 290       |> Map.put("state", state)
 291
 292     # Handing the request to Ueberauth
 293     redirect(conn, to: o_auth_path(conn, :request, provider, params))
 294   end
 295
 296   def request(%Plug.Conn{} = conn, params) do
 297     message =
 298       if params["provider"] do
 299         dgettext("errors", "Unsupported OAuth provider: %{provider}.",
 300           provider: params["provider"]
 301         )
 302       else
 303         dgettext("errors", "Bad OAuth request.")
 304       end
 305
 306     conn
 307     |> put_flash(:error, message)
 308     |> redirect(to: "/")
 309   end
 310
 311   def callback(%Plug.Conn{assigns: %{ueberauth_failure: failure}} = conn, params) do
 312     params = callback_params(params)
 313     messages = for e <- Map.get(failure, :errors, []), do: e.message
 314     message = Enum.join(messages, "; ")
 315
 316     conn
 317     |> put_flash(
 318       :error,
 319       dgettext("errors", "Failed to authenticate: %{message}.", message: message)
 320     )
 321     |> redirect(external: redirect_uri(conn, params["redirect_uri"]))
 322   end
 323
 324   def callback(%Plug.Conn{} = conn, params) do
 325     params = callback_params(params)
 326
 327     with {:ok, registration} <- Authenticator.get_registration(conn) do
 328       auth_attrs = Map.take(params, ~w(client_id redirect_uri scope scopes state))
 329
 330       case Repo.get_assoc(registration, :user) do
 331         {:ok, user} ->
 332           create_authorization(conn, %{"authorization" => auth_attrs}, user: user)
 333
 334         _ ->
 335           registration_params =
 336             Map.merge(auth_attrs, %{
 337               "nickname" => Registration.nickname(registration),
 338               "email" => Registration.email(registration)
 339             })
 340
 341           conn
 342           |> put_session_registration_id(registration.id)
 343           |> registration_details(%{"authorization" => registration_params})
 344       end
 345     else
 346       error ->
 347         Logger.debug(inspect(["OAUTH_ERROR", error, conn.assigns]))
 348
 349         conn
 350         |> put_flash(:error, dgettext("errors", "Failed to set up user account."))
 351         |> redirect(external: redirect_uri(conn, params["redirect_uri"]))
 352     end
 353   end
 354
 355   defp callback_params(%{"state" => state} = params) do
 356     Map.merge(params, Jason.decode!(state))
 357   end
 358
 359   def registration_details(%Plug.Conn{} = conn, %{"authorization" => auth_attrs}) do
 360     render(conn, "register.html", %{
 361       client_id: auth_attrs["client_id"],
 362       redirect_uri: auth_attrs["redirect_uri"],
 363       state: auth_attrs["state"],
 364       scopes: Scopes.fetch_scopes(auth_attrs, []),
 365       nickname: auth_attrs["nickname"],
 366       email: auth_attrs["email"]
 367     })
 368   end
 369
 370   def register(%Plug.Conn{} = conn, %{"authorization" => _, "op" => "connect"} = params) do
 371     with registration_id when not is_nil(registration_id) <- get_session_registration_id(conn),
 372          %Registration{} = registration <- Repo.get(Registration, registration_id),
 373          {_, {:ok, auth}} <- {:create_authorization, do_create_authorization(conn, params)},
 374          %User{} = user <- Repo.preload(auth, :user).user,
 375          {:ok, _updated_registration} <- Registration.bind_to_user(registration, user) do
 376       conn
 377       |> put_session_registration_id(nil)
 378       |> after_create_authorization(auth, params)
 379     else
 380       {:create_authorization, error} ->
 381         {:register, handle_create_authorization_error(conn, error, params)}
 382
 383       _ ->
 384         {:register, :generic_error}
 385     end
 386   end
 387
 388   def register(%Plug.Conn{} = conn, %{"authorization" => _, "op" => "register"} = params) do
 389     with registration_id when not is_nil(registration_id) <- get_session_registration_id(conn),
 390          %Registration{} = registration <- Repo.get(Registration, registration_id),
 391          {:ok, user} <- Authenticator.create_from_registration(conn, registration) do
 392       conn
 393       |> put_session_registration_id(nil)
 394       |> create_authorization(
 395         params,
 396         user: user
 397       )
 398     else
 399       {:error, changeset} ->
 400         message =
 401           Enum.map(changeset.errors, fn {field, {error, _}} ->
 402             "#{field} #{error}"
 403           end)
 404           |> Enum.join("; ")
 405
 406         message =
 407           String.replace(
 408             message,
 409             "ap_id has already been taken",
 410             "nickname has already been taken"
 411           )
 412
 413         conn
 414         |> put_status(:forbidden)
 415         |> put_flash(:error, "Error: #{message}.")
 416         |> registration_details(params)
 417
 418       _ ->
 419         {:register, :generic_error}
 420     end
 421   end
 422
 423   defp do_create_authorization(
 424          %Plug.Conn{} = conn,
 425          %{
 426            "authorization" =>
 427              %{
 428                "client_id" => client_id,
 429                "redirect_uri" => redirect_uri
 430              } = auth_attrs
 431          },
 432          user \\ nil
 433        ) do
 434     with {_, {:ok, %User{} = user}} <-
 435            {:get_user, (user && {:ok, user}) || Authenticator.get_user(conn)},
 436          %App{} = app <- Repo.get_by(App, client_id: client_id),
 437          true <- redirect_uri in String.split(app.redirect_uris),
 438          {:ok, scopes} <- validate_scopes(app, auth_attrs),
 439          {:auth_active, true} <- {:auth_active, User.auth_active?(user)} do
 440       Authorization.create_authorization(app, user, scopes)
 441     end
 442   end
 443
 444   # Special case: Local MastodonFE
 445   defp redirect_uri(%Plug.Conn{} = conn, "."), do: mastodon_api_url(conn, :login)
 446
 447   defp redirect_uri(%Plug.Conn{}, redirect_uri), do: redirect_uri
 448
 449   defp get_session_registration_id(%Plug.Conn{} = conn), do: get_session(conn, :registration_id)
 450
 451   defp put_session_registration_id(%Plug.Conn{} = conn, registration_id),
 452     do: put_session(conn, :registration_id, registration_id)
 453
 454   @spec validate_scopes(App.t(), map()) ::
 455           {:ok, list()} | {:error, :missing_scopes | :unsupported_scopes}
 456   defp validate_scopes(app, params) do
 457     params
 458     |> Scopes.fetch_scopes(app.scopes)
 459     |> Scopes.validate(app.scopes)
 460   end
 461
 462   def default_redirect_uri(%App{} = app) do
 463     app.redirect_uris
 464     |> String.split()
 465     |> Enum.at(0)
 466   end
 467
 468   defp render_invalid_credentials_error(conn) do
 469     render_error(conn, :bad_request, "Invalid credentials")
 470   end
 471 end