git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/websocket_handler.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.WebsocketHandler do
   6   require Logger
   7
   8   alias Pleroma.Repo
   9   alias Pleroma.User
  10   alias Pleroma.Web.OAuth.Token
  11   alias Pleroma.Web.Streamer
  12
  13   @behaviour :cowboy_websocket
  14
  15   # Cowboy timeout period.
  16   @timeout :timer.seconds(30)
  17   # Hibernate every X messages
  18   @hibernate_every 100
  19
  20   @streams [
  21     "public",
  22     "public:local",
  23     "public:media",
  24     "public:local:media",
  25     "user",
  26     "user:notification",
  27     "direct",
  28     "list",
  29     "hashtag"
  30   ]
  31   @anonymous_streams ["public", "public:local", "hashtag"]
  32
  33   def init(%{qs: qs} = req, state) do
  34     with params <- :cow_qs.parse_qs(qs),
  35          sec_websocket <- :cowboy_req.header("sec-websocket-protocol", req, nil),
  36          access_token <- List.keyfind(params, "access_token", 0),
  37          {_, stream} <- List.keyfind(params, "stream", 0),
  38          {:ok, user} <- allow_request(stream, [access_token, sec_websocket]),
  39          topic when is_binary(topic) <- expand_topic(stream, params) do
  40       req =
  41         if sec_websocket do
  42           :cowboy_req.set_resp_header("sec-websocket-protocol", sec_websocket, req)
  43         else
  44           req
  45         end
  46
  47       {:cowboy_websocket, req, %{user: user, topic: topic, count: 0}, %{idle_timeout: @timeout}}
  48     else
  49       {:error, code} ->
  50         Logger.debug("#{__MODULE__} denied connection: #{inspect(code)} - #{inspect(req)}")
  51         {:ok, req} = :cowboy_req.reply(code, req)
  52         {:ok, req, state}
  53
  54       error ->
  55         Logger.debug("#{__MODULE__} denied connection: #{inspect(error)} - #{inspect(req)}")
  56         {:ok, req} = :cowboy_req.reply(400, req)
  57         {:ok, req, state}
  58     end
  59   end
  60
  61   def websocket_init(state) do
  62     Logger.debug(
  63       "#{__MODULE__} accepted websocket connection for user #{
  64         (state.user || %{id: "anonymous"}).id
  65       }, topic #{state.topic}"
  66     )
  67
  68     Streamer.add_socket(state.topic, state.user)
  69     {:ok, state}
  70   end
  71
  72   # We never receive messages.
  73   def websocket_handle(_frame, state) do
  74     {:ok, state}
  75   end
  76
  77   def websocket_info({:render_with_user, view, template, item}, state) do
  78     user = %User{} = User.get_cached_by_ap_id(state.user.ap_id)
  79
  80     unless Streamer.filtered_by_user?(user, item) do
  81       websocket_info({:text, view.render(template, item, user)}, %{state | user: user})
  82     else
  83       {:ok, state}
  84     end
  85   end
  86
  87   def websocket_info({:text, message}, state) do
  88     # If the websocket processed X messages, force an hibernate/GC.
  89     # We don't hibernate at every message to balance CPU usage/latency with RAM usage.
  90     if state.count > @hibernate_every do
  91       {:reply, {:text, message}, %{state | count: 0}, :hibernate}
  92     else
  93       {:reply, {:text, message}, %{state | count: state.count + 1}}
  94     end
  95   end
  96
  97   def terminate(reason, _req, state) do
  98     Logger.debug(
  99       "#{__MODULE__} terminating websocket connection for user #{
 100         (state.user || %{id: "anonymous"}).id
 101       }, topic #{state.topic || "?"}: #{inspect(reason)}"
 102     )
 103
 104     Streamer.remove_socket(state.topic)
 105     :ok
 106   end
 107
 108   # Public streams without authentication.
 109   defp allow_request(stream, [nil, nil]) when stream in @anonymous_streams do
 110     {:ok, nil}
 111   end
 112
 113   # Authenticated streams.
 114   defp allow_request(stream, [access_token, sec_websocket]) when stream in @streams do
 115     token =
 116       with {"access_token", token} <- access_token do
 117         token
 118       else
 119         _ -> sec_websocket
 120       end
 121
 122     with true <- is_bitstring(token),
 123          %Token{user_id: user_id} <- Repo.get_by(Token, token: token),
 124          user = %User{} <- User.get_cached_by_id(user_id) do
 125       {:ok, user}
 126     else
 127       _ -> {:error, 403}
 128     end
 129   end
 130
 131   # Not authenticated.
 132   defp allow_request(stream, _) when stream in @streams, do: {:error, 403}
 133
 134   # No matching stream.
 135   defp allow_request(_, _), do: {:error, 404}
 136
 137   defp expand_topic("hashtag", params) do
 138     case List.keyfind(params, "tag", 0) do
 139       {_, tag} -> "hashtag:#{tag}"
 140       _ -> nil
 141     end
 142   end
 143
 144   defp expand_topic("list", params) do
 145     case List.keyfind(params, "list", 0) do
 146       {_, list} -> "list:#{list}"
 147       _ -> nil
 148     end
 149   end
 150
 151   defp expand_topic(topic, _), do: topic
 152 end