git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/media_proxy.ex

   1 defmodule Pleroma.Web.MediaProxy do
   2   @base64_opts [padding: false]
   3
   4   def url(nil), do: nil
   5
   6   def url(""), do: nil
   7
   8   def url(url = "/" <> _), do: url
   9
  10   def url(url) do
  11     config = Application.get_env(:pleroma, :media_proxy, [])
  12
  13     if !Keyword.get(config, :enabled, false) or String.starts_with?(url, Pleroma.Web.base_url()) do
  14       url
  15     else
  16       secret = Application.get_env(:pleroma, Pleroma.Web.Endpoint)[:secret_key_base]
  17       base64 = Base.url_encode64(url, @base64_opts)
  18       sig = :crypto.hmac(:sha, secret, base64)
  19       sig64 = sig |> Base.url_encode64(@base64_opts)
  20
  21       build_url(sig64, base64, filename(url))
  22     end
  23   end
  24
  25   def decode_url(sig, url) do
  26     secret = Application.get_env(:pleroma, Pleroma.Web.Endpoint)[:secret_key_base]
  27     sig = Base.url_decode64!(sig, @base64_opts)
  28     local_sig = :crypto.hmac(:sha, secret, url)
  29
  30     if local_sig == sig do
  31       {:ok, Base.url_decode64!(url, @base64_opts)}
  32     else
  33       {:error, :invalid_signature}
  34     end
  35   end
  36
  37   def filename(url_or_path) do
  38     if path = URI.parse(url_or_path).path, do: Path.basename(path)
  39   end
  40
  41   def build_url(sig_base64, url_base64, filename \\ nil) do
  42     [
  43       Pleroma.Config.get([:media_proxy, :base_url], Pleroma.Web.base_url()),
  44       "proxy",
  45       sig_base64,
  46       url_base64,
  47       filename
  48     ]
  49     |> Enum.filter(fn value -> value end)
  50     |> Path.join()
  51   end
  52 end