git.squeep.com Git - akkoma/blob - lib/pleroma/web/nodeinfo/nodeinfo_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Nodeinfo.NodeinfoController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Stats
  10   alias Pleroma.User
  11   alias Pleroma.Web
  12   alias Pleroma.Web.ActivityPub.MRF
  13   alias Pleroma.Web.Federator.Publisher
  14
  15   def schemas(conn, _params) do
  16     response = %{
  17       links: [
  18         %{
  19           rel: "http://nodeinfo.diaspora.software/ns/schema/2.0",
  20           href: Web.base_url() <> "/nodeinfo/2.0.json"
  21         },
  22         %{
  23           rel: "http://nodeinfo.diaspora.software/ns/schema/2.1",
  24           href: Web.base_url() <> "/nodeinfo/2.1.json"
  25         }
  26       ]
  27     }
  28
  29     json(conn, response)
  30   end
  31
  32   # returns a nodeinfo 2.0 map, since 2.1 just adds a repository field
  33   # under software.
  34   def raw_nodeinfo do
  35     stats = Stats.get_stats()
  36
  37     quarantined = Config.get([:instance, :quarantined_instances], [])
  38
  39     staff_accounts =
  40       User.all_superusers()
  41       |> Enum.map(fn u -> u.ap_id end)
  42
  43     federation_response =
  44       if Config.get([:instance, :mrf_transparency]) do
  45         {:ok, data} = MRF.describe()
  46
  47         data
  48         |> Map.merge(%{quarantined_instances: quarantined})
  49       else
  50         %{}
  51       end
  52
  53     features =
  54       [
  55         "pleroma_api",
  56         "mastodon_api",
  57         "mastodon_api_streaming",
  58         "polls",
  59         "pleroma_explicit_addressing",
  60         if Config.get([:media_proxy, :enabled]) do
  61           "media_proxy"
  62         end,
  63         if Config.get([:gopher, :enabled]) do
  64           "gopher"
  65         end,
  66         if Config.get([:chat, :enabled]) do
  67           "chat"
  68         end,
  69         if Config.get([:suggestions, :enabled]) do
  70           "suggestions"
  71         end,
  72         if Config.get([:instance, :allow_relay]) do
  73           "relay"
  74         end,
  75         if Config.get([:instance, :safe_dm_mentions]) do
  76           "safe_dm_mentions"
  77         end
  78       ]
  79       |> Enum.filter(& &1)
  80
  81     %{
  82       version: "2.0",
  83       software: %{
  84         name: Pleroma.Application.name() |> String.downcase(),
  85         version: Pleroma.Application.version()
  86       },
  87       protocols: Publisher.gather_nodeinfo_protocol_names(),
  88       services: %{
  89         inbound: [],
  90         outbound: []
  91       },
  92       openRegistrations: Config.get([:instance, :registrations_open]),
  93       usage: %{
  94         users: %{
  95           total: stats.user_count || 0
  96         },
  97         localPosts: stats.status_count || 0
  98       },
  99       metadata: %{
 100         nodeName: Config.get([:instance, :name]),
 101         nodeDescription: Config.get([:instance, :description]),
 102         private: !Config.get([:instance, :public], true),
 103         suggestions: %{
 104           enabled: Config.get([:suggestions, :enabled], false),
 105           thirdPartyEngine: Config.get([:suggestions, :third_party_engine], ""),
 106           timeout: Config.get([:suggestions, :timeout], 5000),
 107           limit: Config.get([:suggestions, :limit], 23),
 108           web: Config.get([:suggestions, :web], "")
 109         },
 110         staffAccounts: staff_accounts,
 111         federation: federation_response,
 112         pollLimits: Config.get([:instance, :poll_limits]),
 113         postFormats: Config.get([:instance, :allowed_post_formats]),
 114         uploadLimits: %{
 115           general: Config.get([:instance, :upload_limit]),
 116           avatar: Config.get([:instance, :avatar_upload_limit]),
 117           banner: Config.get([:instance, :banner_upload_limit]),
 118           background: Config.get([:instance, :background_upload_limit])
 119         },
 120         accountActivationRequired: Config.get([:instance, :account_activation_required], false),
 121         invitesEnabled: Config.get([:instance, :invites_enabled], false),
 122         mailerEnabled: Config.get([Pleroma.Emails.Mailer, :enabled], false),
 123         features: features,
 124         restrictedNicknames: Config.get([Pleroma.User, :restricted_nicknames]),
 125         skipThreadContainment: Config.get([:instance, :skip_thread_containment], false)
 126       }
 127     }
 128   end
 129
 130   # Schema definition: https://github.com/jhass/nodeinfo/blob/master/schemas/2.0/schema.json
 131   # and https://github.com/jhass/nodeinfo/blob/master/schemas/2.1/schema.json
 132   def nodeinfo(conn, %{"version" => "2.0"}) do
 133     conn
 134     |> put_resp_header(
 135       "content-type",
 136       "application/json; profile=http://nodeinfo.diaspora.software/ns/schema/2.0#; charset=utf-8"
 137     )
 138     |> json(raw_nodeinfo())
 139   end
 140
 141   def nodeinfo(conn, %{"version" => "2.1"}) do
 142     raw_response = raw_nodeinfo()
 143
 144     updated_software =
 145       raw_response
 146       |> Map.get(:software)
 147       |> Map.put(:repository, Pleroma.Application.repository())
 148
 149     response =
 150       raw_response
 151       |> Map.put(:software, updated_software)
 152       |> Map.put(:version, "2.1")
 153
 154     conn
 155     |> put_resp_header(
 156       "content-type",
 157       "application/json; profile=http://nodeinfo.diaspora.software/ns/schema/2.1#; charset=utf-8"
 158     )
 159     |> json(response)
 160   end
 161
 162   def nodeinfo(conn, _) do
 163     render_error(conn, :not_found, "Nodeinfo schema version not handled")
 164   end
 165 end